Formule cel splitsen op basis van _

[JelleN]

Goedemorgen,

Kan iemand een formule geven voor het splitsen van een waarde in een cel.
FNH_S691_31 staat in cel A1.
Ik wil graag in cel B1: S691

Een andere code zou zijn:
FCG_523_31
Dan wil ik 523 in de volgende cel.

splitsen op basis van aantal karakters lijkt me niet mogelijk omdat dit verschillend is per code.
Lijkt me eerder te splitsen op basis van _ . (met een formule want dit moet ik één keer)

GR. Jelle

 

[JEC.]

=index(textsplit(a1;"_");;2)

 

[JEC.]

Of matrix formule voor oudere versies

=FILTERXML("<x><y>"&SUBSTITUTE(A1;"_";"</y><y>")&"</y></x>";"//y[2]")

 

[AlexCEL]

Of als je geen Excel 365 gebruikt:

=DEEL(A1;1+VIND.SPEC("_";A1);VIND.SPEC("_";A1;VIND.SPEC("_";A1)+1)-VIND.SPEC("_";A1)-1)

Of, als het eerste deel van de code wel altijd 3 letters bevat:

=LINKS(VERVANGEN(A1;1;4;"");VIND.SPEC("_";VERVANGEN(A1;1;4;""))-1)

Power Query kan ook gemakkelijk tekst splitsen, ook in eerdere Excel versies dan 365.

En tenslotte nog een Excel 365 oplossing:

=TEKST.VOOR(TEKST.NA(A1;"_");"_")

 

[AlexCEL]

Opgelost? Mooi.

Nog eentje voor de gein:

=SPATIES.WISSEN(DEEL(SUBSTITUEREN(A1;"_";"     ");5;9))

 

[JelleN]

Bedankt voor de reacties.
Probleem is opgelost.

GR. Jelle

 

[snb]

Function F_snb(c00)
  F_snb=split(c00,"_")(1)
End Function

In B1 :

=F_snb(A1)