Een lijst met waarde vergelijken met een andere lijst

[Steven89]

Gegroet,

In het voorbeeld heb ik 2 kolommen in kolom A heb ik een lijst met waardes, in kolom B heb ik een kolom vol met tekst. Nu wil ik in kolom C weergeven als 1 van de waardes van de lijst in kolom A voorkomt in de tekst in kolom B. Dus als ik een lijst heb in kolom A ( test, test waarde, Test-waarde, hallo, proberen, blijven-proberen) en in kolom B een hele hoop tekst wil ik kijken of er een waarde uit te lijst voorkomt in deze kolom en die dan weergeeft in kolom C.
zie het voorbeeld voor duidelijkere uitleg wat ik wil

Alvast bedankt !!

Groeten,

 

[AlexCEL]

Zo krijg ik de gewenste uitkomsten:

=ALS.FOUT(INDEX($A:$A;1/(1/MAX(ALS(ISGETAL(VIND.SPEC($A$2:$A$7;$B2));RIJ($A$2:$A$7)))));"Not found")

Laatste overeenkomst in kolom A wordt getoond.

 

[Steven89]

Dank je AlexCEL,

Spijtig genoeg werkt de formule niet(al doe ik waarschijnlijk iets fout)

Alvast bedankt!

 

[AlexCEL]

Het is een matrixfunctie, die moet je afsluiten met Control+Shift+Enter.

Had ik er even bij moeten zetten...

Ik werk met Excel365 en dan hoeft bovenstaande niet meer expliciet.

 

[Steven89]

Dank je AlexCEL,

Ik krijg nog een error als ik de formule probeer: =IFERROR(INDEX($A:$A;1/(1/MAX(IF(ISNUMBER(SEARCH($A$2:$A$7;$B2));ROW($A$2:$A$7)))));"Not found")

 

[AlexCEL]

Ingevuld in je voorbeeld.

 

[Steven89]

Dag AlexCEL,

Alvast heel hard bedankt !
Is er ook een mogelijkheid om de exacte waarde op te zoeken ?
Dus bv als er in kolom B "testing" staat geeft hij met dit resultaat "test" terug omdat "test" in "testing" voorkomt maar ik zou dan een Not found waarde willen hebben aangezien het niet de exacte waarde is gelijk aan "test"?

Alvast bedankt!

 

[JEC.]

Hier nog wel een alternatief (zelfde output als die van Alex zonder matrix formule)

=ALS.FOUT(ZOEKEN(100;1/AANTAL.ALS(B3;"*"&$A$3:$A$8&"*");$A$3:$A$8);"Not Found")

 

[JEC.]

Zo pakt hij alleen de exacte matches

=ALS.FOUT(INDEX($A:$A;1/(1/MAX(ALS(ISGETAL(VIND.SPEC(" "&$A$3:$A$8&" ";" "&$B3&" "));RIJ($A$3:$A$8)))));"Not found")

 

[HSV]

Alsook.

=ALS.FOUT(ZOEKEN(1000;VIND.SPEC($A$3:$A$8;B3);$A$3:$A$8);"Not Found")

 

[JEC.]

Voor de exacte match (Zo is Test geen match met Testing)

=ALS.FOUT(ZOEKEN(1000;VIND.SPEC(" "&$A$3:$A$8&" ";" "&B4&" ");$A$3:$A$8);"Not Found")

 

[HSV]

Mooi kort he?

 

[JEC.]

Zeker! En geen matrix

 

[AlexCEL]

In het geval van Excel is korter (vrijwel) altijd beter.

Ik vergeet de functionaliteit van de ZOEKEN functie nog wel eens... *note to self*