Excel automatisch betalingsherinnering laten mailen

[safe]

Hallo allemaal,

Om meer automatisering in mijn debiteurenbeheer te creëren was ik op zoek naar een oplossing om automatisch een herinneringsbrief te sturen naar klanten waarbij de betalingstermijn van 30 dagen is overschreden. Om mijn uitleg wat makkelijker te houden heb ik een voorbeeld toegevoegd met daarin wat meer tekst en uitleg over mijn wensen.

Ik stuitte al op diverse forums met een tal van mogelijkheden, maar ik kon er niet eentje vinden die voldeed naar mijn verwachtingen.

Willen jullie brainstormen in mijn voorbeeld? Bekijk bijlage Voorbeeld.xlsm

Ik ben benieuwd of dit praktisch haalbaar is.
Alvast bedankt !!:d:d

M.vr.gr.
Safe

 

[Warme bakkertje]

Ik veronderstel dat je dit bestand dagelijks opent ?
Waarom dan niet in Workbook_Open een macro die kolom P doorloopt op verlopen items en dan je herinneringsmacro starten ?

 

[safe]

Is inderdaad een optie, aangezien de macro pas moet gaan werken als het getal 30 in een cel staat. Aan het einde van de macro dient hij dan wel de inhoud van de betreffende cel te veranderen. (mocht het excelbestand vaker geopend worden op dezelfde dag) Ik weet alleen helaas niet hoe ik dit in m'n macro's moet verwerken.

Zou je mij hierin willen toelichten?

M.vr.gr.
Safe

 

[cow18]

gebruik gewoon de kolom O om aan te geven of er al een mail verzonden is. Schrijf daar bv. tijdstip in waarop je de mail verstuurde.
Als je de volgende keer opent en iets staat al meer dan 30 dagen open zonder dat er een herinnering gestuurd werd, dan ben je aan de beurt.

 

[Warme bakkertje]

Onderstaande in ThisWorkBook.

Public mailadres As String
Public facnummer As String
Public saldo As Double
Private Sub Workbook_Open()
    With Sheets("Blad1")
        For Each cl In .Range("M5:M" & .Cells(Rows.Count, 13).End(xlUp).Row)
            If cl.Value <= Date - 30 And cl.Offset(, 2) = vbNullString And cl.Offset(, -1) <> 0 Then
                mailadres = cl.Offset(, -4): facnummer = cl.Offset(, -10): saldo = cl.Offset(, -1)
                AutomatischeHerinneringsmail30dagen
                cl.Offset(, 2) = "Verzonden"
            Else
            End If
        Next
    End With
End Sub

Je mailmacro ziet er dan als volgt uit.

Sub AutomatischeHerinneringsmail30dagen()
 
    strbody = "<P>" & "Geachte heer/mevrouw," & "</P>" & _
    "Uit onze administratie is gebleken dat u onze factuur met factuurnummer." & ThisWorkbook.facnummer & " nog niet heeft voldaan." & "<br>" & _
    "Wij verzoeken u het openstaande bedrag van " & ThisWorkbook.saldo & " <br> " & "binnen 5 dagen te hebben voldaan o.v.v. uw factuurnummer." & _
    "<br><br>" & "Met vriendelijke groet," & "<br><br>" & "AAA."

    'Change only Mysig.htm to the name of your signature
    SigString = Environ("appdata") & _
     "\Microsoft\Handtekeningen\AAA.htm"

    Signature = IIf(Dir(SigString) <> "", GetBoiler(SigString), "")

    On Error Resume Next
    With CreateObject("Outlook.Application").CreateItem(0)
        .To = ThisWorkbook.mailadres
        .CC = ""
        .BCC = ""
        .Subject = "factuur. ( factuurnummer : " & ThisWorkbook.facnummer & " )"
        .HTMLBody = strbody & "<br><br><br><br>" & Signature
        .SendUsingAccount = .Session.Accounts.Item(2)
        .Display
    End With
    On Error GoTo 0
End Sub

Er wordt nu gekeken naar de datum in kolom M. Als deze kleiner is dan de datum van vandaag - 30 dagen, en als kolom O (waar de melding van verstuurde mail komt) leeg is en als het saldo van bedrag en betaling niet 0 is wordt de mailmacro gestart. Daarna wordt in kolom O de melding Verzonden geplaatst.
Je hebt kolom P en ook cel I1 met de datum van vandaag dus niet meer nodig.

 

[safe]

Warme Bakkertje you did it again !!!!:d

Superrr!!! Hier ben ik enorm blij mee !!:thumb:
Je hebt het precies zo gedaan zoals ik het mij had voorgesteld.

Nogmaals bedankt voor je hulp, echt top !!

M.vr.gr.
Safe.