Gemiddelde berekenen op basis van 2 voorwaarde

[WVR132]

Hallo vrienden,

Ik heb jullie hulp nodig.
Ik heb een lijst met data (KOLOM A) en In kolom B staan waardes. Nu wil ik het gemiddelde uitrekenen van de waardes in kolom B op basis van het maand nummer van kolom A maar zonder de 0.
Ik wil namelijk het gemiddelde uitrekenen als er daadwerkelijk iets is verkocht.

De formules die ik tot nu toe heb gebruikt:
=GEMIDDELDE.ALS(B2:B25; "<>0") Werkt wel maar is zonder de voorwaarde van de maand

{=GEMIDDELDE(ALS(MAAND($A$2:$A$400)=2;($B$2:$B$400)))} Werkt wel maar is zonder de voorwaarde "0" Dit is dus een matrix.
Volgens mij moet ik ook een matrix formule gebruiken omdat ik meerdere voorwaarde gebruikt (datum en >0)

In de bijlage heb ik een voorbeeld. Let wel dat de kolommen A en B in een ander tab komen te staan dan het overzicht. Dit is alleen een voorbeeld.
Ik wil dus eigenlijk de 2 formules samen voegen maar ik kom er niet meer uit.
Ik hoop dat jullie mij kunnen helpen.
Bekijk bijlage Gemiddelde maand verkoop.xlsx

 

[E v R]

kijk eens naar gemiddeldeN.als

 

[Gerard2348]

Met hulp vanuit kolom C

Bekijk bijlage Gemiddelde maand verkoop (2).xlsx

 

[WVR132]

Met gemiddelden.als had ik ook al zitten experimenteren.

En ook de oplossing van Gerard had ik al gebruikt.
Bedankt voor jullie reacties. :thumb:

Het is alleen niet precies wat ik zoek. De oplossing van Gerard is een zeer werkzame oplossing maar ik wilde zonder een extra kolom de formule maken. De kolom C wilde ik dus vervangen met de functie MAAND. maar dit werkt niet helaas. Misschien wil ik iets dat niet kan.

 

[E v R]

In G2:

=AVERAGEIFS($B$2:$B$184;$A$2:$A$184;">="&DATE(2017;E2;1);$A$2:$A$184;"<="& EOMONTH(DATE(2017;E2;1);0);$B$2:$B$184;"<>"&0)

nl:

=GEMIDDELDEN.ALS($B$2:$B$184;$A$2:$A$184;">="&DATUM(2017;E2;1);$A$2:$A$184;"<="& LAATSTE.DAG(DATUM(2017;E2;1);0);$B$2:$B$184;"<>"&0)

 

[WVR132]

Hoi Eric,

Dit is hem!
Ik ga het even uitpluizen.:thumb::thumb:

Echt super bedankt! ik kan weer verder.

Groet,
Wouter

 

[WVR132]

Hoi Eric,

Nogmaals bedankt voor je hulp.
Ik heb de formule in gebruik en hij werkt helemaal top.

Nu wil ik natuurlijk ook begrijpen wat de formule doet. Ik zie dat je de functie DATUM hebt gebruikt waar je naar de eerste dag en laatste dag zoekt.
Kan jij mij uitleggen waarom dit wel werkt en de functie MAAND niet.
Ik gebruik in andere formules (met name som.als in een matrix) wel de functie MAAND en daar werkt het prima, maar ik kreeg het niet voor elkaar met de gemiddelde.

Alvast bedankt
Gr,
Wouter

 

[E v R]

In jouw kolom A (maand) staan data en geen maanden. Het criterium waar je op zoekt moet dus een datum zijn. (vandaar dat ik van jouw maandnummers data heb gemaakt)
Anders moet je eerst van de data, maanden maken, maar dit betekent of een hulpkolom of een matrix/sumproduct-formule.

zo kan ook:

=SOMPRODUCT((MAAND($A$2:$A$184)=E$2)*($B$2:$B$184<>0)*($B$2:$B$184))/SOMPRODUCT((MAAND($A$2:$A$184)=$E$2)*($B$2:$B$184<>0))

maar gemiddelen.als is ervoor gemaakt

 

[WVR132]

Hoi Eric,

Dank voor je uitleg. Klinkt heel logisch
Ik ben vandaag weer een stukje wijzer geworden.

Groet,
Wouter