formule haal bestandsnaam uit volledig path

[sjonnie1974]

Hoi,

p:\testmap\collega\rooster.xls

Bovenstaand path en filename is als voorbeeld
Ik wil graag een formule die de bestandsnaam apart in een cel zet.
De bestandsnaam staat uiteraard altijd achter de laatste \ , maar kan altijd anders zijn.

Wie o wie heeft de formule voor mij?

 

[rebmog]

Kijk eens of deze matrixformule (ingeven met Ctrl+Shift+Enter) je verder helpt:

=DEEL(A1;MAX(ALS(DEEL(A1;RIJ(INDIRECT("1:"&LENGTE(A1)));1)="\";RIJ(INDIRECT("1:"&LENGTE(A1)))))+1;1000)

 

[sjonnie1974]

Euh Sorry, maar heb je hem toevallig ook in het engels?

 

[rebmog]

Zeker:

=MID(A1;MAX(IF(MID(A1;ROW(INDIRECT("1:"&LEN(A1)));1)="\";ROW(INDIRECT("1:"&LEN(A1)))))+1;1000)

 

[sjonnie1974]

Neen, deze formule zet precies hetzelfde neer als wat in A1 staat

 

[rebmog]

Nee hoor. Heb je de formule wel afgesloten met Ctrl+Shift+Enter? Er verschijnen dan automatisch accolades om de formule ten teken dat het om een matrixformule gaat.

 

[edmoor]

Probeer deze eens:

=TRIM(RIGHT(SUBSTITUTE(A1,"\";REPT(" ";100));100))

Ik kan het hier even niet testen omdat ik geen Engelse office versie meer voorhanden heb.

 

[sjonnie1974]

deze formule geeft foutmelding, kan dus niet "berekenen"

 

[popipipo]

=TRIM(RIGHT(SUBSTITUTE(A1;"\";REPT(" ";100));100))

Probeer het hier eens mee


@ Edmoor
Jouw oplossing pas gezien nadat ik dit gepost had.
Bijna het zelfde op de 'komma' of 'puntkomma' na achter A1

Deze zal het wel doen.

 

[edmoor]

Ik had dus ergens een , staan waar een ; hoort te staan.
popipipo heeft 'm wel goed.

Voor de geïnteresseerden is dit de Nederlandse versie:

=SPATIES.WISSEN(RECHTS(SUBSTITUEREN(A1;"\";HERHALING(" ";100));100))

@popipipo:
Ik zag het pas nadat TS meldde dat de formule een fout gaf.
Had geen nut het aan te passen omdat jij de juiste al had staan

@sjonnie:
Wellicht dat je hier ook iets aan hebt:
http://www.piuha.fi/excel-function-name-translation/index.php?page=nederlands-english.html

 

[rebmog]

deze formule geeft foutmelding, kan dus niet "berekenen"

Ik heb maar even een voorbeeldje gemaakt waarin je kunt zien dat 'mijn' formule volgens mij wel goed werkt. Ik heb hierin ook de formules van popipipo/edmoor opgenomen. Aangezien deze laatste formule korter is en geen matrixformule, zou ik overigens wel adviseren om deze laatste formule te gebruiken.

 

[edmoor]

Die formule heb ik ook niet zelf bedacht maar vind 'm wel net zo simpel als inventief
Zoek het laatste \ teken, vervang alles voor dat teken door spaties en haal vervolgens de spaties weg.

 

[sjonnie1974]

Heren, allemaal weer bedankt, de formules in het voorbeeld werken idd! Fijn dat julli zo supersnel met antwoorden komen!

Thnx!