En OF Als formule

[Albatros]

Hoi,

Ik word er een beetje draaierig van.
Ik zoek een formule om bij "lijn 1"een a, b, of c te zetten bij respectievelijk < 8 uur , 8 - 16 uur, en > 16 uur productie, en een d, e, f bij lijn 2, met dezelfde uren.
Een voorbeeld staat in de bijlage.
Iemand die de logica ziet en mij kan helpen?
Bekijk bijlage En-OF-Als formule.xlsx
Albatros

 

[HSV]

Kom je hiermee tot het resultaat?

=KIEZEN(G8;ALS(H8>=16;"c";ALS(H8>8;"b";"a"));ALS(H8>=16;"f";ALS(H8>8;"e";"d")))

Zonder je hulpcellen dus.

 

[Ginger]

Nog een optie in een héél andere hoek..

=TEKEN((G8*ALS(H8<=8;1;ALS(EN(H8>8;H8<16);2;3))+96))

=CHAR((G8*IF(H8<=8;1;IF(AND(H8>8;H8<16);2;3))+96))

[EDIT] nu in de ochtend zie ik dat mijn idee toch niet goed werkt... Helaas pindakaas...

 

[MarcelBeug]

Of in H3:J3 alleen de ondergrenswaarden opnemen (0 8 16) en dan

=INDEX($H$4:$J$5;G8;VERGELIJKEN(H8;H3:J3))

Let op: de ondergrens is inclusief dus 8 levert b of e op.

 

[abevleeming]

=INDEX(H4:J5;VERGELIJKEN(G8;G4:G5;0);ALS(H8<=8;1;ALS(H8<=16;2;3)))

Dit zou je vraag moeten oplossen

 

[Ad Becude]

Ik zie hier hele mooie voorbij komen :thumb:

Maar als Albatros gewoon 2 aparte formules had maakt, en ze zou samenvoegen had hij dit resultaat bekomen.

=ALS(G8=1;ALS(H8<8;"A";ALS(H8>16;"C";"B"));ALS(G8=2;ALS(H8<8;"D";ALS(H8>16;"F";"E"));""))

En om te zorgen dat als in G8 of H8 niets staat, er geen waarde in de cel staat:

=ALS(AANTAL(G8;H8)=2;ALS(G8=1;ALS(H8<8;"A";ALS(H8>16;"C";"B"));ALS(G8=2;ALS(H8<8;"D";ALS(H8>16;"F";"E"));""));"")

 

[Albatros]

Geweldig om te zien dat er zoveel interesse is om deze uitdaging voor mij aan te gaan!
Er zijn hier diverse creatieve oplossingen bedacht, om een probleem ook van een andere kant op te lossen.
De verwijzingen naar de tabel vallen in dit geval voor mij af, maar ik bewaar ze voor als ze van pas komen in een later stadium.
Zou ik een "winnaar" moeten kiezen, is er een gedeelde eerste plaats voor Ad Becude en HSV.

Eenieder bedankt voor het meedenken en de aangedragen formule! :thumb:

Albatros

 

[Ginger]

Ha ha ha... Het liet me toch niet los dat mijn idee niet werkte... Daar heb ik dus nog 'ns stevig over nagedacht en ben nu wél tot de perfecte oplossing gekomen....
De grap is dat de aanpassing niet eens zo groot is.

=CHAR(([B][COLOR="#FF0000"](G8*3)-[/COLOR][/B]IF(H8<=8;[B][COLOR="#FF0000"]2[/COLOR][/B];IF(AND(H8>8;H8<16);[B][COLOR="#FF0000"]1[/COLOR][/B];[B][COLOR="#FF0000"]0[/COLOR][/B]))+96))

Het mooie van deze oplossing is dat je nu gewoon verder kan met code 3, 4 enzovoorts (tot het alfabet op is natuurlijk )

 

[MarcelBeug]

...en ben nu wél tot de perfecte oplossing gekomen....

Hij is mooi, wat natuurlijk niets afdoet aan de andere oplossingen...
Persoonlijk vind ik bijvoorbeeld het mooie van #4 dat er geen hard gecodeerde waarden in de formule staan (hoewel je over de G8 van mening kunt verschillen).
Oh, da's de mijne, nou ja whatever

 

[Ginger]

Hij is mooi, wat natuurlijk niets afdoet aan de andere oplossingen

Ahhhh... Zéker niet. Het sloeg in dit geval volledig op mijn eigen herstelde mislukte eerste poging.

 

[HSV]

Hij is mooi Leo. :thumb:

 

[Ginger]

Tnx Harry!