• Privacywetgeving
    Het is bij Helpmij.nl niet toegestaan om persoonsgegevens in een voorbeeld te plaatsen. Alle voorbeelden die persoonsgegevens bevatten zullen zonder opgaaf van reden verwijderd worden. In de vraag zal specifiek vermeld moeten worden dat het om fictieve namen gaat.

gegevens berekenen met filter en voorwaarde

Status
Niet open voor verdere reacties.

janneman2011

Gebruiker
Lid geworden
11 okt 2011
Berichten
81
Beste allen

Ik heb in kolom A allemaal data staan van 1-1 t/m 30-6
In kolom B heb ik allemaal waarden staan
Nu wil ik wat resultaten laten zien van de waarden uit kolom B ( mediaan, 75% percentiel, aantal, etc)
Dat is op zich niet moeilijk als ik het hele bereik kies ( dus van 1-1 t/m 30-6)
Maar ik wil ook graag weten wat de aantallen zijn van alleen januari.
Op kolom A zet ik dan een filter en excel laat mij keurig alle waarden zien.
Maar in de resultaten neemt hij alles weer mee.
Kunnen jullie mijn formules aanpassen zodat hij wel werkt?

Al vast heel erg bedankt
 

Bijlagen

Bv.
Code:
=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ($1:$900);0)))*(B2:B901<276))
Ook nog.
Code:
=SOMPRODUCT(SUBTOTAAL(2;INDIRECT(ADRES(RIJ($2:$900);2)))*(B2:B900<276))
 
Laatst bewerkt:
Welke versie van Excel gebruik je?

De FILTER functie uit Excel 365 kan ook handig zijn.
 
Beste Alexcel

Bedankt voor je reactie
de waarden onder de 276 werkt nu.
maar nu ook nog de andere waarden.
Ik probeer de logica van jou formule te begrijpen, maar dit gaat me echt boven de pet.
Zou je me nog een keer willen helpen met de andere resultaten?
dus hoeveel waarden tussen 276 en 400, max waarden, 75% percentiel etc.

Ik gebruik office 365, maar als ik filter van datum aan pas, veranderen de resultaten niet mee
 
Tussen 276 en 400
Code:
=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ(Tabel1[[#Alles];[DLP (mGy*cm)]]);0)))*(Tabel1[[#Alles];[DLP (mGy*cm)]]>276)*(Tabel1[[#Alles];[DLP (mGy*cm)]]<400))
Groter dan 400
Code:
=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ(Tabel1[[#Alles];[DLP (mGy*cm)]])-1;0)))*(Tabel1[[#Alles];[DLP (mGy*cm)]]>400))
Kwartiel
Code:
=KWARTIEL(ALS(SUBTOTAAL(3;VERSCHUIVING(Tabel1[DLP (mGy*cm)];RIJ(Tabel1[DLP (mGy*cm)])-RIJ(B2);;1));Tabel1[DLP (mGy*cm)]);3)
Max
Code:
=MAX(SUBTOTAAL(4;VERSCHUIVING(Tabel1[DLP (mGy*cm)];RIJ(Tabel1[DLP (mGy*cm)]);0)))
 
Voor Excel 365 worden ze respectievelijk:
Code:
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM(--(c<275)))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM((c>=275)*(c<=400)))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM(--(c>400)))
=AANTAL(Tabel1[Study Date])
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");KWARTIEL(c;3))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");KWARTIEL(c;2))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");MAX(c))
Je kan de formules ook naar een cel met een jaartal en een maand laten verwijzen. Nu verwijst alles naar 2022 en maand 1 (januari).
 
Of in ene, alhoewel ik denk dat TS de methode van Harry bedoelt via Subtotal.

Code:
=LET(z;Tabel1;a;INDEX(z;;1);c;FILTER(INDEX(z;;2);(YEAR(a)=2022)*(MONTH(a)=1);"");VSTACK(SUM(--(c<275));SUM((c>=275)*(c<=400));SUM(--(c>400));COUNT(a);QUARTILE(c;{3;2;4})))
 
Laatst bewerkt:
Kunstig JEC, heb hem even naar het NL vertaald en uitgeprobeerd...
Code:
=LET(x;Tabel1;y;INDEX(x;;1);z;FILTER(INDEX(x;;2);(JAAR(y)=2022)*(MAAND(y)=1);"");VERT.STAPELEN(SOM(--(z<275));SOM((z>=275)*(z<=400));SOM(--(z>400));AANTAL(y);KWARTIEL(z;{2;3;4})))
Zie ook bijlage.
 

Bijlagen

Laatst bewerkt:
Fantastisch, bedankt allemaal.
Wat is dit toch een fijn forum!!
Ben nu bezig met basis cursus Excel, maar daar krijg ik dit nog niet ( gelukkig).
Dit is echt voor pro's
 
Status
Niet open voor verdere reacties.
Terug
Bovenaan Onderaan