For...Next lus probleem

[Eggie]

Hallo,

ik heb een code geschreven en daarbij gebruik gemaakt van de for...next lus.

Het probleem is echter dat dit erg lang duurt, aangezien de data sheet uit +- 20.000 regels bestaat.

Weet iemand een manier om dit probleem te omzeilen?

Hieronder nog even ter info een gedeelte van de code.

Alvast bedankt! Mvg,

Eggie

Dim Cel As Range
Dim ShipmentRangeCountDATA As Integer
    
    ShipmentRangeCountDATA = Sheets(6).Range(Range("a2"), Range("a2").End(xlDown)).Rows.Count


For Each Cel In Range("L2:L" & ShipmentRangeCountDATA + 1)
    If Cel.Offset(0, -2).Range("A1").Value = "" Then Cel.Value = 1
    If Cel.Offset(0, -9).Range("A1").Value <> Cel.Offset(-1, -9).Range("A1").Value Then Cel.Value = 1
    Next

 

[Wigi]

Betaal je mij 1 pint per 5 seconden tijdswinst?

Sub ddd()

    Dim Cel As Range
    Dim ShipmentRangeCountDATA As Integer
    
    With Application
        .ScreenUpdating = False
        .Calculation = xlCalculationManual
    End With
    
    ShipmentRangeCountDATA = Sheets(6).Range(Range("a2"), Range("a2").End(xlDown)).Rows.Count
    
    With Range("L2:L" & ShipmentRangeCountDATA + 1)
        .Formula = "=IF(OR(RC[-2]="""",RC[-9]<>R[-1]C[-9]),1,"""")"
        .Value = .Value
    End With
    
    With Application
        .ScreenUpdating = True
        .Calculation = xlCalculationAutomatic
    End With

End Sub

Wigi

 

[Eggie]

haha, dat wordt een aardige rekening dan ...

Deze oplossing werkt perfect, bedankt!!!!

Eggie