email verzenden met excel gegevens extern bestand

[gast0699]

Goedemiddag,

Ik gebruik:

Sub Mail_ActiveSheet()
'Working in Excel 2000-2016
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm
    Dim FileExtStr As String
    Dim FileFormatNum As Long
    Dim Sourcewb As Workbook
    Dim Destwb As Workbook
    Dim TempFilePath As String
    Dim TempFileName As String
    Dim OutApp As Object
    Dim OutMail As Object

    With Application
        .ScreenUpdating = False
        .EnableEvents = False
    End With

    Set Sourcewb = ActiveWorkbook

    'Copy the ActiveSheet to a new workbook
    ActiveSheet.Copy
    Set Destwb = ActiveWorkbook

    'Determine the Excel version and file extension/format
    With Destwb
        If Val(Application.Version) < 12 Then
            'You use Excel 97-2003
            FileExtStr = ".xls": FileFormatNum = -4143
        Else
            'You use Excel 2007-2016
            Select Case Sourcewb.FileFormat
            Case 51: FileExtStr = ".xlsx": FileFormatNum = 51
            Case 52:
                If .HasVBProject Then
                    FileExtStr = ".xlsm": FileFormatNum = 52
                Else
                    FileExtStr = ".xlsx": FileFormatNum = 51
                End If
            Case 56: FileExtStr = ".xls": FileFormatNum = 56
            Case Else: FileExtStr = ".xlsb": FileFormatNum = 50
            End Select
        End If
    End With

    '    'Change all cells in the worksheet to values if you want
    '    With Destwb.Sheets(1).UsedRange
    '        .Cells.Copy
    '        .Cells.PasteSpecial xlPasteValues
    '        .Cells(1).Select
    '    End With
    '    Application.CutCopyMode = False

    'Save the new workbook/Mail it/Delete it
    TempFilePath = Environ$("temp") & "\"
    TempFileName = "Part of " & Sourcewb.Name & " " & Format(Now, "dd-mmm-yy h-mm-ss")

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    With Destwb
        .SaveAs TempFilePath & TempFileName & FileExtStr, FileFormat:=FileFormatNum
        On Error Resume Next
        With OutMail
            .to = "ron@debruin.nl"
            .CC = ""
            .BCC = ""
            .Subject = "This is the Subject line"
            .Body = "Hi there"
            .Attachments.Add Destwb.FullName
            'You can add other files also like this
            '.Attachments.Add ("C:\test.txt")
            .Send   'or use .Display
        End With
        On Error GoTo 0
        .Close savechanges:=False
    End With

    'Delete the file you have send
    Kill TempFilePath & TempFileName & FileExtStr

    Set OutMail = Nothing
    Set OutApp = Nothing

    With Application
        .ScreenUpdating = True
        .EnableEvents = True
    End With
End Sub

Het bekende van Ron de Bruin, erg handig en gebruik dit al jaren echter heb ik dingen door de jaren heen dingen toegevoegd en nu is de situatie zo dat van de sheet die ik verstuur via de mail er verwijzingen zijn bijgekomen die naar een ander blad in de werkmap verwijzen. Maaromdat ik maar 1 werkblad verstuur krijg ik logischerwijs in het bestand die met de mail wordt verzonden overal de term: #waarde te staan. Is er een manier om de code aan te passen? Ik heb in dit forum al gezocht naar wellicht een licht aan het einde van deze tunnel maar dit kan ik helaas niet vinden.

Groet,

 

[SjonR]

er staat al een stukje code in jouw code die de formules kan wijzigen naar vaste waarden. Die zal je alleen even moeten activeren. Of is dit niet wat je wilt?

 

[HSV]

Maak een kopie van die ene werkblad en zet de formules om naar vaste waarden (values).
Sla het nieuwe bestand op en verstuur het.
Daarna kan je met Kill in de code dat bestand weer verwijderen van je Pc.

 

[VenA]

Ik zou het niet zo ingewikkeld maken.

Sub VenA()
  Dim c00 As String
  c00 = Environ("temp") & "\Part of " & Split(ThisWorkbook.Name, ".")(0) & Format(Now, " dd-mmm-yy hh-mm-ss") & ".xlsx"
  ActiveSheet.Copy
  With ActiveWorkbook
    .Sheets(1).UsedRange = .Sheets(1).UsedRange.Value
    .SaveAs c00, 51
    .Close 0
  End With
  
  With CreateObject("Outlook.Application").createItem(0)
    .to = "ron@debruin.nl"
    .Subject = "This is the Subject line"
    .Body = "Hi there"
    .Attachments.Add c00
    .send 'om Ron blij te maken :-)
  End With
  
  Kill c00
End Sub

 

[HSV]

Ik lees bijna elke dag "het is geen maakvoormij.nl" van dezelfde personen.