Formule met functie FILTER, ISGETAL en ZOEKEN

[Marihilgerdenaar]

Hallo allemaal.
Ik probeer een formule te maken met de functies, filter, isgetal en zoeken, maar ik krijg een foutmelding #WAARDE!

Mijn dataset is:

	A	B
1	Appel	1
2	Banaan	2
3	Peer	3
4	Appelsap	4

Mijn formule is
=FILTER(A1:B4;ISGETAL(ZOEKEN("Appel";A1:A4;1)))

Ik verwacht de uitkomst:

Appel	1
Appelsap	4

Ik krijg de foutmelding:

#WAARDE!

Iemand enig idee wat ik hier fout doe?

 

[edmoor]

Plaats een voorbeeld documentje.

 

[Marihilgerdenaar]

Hierbij het voorbeeld bestandje

 

[edmoor]

Wijzig ZOEKEN in VIND.SPEC:

=FILTER(A1:B4;ISGETAL(VIND.SPEC("Appel";A1:A4;1)))

 

[Marihilgerdenaar]

Super fijn! Deze werkt inderdaad wel
Is het wellicht mogelijk om de lijst te creëren op basis van verschillende tabellen/bereiken?
A1:B4 & D1:E4

 

[lam201]

dat kan zo

=LET(data;VERT.STAPELEN(A1:B4;D1:E4);
F;ISGETAL(VIND.SPEC(N5;INDEX(data;;1)));
FILTER(data;F;"Geen data"))

met in N5 de zoekwaarde. "Appel" bijvoorbeeld.

 

[Marihilgerdenaar]

Hartelijk bedankt voor het antwoord! Ik ben alleen niet helemaal duidelijk geweest in mijn voorbeeld; ik probeer hem nu in mijn eigen bestand te kopiëren en krijg een foutmelding.

In mijn eigenlijke bestand moet ik op verschillende tabbladen data doorzoeken en alles met een specifieke omschrijving vinden. In mijn voorbeeld wil ik lijstje met de personen met de functie EXPEDITIE en de datum die daarachter staat.

Is het mogelijk om dit zonder een LET formule te maken?

 

[edmoor]

Als je zegt een foutmelding te krijgen is het altijd wel zo handig deze er ook bij te vermelden.

 

[lam201]

Die formule wordt niet heelveel anders.

=LET(data;VERT.STAPELEN('Tab1'!A2:C4;'Tab2'!A2:C4;'Tab3'!A2:C4);
FILTER(data;INDEX(data;;2)="Expeditie";"Geen data"))

of zonder LET

=FILTER(VERT.STAPELEN('Tab1'!A2:C4;'Tab2'!A2:C4;'Tab3'!A2:C4);INDEX(VERT.STAPELEN('Tab1'!A2:C4;'Tab2'!A2:C4;'Tab3'!A2:C4);;2)="Expeditie";"Geen data"))

 

[lam201]

beter nog maak je van de gegevens in Tab1,2 en 3 echte Tabellen.
als je nieuwe gegevens toevoegd, worden deze gelijk in je filter functie meegenomen.

je formule wordt dan

=LET(data;VERT.STAPELEN(Table1;Table2;Table3);
FILTER(data;INDEX(data;;2)="Expeditie";"Geen data"))

 

[Marihilgerdenaar]

@edmoor, excuses dat is inderdaad niet handig.
@lam201, Ah super fijn, dat is inderdaad nog beter! Dankjewel
Is er ook nog een mogelijkheid - dat is volgens mij echt mijn laatste vraag - om alle waardes met 'Expeditie' te vinden. In plaats van specifiek het woord 'Expeditie'. Dit lukt me met de formule op 1 tabblad, maar nu is de formule helemaal anders

Enorm bedankt allemaal

 

[lam201]

=LET(data;VERT.STAPELEN(Table1;Table2;Table3);
F;ISGETAL(VIND.SPEC("expeditie";INDEX(data;;2)));
FILTER(data;F;"Geen data"))

 

[Marihilgerdenaar]

Geweldig! Het is gelukt en ben weer stuk wijzer geworden.
Dankjewel!