Excel Sheet opslaan als afbeelding

[sanders1969]

Ik wil een sheet van een excel bestand opslaan als afbeelding en ik heb online al wat gevonden.
Alleen maakt ie er een chart van en ik wil gewoon dat ie een snapshot maakt van de sheet.
Ik krijg uiteraard de data wel in beeld alleen staan er grafiek gegevens onderin.
Ik weet niet of iemand een soortgelijke oplossing hebben gebouwd.
Onderstaande is de code om de sheetgegevens te kopieren naar een grafiek en vanaf daar wordt een afbeelding gemaakt.
Nogmaals ik wil geen grafiek alleen de sheetgegevens in een afbeelding krijgen.

Sub Export()
Dim ws As Worksheet
Dim Rng As Range
Dim Chrt As Chart
Dim ExportPath As String

Set ws = ActiveSheet
Set Rng = ws.Range("B2:H11")
ExportPath = ThisWorkbook.Path & "\Case.jpg"

Set Chrt = ThisWorkbook.Charts.Add
Rng.CopyPicture xlScreen, xlBitmap   

With Chrt
    .Paste
    .Export FileName:=ExportPath, Filtername:="JPG"
End With
End Sub

 

[jkpieterse]

Misschien gewoon exporteren naar PDF?

 

[sanders1969]

Hoi,

Nee en ik had wat duidelijker moeten zijn.
De gehele sheet is niet interessant alleen een deel van deze sheet dus via een range werk ik.
Sorry anders was idd de pdf optie handig.

 

[Excelbat]

Ik heb dit in een bestandje. Hiermee zou je verder kunnen stoeien:

Worksheets("TabEen").PivotTables("PivotTabEen").TableRange2.CopyPicture Appearance:=xlScreen, Format:=xlPicture
Application.GoTo (Worksheets("TabEen").Range("B10"))
Worksheets("TabEen").Paste

Greetz/Excelbat

 

[snb]

Die grafiek is alleen maar een tijdelijk hulpmiddel om de afbeelding op te slaan.

Sub M_snb()
  With Sheet1.Range("B2:H11")
    .CopyPicture
     
    With Sheet1.ChartObjects.Add(0, 0, .Width, .Height).Chart
      .Paste
      .Export ThisWorkbook.Path & "\Case.jpg"
      .Parent.Delete
    End With
  End With
End Sub

 

[jkpieterse]

Je kunt ook alleen een range als pdf doen vlgs mij

 

[sanders1969]

Beste Pieterse

Dankje voor de tip en de rest uiteraard ook voor het meedenken. De pdf variant vind ik de fraaiste.

strFileName = ThisWorkbook.Path & "\snapshot1.pdf"
ActiveSheet.Range("A1:F15").ExportAsFixedFormat Type:=xlTypePDF, FILENAME:=strFileName, Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=True