formule korter schrijven

[bowlingman]

Hallo,
Kan de volgende formule ook korter geschreven worden

=ALS($H$1=1;VERT.ZOEKEN($B$5;Speeldag01;17;0);
ALS($H$1=2;VERT.ZOEKEN($B$5;Speeldag02;17;0);
ALS($H$1=3;VERT.ZOEKEN($B$5;Speeldag03;17;0);
ALS($H$1=4;VERT.ZOEKEN($B$5;Speeldag04;17;0);
ALS($H$1=5;VERT.ZOEKEN($B$5;Speeldag05;17;0);
ALS($H$1=6;VERT.ZOEKEN($B$5;Speeldag06;17;0);
ALS($H$1=7;VERT.ZOEKEN($B$5;Speeldag07;17;0);
ALS($H$1=8;VERT.ZOEKEN($B$5;Speeldag08;17;0);
ALS($H$1=9;VERT.ZOEKEN($B$5;Speeldag09;17;0);
ALS($H$1=10;VERT.ZOEKEN($B$5;Speeldag10;17;0);
ALS($H$1=11;VERT.ZOEKEN($B$5;Speeldag11;17;0);
ALS($H$1=12;VERT.ZOEKEN($B$5;Speeldag12;17;0);
ALS($H$1=13;VERT.ZOEKEN($B$5;Speeldag13;17;0);
ALS($H$1=14;VERT.ZOEKEN($B$5;Speeldag14;17;0);
ALS($H$1=15;VERT.ZOEKEN($B$5;Speeldag15;17;0);
ALS($H$1=16;VERT.ZOEKEN($B$5;Speeldag16;17;0);
ALS($H$1=17;VERT.ZOEKEN($B$5;Speeldag17;17;0);
ALS($H$1=18;VERT.ZOEKEN($B$5;Speeldag18;17;0);
ALS($H$1=19;VERT.ZOEKEN($B$5;Speeldag19;17;0);
ALS($H$1=20;VERT.ZOEKEN($B$5;Speeldag20;17;0);
ALS($H$1=21;VERT.ZOEKEN($B$5;Speeldag21;17;0);
ALS($H$1=22;VERT.ZOEKEN($B$5;Speeldag22;17;0);
ALS($H$1=23;VERT.ZOEKEN($B$5;Speeldag23;17;0);
ALS($H$1=24;VERT.ZOEKEN($B$5;Speeldag24;17;0);
ALS($H$1=25;VERT.ZOEKEN($B$5;Speeldag25;17;0);
ALS($H$1=26;VERT.ZOEKEN($B$5;Speeldag26;17;0);
ALS($H$1=27;VERT.ZOEKEN($B$5;Beker1;17;0);
ALS($H$1=28;VERT.ZOEKEN($B$5;Beker2;17;0);
ALS($H$1=29;VERT.ZOEKEN($B$5;Beker3;17;0);
ALS($H$1=30;VERT.ZOEKEN($B$5;Beker4;17;0);
ALS($H$1=31;VERT.ZOEKEN($B$5;Kampioenschappen01;17;0);
ALS($H$1=32;VERT.ZOEKEN($B$5;Kampioenschappen02;17;0);
ALS($H$1=33;VERT.ZOEKEN($B$5;Kampioenschappen03;17;0);
ALS($H$1=34;VERT.ZOEKEN($B$5;Kampioenschappen04;17;0);
ALS($H$1=35;VERT.ZOEKEN($B$5;Kampioenschappen05;17;0);
ALS($H$1=36;VERT.ZOEKEN($B$5;Kampioenschappen06;17;0);
ALS($H$1=37;VERT.ZOEKEN($B$5;Kampioenschappen07;17;0);
ALS($H$1=38;VERT.ZOEKEN($B$5;Kampioenschappen08;17;0);
ALS($H$1=39;VERT.ZOEKEN($B$5;Kampioenschappen09;17;0);
ALS($H$1=40;VERT.ZOEKEN($B$5;Kampioenschappen10;17;0);))))))))))))))))))))))))))))))))))))))))

Grtjs.
Armand

 

[WoutMag]

Plaats in een vrije cel de formule bijvoorbeeld I1

=ALS(EN(H1>=1;H1<=26);"Speeldag"&TEKST(H1;"00");ALS(EN(H1>=27;H1<=30);"Beker"&TEKST(H1-26;"00");"Kampioenshappen"&TEKST(H1-30;"00")))

Kort je eigen formule in tot:

=ALS($H$1=34;VERT.ZOEKEN($B$5;INDIRECT(I1);17;0))

Je kan ook deze twee samenvoegen tot:

=ALS($H$1=34;VERT.ZOEKEN($B$5;INDIRECT(ALS(EN(H1>=1;H1<=26);"Speeldag"&TEKST(H1;"00");ALS(EN(H1>=27;H1<=30);"Beker"&TEKST(H1-26;"00");"Kampioenshappen"&TEKST(H1-30;"00"))));17;0))

Succes,

 

[jkpieterse]

Weet wel dat INDIRECT een "volatiele" functie is, dus de cel met deze functie (en alle cellen die naar deze verwijzen) zullen altijd herberekenen. Ook bij bestand openen, dus voortaan vraagt Excel bij je bestand altijd om wijzigingen op te slaan, ook als je er niets in hebt "gedaan".

 

[bowlingman]

Hallo,
Bedankt voor de snelle reactie.
Heb het juist geprobeert.
Als ik in cel H1 "34" zet werkt het perfect, als daar "1" of een ander getal tussen 1 en 40 zet krijg ik "onwaar"
Heb wel even mijn ingestuurde formule aangepast, de laatste vier moesten 37 t/m 40 zijn en niet allemaal 34

Grtjs.
Armand

 

[VenA]

Er staat je toch niets in de weg om het document even te plaatsen?

 

[AlexCEL]

Het stukje "=ALS($H$1=34;..." uit post #2 is overbodig geworden door jouw wijzigingen t.o.v. de originele vraag.

Beetje gemodificeerde versie wordt dan:

=ALS.FOUT(VERT.ZOEKEN(B5;INDIRECT(ALS(H1<=26;"speeldag"&TEKST(H1;"00");ALS(H1<=30;"beker"&H1-26;"kampioenschappen"&TEKST(H1-30;"00"))));17;0);"foutmelding")

 

[bowlingman]

Hallo alle meedenkers/werkers

Super bedankt voor jullie reactie
@Alex
Werkt perfect nu. Stom van mij dat ik de formule in post 1 niet eerst had verbeterd vooralleer ze te plaatsen.
Waarschijnlijk had Wout dan al de goede voorzet gegeven.
Ik heb wel nog "foutmelding" vervangen door "", zodat de lege cellen leeg blijven.

@VenA
Sorry, dacht dat het zou lukken zonder voorbeeldfile.

Grtjs.
Armand