Foto selecteren

[assessor]

Ik heb in een werkblad x foto's over elkaar staan.
Met "send to back" selecteer ik nu de foto die ik voor wil hebben.

Nu wil ik dit doen met een knop in plaats van steeds rechts klikken en "send to back" selecteren.

Heb dit in een macro gezet en aan een knop gehangen.
Helaas zo makkelijk was dit niet.

Kan iemand mij op de goede weg helpen?

Vast dank.

 

[jkpieterse]

Op zijn minst zal je je macro moeten plaatsen en aan moeten geven wat er mis gaat. Liever nog een uigeklede versie van je bestand erbij. We zijn helaas niet helderziende

 

[assessor]

De macro heeft niet veel om het lijf...

Sub ChoosePicture()
'
' Macro1 Macro

'
    ActiveSheet.Shapes.Range(Array("Picture 2")).Select
    Selection.ShapeRange.ZOrder msoSendToBack
    ActiveSheet.Shapes.Range(Array("irc_mi")).Select
    Selection.ShapeRange.ZOrder msoSendToBack
End Sub

...bij het opnemen van deze macro had ik twee fotos naar achteren gestuurd, dat ging prima.

Als je echter de macro oproept zie je dat de foto geselecteerd wordt, scherm knippert even, klaar.. zelfde foto blijft voor.

 

[jkpieterse]

Wat moet de macro de volgende keer doen als hij wordt gestart?

 

[assessor]

Bij elke klik moet de zichtbare foto naar de achteren verdwijnen waardoor de volgende foto zichtbaar wordt.

 

[jkpieterse]

Dze macro werkt bij mij:

Option Explicit

Sub PlaatjeNaarVoren()
    Dim Shp As Shape
    Dim ForeMostShp As Shape
    Dim MaxOrder As Long
    For Each Shp In ActiveSheet.Shapes
        If Shp.ZOrderPosition > MaxOrder Then
            MaxOrder = Shp.ZOrderPosition
            Set ForeMostShp = Shp
        End If
    Next
    ForeMostShp.ZOrder msoSendToBack
End Sub

 

[snb]

Zou dit niet handiger zijn ?

Sub ChoosePicture()
   with sheet1.Shapes("Picture 2")
      .Visible= not .Visible
     .parent.Shapes("irc_mi").Visible= not .Visible
   end with
End Sub

 

[assessor]

De code van jkpieterse krijg ik niet aan het werk, gaat 8x door de loop maar er gebeurt niets.

@snb, jouw code werkt perfect met 2 foto's, helaas heb ik er (momenteel) 5 waar ik doorheen moet scrollen.
PS. hoe kan ik al de andere foto's die verborgen blijven weer tevoorschijn krijgen?

vast dank

 

[snb]

Maak alle afbeeldingen onzichtbaar op 1 na.

De macro is geschikt voor een onbeperkt aantal afbeeldingen; je hoeft hem niet te wijzigen als het aantal afbeeldingen toe-, of afneemt.

Sub M_snb()
   For j = 1 To Sheet1.Pictures.Count
      If Sheet1.Pictures(j).Visible Then
        Sheet1.Pictures(j).Visible = False
        Sheet1.Pictures(j Mod Sheet1.Pictures.Count + 1).Visible = True
        Exit For
      End If
   Next
End Sub

 

[assessor]

snb,

Perfecte oplossing:thumb:, met veel dank, ook voor jkpieterse

Volgende stap wordt het tonen van een van de foto's afhankelijk van de waarde in cel 'x'
Gaat ook ongetwijfeld niet in een keer lukken, dan zien jullie mijn vraag wel tevoorschijn komen , ga eerst even zelf aan de gang.

groet, Jos