Eerste van de (volgende) maand

[comass]

Hoi,

Hoe krijg ik in e xcel de eerste van de maand?
Ik gebruik nu =LAATSTE.DAG(F9;0)
Alleen krijg ik nu de laatste dag van de maand, ik wil echter altijd de eerste van de maand hebben, behalve als het al de eerste is.

Als voorbeeld
1-1-2023 blijft 1-1-2023
2-1 of een latere datum in januari moet worden 1-2

Ik hoor het graag.
Gr. Daan

 

[AlexCEL]

Zo?

=ALS(DAG(F9)>1;LAATSTE.DAG(F9;0)+1;F9)

Of iets korter geschreven:

=LAATSTE.DAG(F9;-(DAG(F9)=1))+1

 

[comass]

Hoi,

Dit is hem nog niet helemaal volgens mij.
1-1 blijft inderdaad mooi 1-1
Maar 15-1 wordt ook 1-1 en dat zou 1-2 moeten worden.

Als ik er van maak =laatste.dag(f9;0)+1
dan wordt 15-1 de gevraagd 1-2 , maar dan wordt 1-1 ook 1-2

 

[AlexCEL]

Ik had de nuance ook opgemerkt en snel mijn oplossing bijgewerkt in de hoop dat je 'm nog niet gelezen had

Het nieuwe voorstel in #2 voldoet wel dacht ik zo.

=LAATSTE.DAG(F9;-(DAG(F9)=1))+1

 

[comass]

Top, super
Dit werkt voor mij.

 

[OctaFish]

Voor de gein een andere variant:

=DATUM(JAAR(NU());MAAND(NU());0)+1

 

[snb]

Of

=--("1/"&MONTH(A1)+(DAY(A1)>1))

 

[E v R]

en nog 1 voortbordurend op hetgeen je al (bijna) had:

=LAATSTE.DAG(F9-1;0)+1

 

[anton44]

En hoe denken we over

DATUM(JAAR(F9);MAAND(F9);1)

en als het de 1e van de volgende maand moet zijn:

DATUM(JAAR(F9);MAAND(F9)+1;1)

 

[AlexCEL]

@anton, als het de 1-1 moet afgerond worden naar 1-1, terwijl 2-1 afgerond moet worden naar 1-2. Dat gebeurt niet met bovenstaande.

Dus alles met dag groter dan eerste van de maand moet naar eerste van de volgende maand.

 

[anton44]

@AlexCEL, zo had ik het niet begrepen, maar geen nood

=als(dag(F9)=1;DATUM(JAAR(F9);MAAND(F9);1);DATUM(JAAR(F9);MAAND(F9)+1;1)

 

[anton44]

@comass,
Als je voldoende geholpen bent dan graag je vraag als opgelost markeren (rechts boven bij je vraag)