Formule om gegevens over te nemen uit ander tabblad (2 voorwaarden)

[Flowiris]

Dag allemaal,

Zie voorbeeld bestand in bijlage.
Ik zoek een formule om ervoor te zorgen dat op blad 1 de gegevens komen uit de andere tabbladen.
Voorwaarde 1 = zoek de waarde binnen het tabblad dat overeenstemt met cel B2
Voorwaarde 2 = zoek binnen dat tabblad de waarde van het bedrijf dat overeenstemt met cel C2

Bv. Als ik de resultaten wil van 2024 voor bedrijf G, moet hij die overnemen van tabblad 3 , kolom H4;H32

 

[AlexCEL]

Een optie:

=INDIRECT(ADRES(RIJ();VERGELIJKEN($C$2;INDIRECT("'"&$B$2&"'!A2:K2");0);;;$B$2))

Let op dat geen spaties achter bedrijfsnamen staat... (zoals bij 2023 bedrijf D).

Opmaak (locatie) van de rijen moet gelijk zijn op alle tabbladen, anders is aanpassing nodig. Dus bijv. "financiële kosten" moet overal op rij 22 staan.

 

[Warme bakkertje]

Ik heb een iets andere formule gebruikt omdat je met de formule van @AlexCEL enkel bedrijven tot kolom Z kan invullen. Ga je verder dan krijg je een foutmelding.
Selecteer BEDRIJF Z (staat in kolom AA) in de datavalidatie om dit aan te tonen.

 

[Flowiris]

Dag Rudi

Bedankt!
Maar de formule werkt dan wel enkel als ALLE bedrijven naast mekaar staan?
Niet voor bedrijf K - P die eronder staan?

 

[Warme bakkertje]

Oeps, die had ik niet opgemerkt.
De makkelijkste oplossingen zijn ofwel alle bedrijven naast elkaar zetten zoals je al zelf opgemerkt hebt of op Blad1 een extra blokje onder het andere het andere zetten en de formule dan aanpassen maar ik veronderstel dat je graag je huidige opzet wilt behouden.
Ik wil wel eens kijken of we de bestaande formule kunnen aanpassen maar er zijn hier formule experten die dat waarschijnlijk beter kunnen dan ik. Laat nog iets horen.

 

[Warme bakkertje]

Denk dat ik er ben. Nu is het wachten op de experts om een mooiere formule te bouwen.

 

[AlexCEL]

De formules worden wel heel ingewikkeld door de niet-gebruikersvriendelijke opzet van de gegevens. Ik heb gekozen voor een verzamelblad waarop alle gegevens samenkomen. Dan kun je met een simpele INDEX/VERGELIJKEN alles opzoeken, zonder INDIRECT e.d.

Voor mogelijk meer oplossingen: welke Excel versie gebruik je?
En is Power Query een optie?

 

[globe]

Ik heb een andere benadering gevolgd.

Ik laat eerst zoeken naar de naam van het tabblad en pas dan de zoekfunctie toe:

=VERT.ZOEKEN(B4;INDIRECT("'"&$B$2&"'!A:Z");VERGELIJKEN($C$2;INDIRECT("'"&$B$2&"'!2:2");0);ONWAAR)

plak deze formule in cel C4 van Blad 1 en trek hem door waar je wilt.

 

[AlexCEL]

Heb je de tweede rij met bedrijven (bedrijf K t/m P) ook gezien?

 

[JEC.]

Hier eentje met alle output in ene

=LET(
t;HSTACK('Resultaten 2023:Resultaten 2025'!A2:K67);
z;HSTACK(TAKE(t;31);TAKE(t;-31));
y;SCAN("";TAKE(z;1);LAMBDA(a;b;IF(LEFT(b;10)="Resultaten";b;a)));
TOCOL(IFS((y=B2)*(TAKE(z;1)=C2);DROP(z;1));2)
)

 

[globe]

Heb je de tweede rij met bedrijven (bedrijf K t/m P) ook gezien?

aha... nee

dan moet het als volgt worden:

=VERT.ZOEKEN(
    B4;
    INDIRECT("'"&$B$2&"'!A:Z");
    ALS.FOUT(
        VERGELIJKEN($C$2;INDIRECT("'"&$B$2&"'!2:2");0);
        VERGELIJKEN($C$2;INDIRECT("'"&$B$2&"'!37:37");0)
    );
    ONWAAR
)

de formule kijkt eerst in de tweede rij naar het bedrijf, wordt daar niks gevonden zorgt de ALS.FOUT er voor dat het tweede deel van de formule in rij 37 naar het bedrijf gaat zoeken.