eerste gevonden waarde in een rij

[kibus]

beste kenners

Is er ook een formule die de eeste waarde vind een rij?

alvast bedankt

 

[Roncancio]

Hallo,

Ongetwijfeld, maar zonder aanvullende informatie is het ondoenlijk om een concreet antwoord te geven.

Met vriendelijke groet,


Roncancio

 

[kibus]

Hoi

voorbeeldje bijgevoegd

groeten

 

[Wigi]

=1/SOMPRODUCT(MAX((1/KOLOM($B1:$AD1))*($B1:$AD1<>"")))



Hehe, lekkere formule

Wigi

 

[GiMe]

Of :
=MIN(ALS(B1:AD1>0;(B1:AD1)*RIJ(INDIRECT("1:31"))))
Matrix-formule
Ook niet mis hé !

Maar MIS !
Vergeet deze oplossing zo snel mogelijk en zie item# 14

 

[Wigi]

=1/SOMPRODUCT(MAX((1/KOLOM($B1:$AD1))*($B1:$AD1<>"")))



Hehe, lekkere formule

Wigi

Bovenstaande formule geeft de kolom, niet de eigenlijke waarde. Daarvoor:

=INDEX($B1:$AD1;1;1/SOMPRODUCT(MAX((1/KOLOM($B1:$AD1))*($B1:$AD1<>"")))-1)

Wigi

 

[GiMe]

Wigi,
Moet jou oplossing niet zijn :
=INDEX(A1:AD1;1/SOMPRODUCT(MAX((1/KOLOM($B1:$AD1))*($B1:$AD1<>""))))
?

 

[Wigi]

Of :
=MIN(ALS(B1:AD1>0;(B1:AD1)*RIJ(INDIRECT("1:31"))))
Matrix-formule
Ook niet mis hé !

Dit klopt niet. Je gaat zeker niet het eigenlijke getal krijgen als resultaat, en meer nog, ik betwijfel sterk of je wel altijd het eerste getal uit de rij krijgt.

Al heb ik dit niet verder uitgetest in Excel zelf, enkel hier lezen op het forum.

Wigi

 

[bandito bob]

of zo:

=VERSCHUIVING(A1;0;(KLEINSTE(ALS(WAARDE(B1:AD1);KOLOM(B1:AD1);"");1)-1);1;1)

invoeren als matrix formule (bevestigen met shift-ctrl-enter)
keus genoeg

 

[Wigi]

Wigi,
Moet jou oplossing niet zijn :
=INDEX(A1:AD1;1/SOMPRODUCT(MAX((1/KOLOM($B1:$AD1))*($B1:$AD1<>""))))
?

Dit had ook gekund ja.

Wigi

 

[Roncancio]

Hallo,

In cel A1 onderstaande formule plaatsen en vervolgens naar beneden slepen.

=ALS(KOLOM($B1:B1)<=AANTAL($B1:$IV1);INDEX(1:1;KLEINSTE(ALS(1:1<>"";KOLOM(1:1)-KOLOM($A1)+1);KOLOM($B1:B1)));"")

LET OP: Dit is een matrixnformule dus afsluiten met CTRL-SHIFT-ENTER.

Met vriendelijke groet,


Roncancio

 

[kibus]

Mag ik jullie bedanken voor jullie hulp deze werkt perfect

=INDEX($B3:$AD3;1;1/SOMPRODUCT(MAX((1/KOLOM($B3:$AD3))*($B3:$AD3<>"")))-1)

 

[bandito bob]

Mag ik jullie bedanken voor jullie hulp deze werkt perfect

=INDEX($B3:$AD3;1;1/SOMPRODUCT(MAX((1/KOLOM($B3:$AD3))*($B3:$AD3<>"")))-1)

hmm, die werkt niet meer als er voor het eerste getal tekst staat. Als dit een probleem mocht geven kan je de volgende proberen, die pakt echt het eerste getal:

=INDEX(A1:AD1;1;(KLEINSTE(ALS(ISGETAL(B1:AD1);KOLOM(B1:AD1);"");1)))

LET OP: Dit is een matrixnformule dus afsluiten met CTRL-SHIFT-ENTER.

 

[GiMe]

Vergeet mijn vorige oplossing item #5
Moest zijn :
=INDEX(A1:AD1;MIN(ALS(B1:AD1<>"";KOLOM(B1:AD1))))
Matrix formule !

 

[Wigi]

hmm, die werkt niet meer als er voor het eerste getal tekst staat

Dan moet

... ($B3:$AD3<>"")

vervanderd worden in

... ($B3:$AD3>0)

Al heb ik dat niet getest wegens tijdsgebrek.

Wigi

 

[bandito bob]

Dan moet

... ($B3:$AD3<>"")

vervanderd worden in

... ($B3:$AD3>0)

Al heb ik dat niet getest wegens tijdsgebrek.

Wigi

En mogelijke getallen kleiner dan 0 doen niet mee?

Ik had al iets geprobeert als .....(isgetal($B3:$AD3)), maar dat werkt geloof ik niet

 

[kibus]

Gaat me echt om de eerste waarde die hij vind..

Dit heeft nog steeds betrekking op mijn vorige vraag korting bepalen aan de hand van begin cijfer met deze formule in combinatie met verticaalzoeken en de formule deel probeer ik een oplossing te zoeken. beetje bij beetje kom ik er uit maar voor de echte kenners die vraag staat nog steeds open

 

[GiMe]

De eerste waarde wordt toch gevonden !?

 

[kibus]

Helemaal correct !!