Excel Overloop bij regels tellen

[PaulMak]

Goede avond Excelspecialisten,

Ik krijg een overloop fout bij het tellen van regels (meer dan 55700)
Voor het bijwerken van een bestand gebruik ik een macro die een formule in B2 kopieert naar laatst gebruikte regel in mijn bestand.

Echter, er blijkt een limiet aan het aantal regels te zitten.

Wie kan mij helpen om te laten tellen tot bijvoorbeeld de maximale regel die Excel aankan?

Dit is mijn macro:

Sub RijenTeller()
Application.ScreenUpdating = False
With Sheets("Blad1")
Dim aantal As Integer
aantal = Sheets("Blad1").UsedRange.Rows.Count
Range("Blad1!B1") = aantal
End With
Application.ScreenUpdating = True



Range("B2:C2").Select
Selection.Copy
Application.CutCopyMode = False
Selection.AutoFill Destination:=Range("B2:C" & aantal)
Range("B2:C" & aantal).Select


End Sub

 

[puppie]

Verplaatst van memberchat naar het excel forum.

 

[HSV]

Volgens mij heb je de overloop al bij 32768.

Dim aantal As long

 

[edmoor]

32767 is inderdaad de max voor een Integer
Gebruik deze, dan heb je geen variabele nodig:

    With Sheets("Blad1")
        .Range("B1") = .UsedRange.Rows.Count
    End With

 

[VenA]

Als het alleen gaat om B2:C2 door te trekken t/m de laatste gebruikte rij dan kan je ook deze gebruiken

Sub VenA()
With Sheets("Blad1")
    .Range("B2:C2").AutoFill .Range("B2:C" & .UsedRange.Rows.Count)
End With
End Sub

 

[snb]

En als je van het gebied een tabel maakt (VBA: Listobject) gebeurt het automatisch en is geen enkele VBA regel nodig (laat staan variabele).

 

[PaulMak]

Super maar dan ook super bedankt !!

Ik wil graag puppie, HSV, edmoor, VenA en snb bedanken voor jullie hulp !!

Ik heb mijn macro aangepast met uiteindelijk de complete Sub van VenA.
Natuurlijk had edmoor al de oplossing die paste bij mijn huidige macro en VenA maakte het daar bovenop ook nog eens compleet door de functie in B2 en C2 direct mee nemen.

Hierdoor is mijn macro aanzienlijk korter en nog belangrijker ... het rapport voor mijn werk super betrouwbaar!

Dank jullie wel !

ps. Helpmij ... ook jullie bedankt voor dit platform !!
:d

 

[MarcelBeug]

En vanwege het grote aantal regels heeft Microsoft CountLarge uitgevonden...

 

[PaulMak]

Hey Marcel, ook bedankt voor jouw reactie.

Kan ik die functie wél gebruiken om bijvoorbeeld een integer een waarde mee te geven?

 

[HSV]

Test het, en je weet het.

msgbox range("a1:e5").countlarge
msgbox range("a1:e2").countlarge
msgbox range("a1:a5").countlarge
msgbox range("a1:b5").countlarge

 

[MarcelBeug]

Voor zover ik weet heb je een Long nodig.