eerste 2 woorden uit een cel halen

[CoolRunnings]

Hoi IK heb het volgende probleem waar ik niet uit kom, ik heb al diverse dingen geprobeerd

Ik heb een geimporteerd csv bestand wat na het inporteren de volgende soortgelijke tekst in een cel geeft
beau bridges als president paul hollister;John cassine als sean morris; etc
nu wil ik uit die cel alleen de 1ste 2 woorden halen, ik heb iets met =deel(vind.spec; ) geprobeerd, maar dan krijg ik vnl beau bridges als president paul hollister, terwijl ik alleen de 1ste 2 worden wil hebben nl beau bridges.

de import is van een dvd catalogus programma

iemand een idee hoe dit te doen

 

[danny147]

Beste CoolRunnings

Zet de volgende formule in cel B1 als de tekst in cel A1 staat

=LINKS(A1;VIND.ALLES(" ";A1)-1)&" "&LINKS(DEEL(A1;VIND.ALLES(" ";A1)+1;LENGTE(A1));VIND.ALLES(" ";DEEL(A1;VIND.ALLES(" ";A1)+1;LENGTE(A1)))-1)

Deze kan je dan slepen naar beneden.

Groetjes Danny. :thumb:

 

[Wigi]

Danny

Gebruik de SUBSTITUEREN functie op een clevere manier, je maakt formules korter en vooral duidelijker:

=LINKS(A1;VIND.ALLES("^";SUBSTITUEREN(A1;" ";"^";2))-1)

Wigi

 

[danny147]

Beste Wigi

Danny

Gebruik de SUBSTITUEREN functie op een clevere manier, je maakt formules korter en vooral duidelijker:

=LINKS(A1;VIND.ALLES("^";SUBSTITUEREN(A1;" ";"^";2))-1)

Wigi

Nu snap ik hem met SUBSTITUEREN

MAAR kan je ook met SUBSTITUEREN het 2de woord of het 3de woord eruit halen ?

Groetjes Danny. :thumb:

 

[Wigi]

Dat kan met SUBSTITUEREN, maar niet zo elegant als hierboven.

=DEEL(A1;VIND.ALLES("§";SUBSTITUEREN(A1;" ";"§";1))+1;VIND.ALLES("^";SUBSTITUEREN(A1;" ";"^";3))-1-VIND.ALLES("§";SUBSTITUEREN(A1;" ";"§";1)))

 

[Duneman]

Beste Danny147,

Al een oude case, maar toch proberen: Als cel A1 0, 1 of 2 woorden bevat, werkt deze code niet. Is daar nog een mouw aan te passen?

0 = leeg
1 = 1
>=2 = 2

MvG,
Marco.