gemiddelde berekenen met waardes >0

[mousden]

Dag Dames en Heren,

Hoe formuleer ik een functie waarbij het gemiddelde wordt berekend van getallen die groter zijn als 0?

Gegevens:
3 werkbladen genaamd "week1","week2","week3"

Cellen :
Op elk werkblad wordt altijd in cel B2 en B3 numerieke waardes genoteerd. Van 0 tot 100 kan dit zijn.

Opmerking:
In geval van een 0 waarde moet deze cel niet meegenomen worden in het berekenen van het gemiddelde.

Met welke combinatie van functies pak ik dit aan? Volgens mij een combinatie van de functies " Als" en "Gemiddelde"?

Hoe pak ik dit aan?

Groetjes van Mouse de Excel beginneling

 

[Hoornvan]

mousden,

Heb je al met de zoekmachine van Helpmij "Doorzoek dit forum" gezocht op "Gemiddelde"?
Moet je eens kijken hoeveel resultaten er zijn, misschien zit de oplossing voor jou er ook bij.

 

[danny147]

Beste mousden

Gebruik deze formule

=ALS(EN(B2=0;B3=0);0;ALS(B2=0;B3;ALS(B3=0;B2;GEMIDDELDE(B2:B3))))

Als B2 en B3 0 is dan 0, Als B2 0 is dan B3, Als B3 0 is dan B2 anders het gemiddelde van B2 en B3.

Groetjes Danny. :thumb:

 

[zapatr]

Op elk werkblad wordt altijd in cel B2 en B3 numerieke waardes genoteerd. Van 0 tot 100 kan dit zijn. In geval van een 0 waarde moet deze cel niet meegenomen worden in het berekenen van het gemiddelde.

Je schrijft dat het alleen om positieve getallen gaat. Je kunt dan gebruiken:

=SOM(B2:B3)/AANTAL.ALS(B2:B3;">0")

 

[HSV]

Iets korter, maar matrix.

=SOM(B2:B3)/SOM(--(B2:B3>0))

Dus afsluiten met Ctrl+Shift+Enter.

 

[jzeedijk]

Hoi Mouse,

De som bepalen van de waades in B2 en B3 op verschillende werkbladen doe je met:
=SOM(week1:week3!B2:B3)

Nu nog het aantal waardes >0 tellen.
Dat is ingewikkelder. Hier heb je een matrix-formule voor nodig.

=SOM((week1!B2:B3>0)+(week2!B2:B3>0)+(week3!B2:B3>0))

Een matrix-formule voer je in door Shift + Ctrl ingedrukt te houden en dan Enter.
In de frmulebalk zie je nu de formule tussen acculades {......} verschijnen.
Het gemiddelde is natuurlijk formule 1 gedeeld door formule 2, wat ook een matrix-formule is.

Groet,

Jeroen

 

[HSV]

Zoiets dacht ik ook al @Jeroen.
De som van alle werkbladen B2:B3 gedeeld door het aantal groter dan 0.
Wist het niet zeker, en nog niet, maar als dat de vraag is kan het met één matrixformule.

=SOM(week1:week3!B2:B3)/SOM((week1!B2:B3>0)+(week2!B2:B3>0)+(week3!B2:B3>0))

Dus afsluiten met Ctrl+Shift+Enter.

 

[mousden]

Zoiets dacht ik ook al @Jeroen.
De som van alle werkbladen B2:B3 gedeeld door het aantal groter dan 0.
Wist het niet zeker, en nog niet, maar als dat de vraag is kan het met één matrixformule.

=SOM(week1:week3!B2:B3)/SOM((week1!B2:B3>0)+(week2!B2:B3>0)+(week3!B2:B3>0))

Dus afsluiten met Ctrl+Shift+Enter.

Bedankt voor jullie hulp maar ik nog een vraag betreffende de oplossing. Het betreft het tellen van de b2:b3 cellen die groter zijn als 0 waarde. Kan het laatste gedeelte achter de / teken ook korter geformuleerd worden? Stel dat je van week1 tot en met week 52 aan werkbladen hebt?

Top dat jullie allemaal meedenken!

Groeten Mousden

 

[RaymondC]

Is het niet gemakkelijker om een totaal overzicht te maken van al je weken.
Dan heb je alle waardes op 1 blad staan.

Dit hoef je maar 1 keer op te stellen.

zie bijlage.

Formules moeten er nog in gezet worden.

 

[mousden]

Is het niet gemakkelijker om een totaal overzicht te maken van al je weken.
Dan heb je alle waardes op 1 blad staan.

Dit hoef je maar 1 keer op te stellen.

zie bijlage.

Formules moeten er nog in gezet worden.

Gelijk heb je!!!!!! Waarom zou ik moeilijk doen als het makkelijk kan! Bedankt.....Ik ga ermee aan de slag.

Tot de volgende vraag iedereen!

Groetjes Mousden

 

[HSV]

Gelijk heb je!!!!!! Waarom zou ik moeilijk doen als het makkelijk kan! Bedankt.....Ik ga ermee aan de slag.

Tot de volgende vraag iedereen!

Groetjes Mousden

Beste mousden,

Zet dan onderstaande formule in B2, en doorvoeren naar onderen en naar rechts.
Hoef je niet 52 weken x 2 = 104 formules te maken.

=ALS(ISFOUT(INDIRECT("'week "&B$1&"'!B"&RIJ()));"";INDIRECT("'week "&B$1&"'!B"&RIJ()))

Zie bestandje.