Geneste functie als en meerdere keren

[Francis80]

In ons vakantie overzicht wil ik dat er een V geplaatst wordt op de dagen dat iemand vakantie heeft.

zie voorbeeld
Met de functie =ALS(EN($X8<=AH$1;$Y8>=AH$1);"V";"") lukt het mij om een V in de juiste vakjes te krijgen. Alleen wil ik dat hij dit ook doet voor Z+AA en AB+AC en AD+AE en AF+AG
Dus eigenlijk alle onderstaande aan elkaar vast.
=ALS(EN($X8<=AH$1;$Y8>=AH$1);"V";"")
=ALS(EN($Z8<=AH$1;$AA8>=AH$1);"V";"")
=ALS(EN($AB8<=AH$1;$AC8>=AH$1);"V";"")
=ALS(EN($AD8<=AH$1;$AE8>=AH$1);"V";"")
=ALS(EN($AF8<=AH$1;$AG8>=AH$1);"V";"")
Ik weet niet goed hoe ik dit genest kan maken door. Heb geprobeerd met of te werken, maar dan lukt het maar voor 2. Bij de derde gaat het fout. Is er iemand die me kan helpen?

 

[jgkdrt]

Francis,

Het meest eenvoudige, aangezien, van een persoon, de ene vakantie de andere niet zal overlappen:

=ALS(EN($X8<=AH$1;$Y8>=AH$1);"V";"") & ALS(EN($Z8<=AH$1;$AA8>=AH$1);"V";"") & ALS(EN($AB8<=AH$1;$AC8>=AH$1);"V";"") & ALS(EN($AD8<=AH$1;$AE8>=AH$1);"V";"") & ALS(EN($AF8<=AH$1;$AG8>=AH$1);"V";"")

maar die van AHulpje (hieronder) is mooier.

 

[AHulpje]

In AH8 en dan doortrekken naar beneden en naar rechts:

=ALS(OF(EN($X8<=AH$1;$Y8>=AH$1);EN($Z8<=AH$1;$AA8>=AH$1);EN($AB8<=AH$1;$AC8>=AH$1);EN($AD8<=AH$1;$AE8>=AH$1);EN($AF8<=AH$1;$AG8>=AH$1));"V";"")

 

[snb]

Je formule illustreert het probleem: een onjuiste/onhandige opbouw/struktuur van je gegevens.
Hoe beter de struktuur hoe minder/eenvoudiger formules (if at all)

 

[Francis80]

Bedankt dit is hem.

 

[Francis80]

snb: ik sta open voor suggesties hoor.

Hier ben ik op uitgekomen, omdat ik historie wil blijven zien en ik het in mijn hoofd niet anders kan zien dan zo. Gebrek aan mijn kant. Dus als er andere eenvoudigere manieren zijn dan mag je dat altijd aangeven.

 

[AlexCEL]

Voor de fun nog een Excel 365 optie:

=LET(x;AH$1;y;$X8:$AG8;z;REEKS(5;;;2);ALS(SOM((x>=INDEX(y;;z))*(x<=INDEX(y;;z+1)))>0;"V";""))

En in bijlage nog een optie met een vakantielijstje waardoor een simpele SOMPRODUCT mogelijk wordt.

 

[snb]

Zo bijvoorbeeld.