gegevens berekenen met filter en voorwaarde

[janneman2011]

Beste allen

Ik heb in kolom A allemaal data staan van 1-1 t/m 30-6
In kolom B heb ik allemaal waarden staan
Nu wil ik wat resultaten laten zien van de waarden uit kolom B ( mediaan, 75% percentiel, aantal, etc)
Dat is op zich niet moeilijk als ik het hele bereik kies ( dus van 1-1 t/m 30-6)
Maar ik wil ook graag weten wat de aantallen zijn van alleen januari.
Op kolom A zet ik dan een filter en excel laat mij keurig alle waarden zien.
Maar in de resultaten neemt hij alles weer mee.
Kunnen jullie mijn formules aanpassen zodat hij wel werkt?

Al vast heel erg bedankt

 

[HSV]

Bv.

=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ($1:$900);0)))*(B2:B901<276))

Ook nog.

=SOMPRODUCT(SUBTOTAAL(2;INDIRECT(ADRES(RIJ($2:$900);2)))*(B2:B900<276))

 

[AlexCEL]

Welke versie van Excel gebruik je?

De FILTER functie uit Excel 365 kan ook handig zijn.

 

[janneman2011]

Beste Alexcel

Bedankt voor je reactie
de waarden onder de 276 werkt nu.
maar nu ook nog de andere waarden.
Ik probeer de logica van jou formule te begrijpen, maar dit gaat me echt boven de pet.
Zou je me nog een keer willen helpen met de andere resultaten?
dus hoeveel waarden tussen 276 en 400, max waarden, 75% percentiel etc.

Ik gebruik office 365, maar als ik filter van datum aan pas, veranderen de resultaten niet mee

 

[HSV]

Tussen 276 en 400

=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ(Tabel1[[#Alles];[DLP (mGy*cm)]]);0)))*(Tabel1[[#Alles];[DLP (mGy*cm)]]>276)*(Tabel1[[#Alles];[DLP (mGy*cm)]]<400))

Groter dan 400

=SOMPRODUCT((SUBTOTAAL(2;VERSCHUIVING(B1;RIJ(Tabel1[[#Alles];[DLP (mGy*cm)]])-1;0)))*(Tabel1[[#Alles];[DLP (mGy*cm)]]>400))

Kwartiel

=KWARTIEL(ALS(SUBTOTAAL(3;VERSCHUIVING(Tabel1[DLP (mGy*cm)];RIJ(Tabel1[DLP (mGy*cm)])-RIJ(B2);;1));Tabel1[DLP (mGy*cm)]);3)

Max

=MAX(SUBTOTAAL(4;VERSCHUIVING(Tabel1[DLP (mGy*cm)];RIJ(Tabel1[DLP (mGy*cm)]);0)))

 

[AlexCEL]

Voor Excel 365 worden ze respectievelijk:

=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM(--(c<275)))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM((c>=275)*(c<=400)))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");SOM(--(c>400)))
=AANTAL(Tabel1[Study Date])
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");KWARTIEL(c;3))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");KWARTIEL(c;2))
=LET(a;Tabel1[Study Date];b;Tabel1[DLP (mGy*cm)];c;FILTER(b;(JAAR(a)=2022)*(MAAND(a)=1);"");MAX(c))

Je kan de formules ook naar een cel met een jaartal en een maand laten verwijzen. Nu verwijst alles naar 2022 en maand 1 (januari).

 

[JEC.]

Of in ene, alhoewel ik denk dat TS de methode van Harry bedoelt via Subtotal.

=LET(z;Tabel1;a;INDEX(z;;1);c;FILTER(INDEX(z;;2);(YEAR(a)=2022)*(MONTH(a)=1);"");VSTACK(SUM(--(c<275));SUM((c>=275)*(c<=400));SUM(--(c>400));COUNT(a);QUARTILE(c;{3;2;4})))

 

[AlexCEL]

Kunstig JEC, heb hem even naar het NL vertaald en uitgeprobeerd...

=LET(x;Tabel1;y;INDEX(x;;1);z;FILTER(INDEX(x;;2);(JAAR(y)=2022)*(MAAND(y)=1);"");VERT.STAPELEN(SOM(--(z<275));SOM((z>=275)*(z<=400));SOM(--(z>400));AANTAL(y);KWARTIEL(z;{2;3;4})))

Zie ook bijlage.

 

[JEC.]

Thanks!

 

[janneman2011]

Fantastisch, bedankt allemaal.
Wat is dit toch een fijn forum!!
Ben nu bezig met basis cursus Excel, maar daar krijg ik dit nog niet ( gelukkig).
Dit is echt voor pro's