Excel formule voor gestaffelde commissie

[klad]

Beste forumleden,

Is het mogelijk om in Excel 365 een formule te maken voor het berekenen van een gestaffelde commissie?

Het gaat om het volgende schema:

€ 1 - € 24 = 12,5 %
€ 25 - € 74 = 12,5% + € 0.75
€ 75 - € 149 =12,5% + € 1
€ 150-€ 299 = 12,5% + € 2
€ 300-€ 499 = 12,5% + € 3
€ 500 - € 999 - 12,5% + € 5
€ 1000+ = 12,5% + € 10

Voor het gemak wordt deze formule berekend in cel B, gebaseerd op de inhoud van cel A. Is cel A leeg, dan blijft B leeg; is cel A ingevuld, dan wordt de formule berekend zoals bovenstaand schema.

Ik hoop dat dit te realiseren is!

 

[AHulpje]

=0,125*A1+ALS(A1>=1000;10;ALS(A1>=500;5;ALS(A1>=300;3;ALS(A1>=150;2;ALS(A1>=75;1;ALS(A1>=25;0,75;0))))))

 

[Enigmasmurf]

Of, makkelijker achteraf aan te passen, met een tabelletje op Blad2.

 

[roeljongman]

In essentie heb ik dezelfde oplossing als Enigmasmurf, maar ik had mijn bericht al getypt en ik gebruik functie X.ZOEKEN() ipv vert zoeken
________________

je tabel bevat gaten..
wat doe je als een waarde uitkomt op 24,50? dan valt hij niet in 1-24 en ook niet in 25 tm 74

Je hebt dus een tabel nodig en met X.ZOEKEN() kun je zorgen dat de juiste extra toeslag wordt berekent als een staffelgrens wordt bereikt. hiervoor heb je geen van tot en met tabel nodig voor excel, en ontstaan er ook geen gaten.

Dit is de formule die ik heb gebruikt
=F1*(1+B1)+X.ZOEKEN(F1;$A$3:$A$9;$B$3:$B$9;0;-1)

F1 bevat de het bedrag
B1 bevat de 12,5%
dan de zoekwaarde, zoekkolom en resultaatkolom.
de -1 zorgt dat X.ZOEKEN() niet alleen bij exacte overeenkomst een waarde geeft maar altijd een waarde toont zolang de waarde in F1 kleiner is dan de volgende rij (in Vert,zoeken is dat de 1 of WAAR als 3e parameter)

 

[AlexCEL]

Nog een optie:

=12,5%*A1+KIEZEN(VERGELIJKEN(A1;{0;25;75;150;300;500;1000};1);0;0,75;1;2;3;5;10)

 

[klad]

Dank voor alle reacties. De eerste formule werkt voor mij op zich wel; behalve dat de cel niet leeg blijft als er in A nog niets is ingevuld. Kan dit nog worden toegevoegd?


Wat betreft het 'gat' in de berekeningen: er komen uitsluitend afgeronde getallen in voor. Ik hoef daar dus geen rekening mee te houden, en mijn document heeft al vrij veel tabbladen. Mijn voorkeur gaat dan ook uit om het direct in de cel in een formule te verwerken.

Als de staffel in de toekomst wijzigt kan ik de formules ook weer vrij eenvoudig in 1x kopiëren.

 

[klad]

Aanvulling: het is me intussen wel gelukt om de cel leeg te laten. In mijn werkblad had ik een typefout waardoor het eerst niet werkte.

Bedankt voor alle hulp!