Elke tab een week

[TiborP]

Hallo,

Op dit moment ben ik bezig met het maken van een soort agenda in excel. Elke tab moet een week voorstellen maar hoe kan ik dit makkelijk en snel maken. heb namelijk geen zin om elke tab apart een naam tegeven. De naam van de tab moet zijn:

1-5 okt
8-12 okt
15-19 okt
..enz

Bij voorbaat dank!

 

[Wigi]

Hoi Tibor

Hier heb ik kant-en-klare code voor jou, vers van de pers :thumb:

Option Explicit

Sub TabPerWeek()

    Dim d As Date
    Dim iWeekcounter As Integer
    Dim i As Integer
    Dim sSheetName As String
    Dim wb As Workbook
    Dim ws As Worksheet
    
    Const dBeginDate As Date = #10/1/2007#
    
    Application.ScreenUpdating = False
    
    Set wb = Workbooks.Add
    
    With wb
    
        For iWeekcounter = 1 To 52
            
            d = dBeginDate + 7 * (iWeekcounter - 1)
            
            Set ws = .Worksheets.Add(After:=.Sheets(.Sheets.Count))
            
            sSheetName = Format(d, "d")
            sSheetName = sSheetName & "-" & Format(d + 4, "d mmm")
            
            ws.Name = sSheetName
            
        Next iWeekcounter
    
        Application.DisplayAlerts = False
        For i = 1 To Application.SheetsInNewWorkbook
            
            .Sheets(i).Delete
            
        Next
        Application.DisplayAlerts = True
        
        .Sheets(1).Select
    
    End With
    
    Application.ScreenUpdating = True
    
End Sub

Wigi

 

[TiborP]

Hoi Tibor

Hier heb ik kant-en-klare code voor jou, vers van de pers :thumb:

Option Explicit

Sub TabPerWeek()

    Dim d As Date
    Dim iWeekcounter As Integer
    Dim i As Integer
    Dim sSheetName As String
    Dim wb As Workbook
    Dim ws As Worksheet
    
    Const dBeginDate As Date = #10/1/2007#
    
    Application.ScreenUpdating = False
    
    Set wb = Workbooks.Add
    
    With wb
    
        For iWeekcounter = 1 To 52
            
            d = dBeginDate + 7 * (iWeekcounter - 1)
            
            Set ws = .Worksheets.Add(After:=.Sheets(.Sheets.Count))
            
            sSheetName = Format(d, "d")
            sSheetName = sSheetName & "-" & Format(d + 4, "d mmm")
            
            ws.Name = sSheetName
            
        Next iWeekcounter
    
        Application.DisplayAlerts = False
        For i = 1 To Application.SheetsInNewWorkbook
            
            .Sheets(i).Delete
            
        Next
        Application.DisplayAlerts = True
        
        .Sheets(1).Select
    
    End With
    
    Application.ScreenUpdating = True
    
End Sub

Wigi

Dank je. Dit is al zware kost voor mij maar ga eens kijken wat ik ermee kan.

 

[TiborP]

He Wigi ik neem aan dat ik hem bij Visual Basic moet invoeren maar waar dan en hoe precies?

Ik heb het al bij verschillende bladen geprobeerd, maar het wil niet lukken.

 

[Wigi]

In een Excel bestand, druk Alt-F11.

Doe Invoegen > Module, plak de code in het lege witte vlak van de module.

Sluit VBE af met Alt-F11.

Ga naar Extra > Macro > Macro's en voer de macro uit.

Wigi

 

[TiborP]

In een Excel bestand, druk Alt-F11.

Doe Invoegen > Module, plak de code in het lege witte vlak van de module.

Sluit VBE af met Alt-F11.

Ga naar Extra > Macro > Macro's en voer de macro uit.

Wigi

Geweldig!!! Dit scheelt mij zeer veel werk!!

 

[Wigi]

Graag gedaan.

Ik zal deze routine wat aanpassen en op mijn site zetten. www.wimgielis.be. Is best wel handig denk ik nu.

Wigi

 

[TiborP]

Zeker!!!

Ik heb nu al een heel werkblad gemaakt wat in al die tabs moet komen heb je hier ook nog een trukje voor? Het gaat om bijgaant bestand ik wil voor de dagen ook graag een datum vermelding mocht dat mogelijk zijn.

Let niet op de opmaak. Heb ik nog niks aangedaan.

BVD

 

[Wigi]

Verander de naam van het tweede tabblad naar Master.

Dat wordt een soort van template dat gekopieerd wordt voor elke week.

Plak deze code in een module van het agendabestand, en voer de code weer uit:

Sub TabPerWeekKopiërenMasterSheet()

    Dim d As Date
    Dim iWeekcounter As Integer
    Dim sSheetName As String
    Dim wb As Workbook
    Dim ws As Worksheet
    
    Const dBeginDate As Date = #10/1/2007#
    Const sSheetBasis As String = "Master"
    
    Application.ScreenUpdating = False
    
    Set wb = ThisWorkbook
    
    With wb
    
        For iWeekcounter = 1 To 52
            
            Sheets(sSheetBasis).Copy After:=.Sheets(.Sheets.Count)
            
            Set ws = .Sheets(.Sheets.Count)
            
            d = dBeginDate + 7 * (iWeekcounter - 1)
            
            sSheetName = Format(d, "d")
            sSheetName = sSheetName & "-" & Format(d + 4, "d mmm")
            
            ws.Name = sSheetName
            
            'change month name in C9
            ws.Range("C9").Value = Application.WorksheetFunction.Proper(Format(d, "mmmm"))
            
        Next iWeekcounter
        
        .Sheets(sSheetBasis).Select
    
    End With
    
    Application.ScreenUpdating = True
    
End Sub

Wigi

 

[TiborP]

Dit is geweldig!!! Hoe weet je dit allemaal?

 

[Wigi]

Dit is geweldig!!! Hoe weet je dit allemaal?

Er is een onzichtbare geest die boven mij komt zweven. En dan fluistert die 1 voor 1 alle stukjes code in mijn oor. Ik moet ze enkel nog uittypen. Best handig hoor.

Wigi

 

[TiborP]

He dat is makkelijk kan diegene dan nog iets meer uitleggen?

Het is namelijk zo dat ik bij elke "dagtabel" ook de juist datum krijg. Corresponderend met datum van tabblad.

hier dus

Bedank hem maar!

 

[TiborP]

He dat is makkelijk kan diegene dan nog iets meer uitleggen?

Het is namelijk zo dat ik bij elke "dagtabel" ook de juist datum krijg. Corresponderend met datum van tabblad.

hier dus

Bedank hem maar!

Ik ben een beetje aan het spelen met de code misschien lukt het al wel.

 

[Wigi]

Inderdaad, experimenteer maar verder. :thumb:

Dat is trouwens ook wat ik doe/gedaan heb, geesten ben ik nog niet tegengekomen...