Formule op controle getal ITF 14 code

[HBot]

Geacht forum,

ik ben op zoek (kan op net deze niet vinden) naar een formule om het controle getal (laatste cijfer) in een ITF-14 bar code te controleren.
meestal begint een ITF code met een [0] bv 05050665028364,

Ik heb een formule voor het controleren van het controle getal (laatste cijfer) van EAN 13 bar code
bv EAN code = 8715700111926

=ALS(B101=0;"";(AFRONDEN.NAAR.BOVEN(((DEEL(B101;2;1)+DEEL(B101;4;1)+DEEL(B101;6;1)+DEEL(B101;8;1)+DEEL(B101;10;1)+DEEL(B101;12;1))*3)+(DEEL(B101;1;1)+DEEL(B101;3;1)+DEEL(B101;5;1)+DEEL(B101;7;1)+DEEL(B101;9;1)+DEEL(B101;11;1));-1)-((DEEL(B101;2;1)+DEEL(B101;4;1)+DEEL(B101;6;1)+DEEL(B101;8;1)+DEEL(B101;10;1)+DEEL(B101;12;1))*3+(DEEL(B101;1;1)+DEEL(B101;3;1)+DEEL(B101;5;1)+DEEL(B101;7;1)+DEEL(B101;9;1)+DEEL(B101;11;1)))))

deze formule laat zien een [6] hiermee weet ik dat het goed is.

zonder [0] werkt bovenstaande code wel maar als er ipv van een[0] een ander getal staat werkt het niet.
gr
Henny

 

[alphamax]

Wat gebeurt er als je er een ' apostrof voor zet?

'0505066502836

Zie bijlage voor een bestandje wat ik vroeger ooit gemaakt heb.

 

[HBot]

Dank,

een apostrof heeft alleen effect als er een 0 voor staat, dan werkt de formule ook gewoon, dan is het gewoon een EAN 13 met een 0.
maar als ik een ITF-14 moet controleren waar het 1e cijfer geen 0 is dan werkt de formule niet.

ik blijf nog zoeken en hopen

gr.

 

[alphamax]

Ik heb het idee dat je wat dingen door elkaar aan het gooien bent
EAN-13 = 12 getallen+1 controlegetal
ITF-14 = 1 voorloopgetal (0...8) + 12 getallen + 1 controlegetal
bron: https://webshop.zillionproductions.com/content/12-wat-is-itf-14-barcode-nummer
bron: https://www.gs1standards.info/itf-14-barcodes/
Kan je geen voorbeeldbestandje maken met wat er goed gaat en wat er fout gaat.
Kijk ook eens naar mijn bijlage deze formule is totaal onafhankelijk van de lengte.

 

[AlexCEL]

Ik heb deze link gebruikt: https://www.gs1.org/services/how-calculate-check-digit-manually

Kom daarmee op zoiets uit...

=ALS(--RECHTS(A1;1)=AFRONDEN.BOVEN(SOMPRODUCT((DEEL(TEKST(A1;"00000000000000");14-RIJ($A$1:$A$13);1))*{3;1;3;1;3;1;3;1;3;1;3;1;3});10)-SOMPRODUCT((DEEL(TEKST(A1;"00000000000000");14-RIJ($A$1:$A$13);1))*{3;1;3;1;3;1;3;1;3;1;3;1;3});"ok";"niet ok")

Of, voor de allernieuwste Excel 365 versies:

=LET(X;SOMPRODUCT((DEEL(TEKST(A1;"00000000000000");14-RIJ($A$1:$A$13);1))*{3;1;3;1;3;1;3;1;3;1;3;1;3});y;--RECHTS(A1;1);ALS(y=AFRONDEN.BOVEN(X;10)-X;"ok";"niet ok"))