Error 91 bij vullen willekeurige cel

[Jongbloedvos]

Hallo allemaal,

Bijgaand de volgende VBA code

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("G23:G222")).Value = "Akkoord" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbGreen
ElseIf Intersect(Target, Range("G23:G222")).Value = "Vervallen" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbRed
ElseIf Intersect(Target, Range("G23:G222")).Value = "Ingediend" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbYellow
ElseIf Intersect(Target, Range("G23:G222")).Value = "Opgesteld" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbCyan
ElseIf Intersect(Target, Range("G23:G222")).Value = "" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.ColorIndex = 15
ElseIf Intersect(Target, Range("G23:G222")).Value = "Afgekeurd" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbMagenta
End If
End Sub

In principe werkt hij prima voor wat hij moet doen.
Ik krijg alleen een error 91 (objectvariabele of blokvariabele With is niet ingesteld) zodra ik iets wil typen in ELKE andere willekeurige, anders dan "G23:G222"

Ongetwijfeld doe ik iets verkeerd...
Ben nog niet zo handig met VBA.

Kan iemand me helpen met de oplossing?

 

[HSV]

Ik ga je alleen op weg helpen en de code niet uitpluizen en verbeteren.

If [COLOR=#ff0000]Not [/COLOR]Intersect(Target, Range("G23:G222")) [COLOR=#ff0000]is nothing then 
[/COLOR][COLOR=#ff0000]   If target[/COLOR].Value = "Akkoord" Then

 

[jkpieterse]

Wellicht bedoelde je dit:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, Range("G23:G222")) Is Nothing Then Exit Sub
If Target.Value = "Akkoord" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbGreen
ElseIf Target.Value = "Vervallen" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbRed
ElseIf Target.Value = "Ingediend" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbYellow
ElseIf Target.Value = "Opgesteld" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbCyan
ElseIf Target.Value = "" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.ColorIndex = 15
ElseIf Target.Value = "Afgekeurd" Then
Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = vbMagenta
End If
End Sub

 

[HSV]

Je hebt maar één keer de 'intersect' nodig en dan voor de rest zou ik 'select case target' doen

 

[Jongbloedvos]

Hallo,

beide codes werken perfect nu!
Zowel met 'intersect' als met 'select case target'

Is er een bepaalde reden voor om te kiezen voor 'select case target'?
Misschien kan ik er iets van leren.

bedankt in ieder geval voor de hulp! Super zeg!

 

[edmoor]

Select Case maakt het beter leesbaar, kan eenvoudiger worden uitgebreid en als de range moet worden aangepast hoeft dat op maar 1 regel:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("G23:G222")) Is Nothing Then
        Select Case Target.Value
            Case "Akkoord":     Kleur = vbGreen
            Case "Vervallen":   Kleur = vbRed
            Case "Ingediend":   Kleur = vbYellow
            Case "Opgesteld":   Kleur = vbCyan
            Case "Afgekeurd":   Kleur = vbMagenta
            Case "":            Kleur = 16777215
        End Select
        Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = Kleur
    End If
End Sub

 

[HSV]

En 'select case' springt de rest van de code over als de waarde is gevonden.

xlnone kan je ook gebruiken bij (leeg) ""

Hier nog een oneliner.

Private Sub Worksheet_Change(ByVal Target As Range)
 If Not Intersect(Target, Range("G23:G222")) Is Nothing Then Sheets(Format(Target.Offset(, -6), "00")).Tab.Color = Switch(Target = "Akkoord", vbGreen, Target = "Vervallen", vbRed, Target = "Ingediend", vbYellow, Target = "Opgesteld", vbCyan, Target = "Afgekeurd", vbMagenta, Target = "", xlNone, Target <> "", xlNone)
End Sub

 

[Jongbloedvos]

Ah oke, bedankt!
Weer wat geleerd.

groeten

 

[VenA]

Heb je een nieuw account aangemaakt? Of zijn jullie met hetzelfde project bezig?
https://www.helpmij.nl/forum/showthread.php/951011-Kleur-veranderen-tabblad-wanneer-op-een-ander-tabblad-een-cel-wordt-gevuld

 

[Jongbloedvos]

Scherp opgemerkt!
Ik zat op kantoor, en uiteraard had ik mijn wachtwoord weer nergens opgeslagen... as always

Dus maar even een nieuw account aangemaakt, kan mijn compagnon ook meteen een vraag stellen als het nodig is.

Groeten

 

[jkpieterse]

Select case is in dit geval ook sneller omdat je niet telkens de waarde uit de cel leest maar maar één keer.

 

[Jongbloedvos]

Dank voor de tip, ik heb het aangepast naar "select case"!
Werkt super!