Helpmij Excel Verticaal Zoeken

[david149]

Beste leden,

Ik ben bezig met een gebruikte document waarbij ik informatie uit meerdere excel bestanden wil gebruiken om een excel sheet compleet te krijgen.

De onderstaande formule is al ingebruik met het laaste gedeelte onder de witregel wil ik toevoegen maar dan geeft excel aan : there are too many arguments...(julluie kennen deze foutmelding wel)

Kort achtergrond informatie: ik gebruik meerdere excel bestanden waar ik twee gegevens van nodig heb; ordernummers en containernummers en deze aan elkaar koppelt. Maar ik wil een nieuwe excel bestand toevoegen omdat daar andere gegevens op staan die ook eraan gekoppeld moeten worden maar tevergeefs..

=IF(ISNA(VLOOKUP(L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0));VLOOKUP(1*L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Uitbesteed Transport[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0);VLOOKUP(L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0);

VLOOKUP(1*L10189;'K:NL.Solutions.Amsterdam\Planning & Process Control\08 Freight(').Kosten Sheet[Kosten Sheet.xlsx]2015'!$A$2:$E$60847;3;0))

Iemand sugesties hoe dit het beste kan? de formule mag geherstructureerd worden. Het lijkt erop dat deze formule te lang is.

heeft iemand een idee??:evil:

 

[crash]

Ik heb je vraag verplaatst vanuit de Helpmijdagen sectie naar de Excel sectie, daar je hier betere hulp krijgt en je vraag ook thuis hoort.

 

[Ndam90]

Beste David149,

Het is lastig je vraag te begrijpen aangezien je een formule levert en het onduidelijk is welke gegevens je graag wilt ophalen.
Wanneer ik naar je formule kijk staat er het volgende:

Laten we zeggen dat elke VLOOKUP een nummer krijgt, dan staat er:
=IF(ISNA(VLOOKUP[B]1[/B]);VLOOKUP[B]2[/B];VLOOKUP[B]3[/B];VLOOKUP[B]4[/B])

Je formule werkt niet omdat de formule maar 2 mogelijke waarden heeft bij een IF formule.

=IF([I]logische test[/I];[I]als waar[/I];[I]als onwaar[/I])

Je voegt ISNA() toe dus wordt dit:

=IF(ISNA([I]test[/I]);[I]als waar[/I];[I]als onwaar[/I])

Een derde waarde toevoegen zoals je doet kan en mag niet. Je moet dan nog een IF formule toevoegen.

Verder vraag ik me nog af waarom je in je 4e VLOOKUP een "1*" hebt staan.

 

[david149]

Collega,

bedankt voor je zeer snelle reactie

ik heb de formule nu zo aangepast: =IF(ISNA(VLOOKUP(1*L10189;'K:NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\(').Kosten Sheet\[Kosten Sheet.xlsx]2015'!$A$2:$E$60847;3;0))

Bedoel je dit met nog een IF? en hoe sluit deze aan bij de hoofdformule ?

 

[david149]

=IF(ISNA(VLOOKUP(L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0));VLOOKUP(1*L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Uitbesteed Transport\[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0);VLOOKUP(L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0);


=IF(ISNA(VLOOKUP(1*L10189;'K:NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\(').Kosten Sheet\[Kosten Sheet.xlsx]2015'!$A$2:$E$60847;3;0))

Hoe krijg ik de bovenstaande formule het beste aangesloten aan de hoofdformule hierboven ?


bedankt alvast ! ik kom er echt niet meer uit


PS; de 1* heb ik staan omdat excel hem zag als tekst i.p.v getal

 

[Ndam90]

Beste David149,

Een ALS/IF formule werkt als volgt:
Voorbeeldformule: IF("Appel"="Peer";"Ja";"Nee")
Hier staat nu: Als het woord Appel gelijk is aan het woord Peer, resulteer dan Ja, anders Nee.

Een extra ALS/IF toevoegen kan als volgt. Stel voor ik wil ook controleren of het woord Appel overeenkomt met het woord Wortel, dan moet er een 3e optie bij.
De formule wordt dan: IF("Appel"="Peer";"Ja";IF("Appel"="Wortel";"Ja";"Nee"))
Het blauwe gedeelte hierin is je waarde als WAAR, het groene gedeelte als de waarde ONWAAR is. Binnen het groene gedeelte ontstaat weer een WAAR/ONWAAR verhouding.

Om een formule voor je te kunnen voorschotelen moet ik eerst begrijpen wat je wilt bereiken.
Wat me opvalt (verbeter me als ik het fout heb) bestaat je formule uit 4x VLOOKUP waarbij de eerste en de 3e hetzelfde zijn.

Laten we de eerste en de derde even VLOOKUP1 noemen, de 2e VLOOKUP2 en de 4e en laatste VLOOKUP3 noemen.

Zonder de toevoeging van je laatste (nieuwe) gedeelte staat er:
ALS VLOOKUP1 de waarde #N/A levert, resulteer dan VLOOKUP2, als de waarde niet #N/A levert, gebruik dan VLOOKUP1.

Mijn vraag is, wanneer je VLOOKUP3 wilt hebben? Wat is je logische test/voorwaarde.

Mocht je me niet goed begrijpen, of is m'n uitleg niet toereikend, kan je dan alsjeblieft een voorbeeldbestandje uploaden.



--------------
Kanttekening.. je gebruikt ISNA(), terwijl je sneller ISERROR() kan gebruiken. Scheelt je een hele reeks formule.
Daarnaast vraag ik me af waarom je tekst als getal wilt neerzetten. Je kan beter alles als tekst noteren als er een letter in je naam zit.

 

[david149]

Bedankt voor je snelle uitleg. Ik zal hieronder het verhaal wat duidelijker neer zetten:
De formule bestaat inderdaad uit drie Vlookup's.

- In de eerste Vlookup raadpleeg excel een prograppa --> [RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0)) Dus er worden gegevens gehaald uit DUMP (excel; bestand) van een programma(RP).
- Vervolgens als in het bovenstaande excel bestand van het programma niet de juiste gegeven staan is het de bedoeling dat hij in een ander excel bestand de juiste gegevens gaat zoeken --> [Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0). Dus hier probeert excel dan nogmaals gegevens uit een andere excel bestand te zoeken en te koppelen.
- Het vreemde is dat de derde Vlookup precies het zelfde is als de eerste --> RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0)). Deze wil ik eruit halen omdat dit natuurlijk dubbelop is

Wat ik nu aan het proberen ben is om een formule toe tevoegen die aangeeft wanneer hij in de bovenstaande vlookups niets vind een derde excel bestandje zal raadplegen --> \[Kosten Sheet.xlsx]2015'!$A$2:$D$60847;3;0);

Alleen ben ik bang dat ik inderdaad een fout maak met IF en ISNA en dat deze gehele formule even geherstructureerd moet worden( in een andere vorm o.i.d)

Kortom: de formule moet de werking hebben van: 1 excel bestand zoekt in meerdere bestanden en haalt daar gegevens uit.
- Zoekt in bestand 1 kijkt of hij daar het juiste order en containernummer kan vinden en koppelen, zo niet --
- Zoekt hij in bestand 2 of daar het juiste order en containernummer kan vinden en koppelen, zo niet --
- Zoekt hij in het laatste bestand of daat een juiste order en containernummer kan vinden en koppelen-- Zo niet --> eventueel een melding(FALSE) van "ontbreekt"


PS; dat over 1* als het lukt zonder zal ik dat zeker gaan doen.

Kun je mij hierbij helpen ?




=IF(ISNA(VLOOKUP(L166;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0))
;VLOOKUP(1*L166;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Uitbesteed Transport\[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0)
;VLOOKUP(L166;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0))

;VLOOKUP(1*L166;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\.Kosten Sheet\[Kosten Sheet.xlsx]2015'!$A$2:$D$60847;3;0);

 

[Leotaxi]

kan het niet met iferror ?

=iferror(vlookup(te zoeken ding,eerste zoekgebied,kolomnr,false),iferror(vlookup(te zoeken ding,tweede zoekgebied, kolomnr,false),iferror(vlookup(te zoeken ding,derde zoekgebied,kolomnr,false),"ontbreekt")))

mvg
Leo

 

[Ndam90]

Beste David149,

Je bent duidelijk en ik snap nu wat je wilt. In het kort kan je de volgende formule gebruiken:

=IFERROR(VLOOKUP1;IFERROR(VLOOKUP2;IFERROR(VLOOKUP3;"Geen waarden")))

De lange code is:

=IFERROR(VLOOKUP(L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0);IFERROR(VLOOKUP(1*L10189;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Uitbesteed Transport[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0);IFERROR(VLOOKUP(1*L10189;'K:NL.Solutions.Amsterdam\Planning & Process Control\08 Freight(').Kosten Sheet[Kosten Sheet.xlsx]2015'!$A$2:$E$60847;3;0);"Geen waarden")))

Let even op dat bij een engelse versie vaak " , " wordt gebruikt ipv " ; " maar omdat in je hoofdvraag je formule " ; " bevatte heb ik dit doorgevoerd in mijn formule.

 

[david149]

Beste leden,

Bedankt voor jullie hulp. Ik ben 1 stapje dichter bij gekomen. De zoekwaarde zijn veranderd en de dubbele Vlooup heb ik eruitgheaald. Daarnaast is de 1* er ook uit , omdat de excel sheets op nummer staan en niet meer op getal.

Dit zijn de nieuwe onderstaande Vlookups. Alleen mijn vraag is hoe kan ik deze met elkaar verbinden ? De IFEROR Functie doet het vreemd dus die haal ik er dan maar uit.

* De formule wordt dus = Vlookup1 ( waardes etc.), geen waarde gevonden dan -->zoeken in Vlookup 2 ( waardes etc.), geen waarde gevonden dan in --> Vlookup 3 ( waardes etc.), .

=VLOOKUP(L791;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0)
;VLOOKUP(L791;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Uitbesteed Transport\[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0)
;VLOOKUP(L791;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\.Kosten Sheet\[Kosten Sheet.xlsx]2015'!$C:$D;2;0)


Wie kan mij helpen met het verbinden van deze Vloookups ?:thumb:

 

[Leotaxi]

met iferror


mvg
Leo

 

[Leotaxi]

voorbeeldje met 3 verschillende zoekgebieden


mvg
Leo

 

[david149]

Ik wil graag iedereen bedanken voor zijn hulp en snelle reacties !! Eeen dikke duim .

Hieronder de werkende Formule:
=IFERROR(VLOOKUP(L791;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\Invoicing\Data\[RP Data.xlsx]RP DATA'!$A$1:$B$60813;2;0);IFERROR(VLOOKUP(L791;'[Uitbesteed Transport 2015.xlsx]2015'!$B$3:$E$60847;4;0);IFERROR(VLOOKUP(L791;'K:\NL.Solutions.Amsterdam\Planning & Process Control\08 Freight\.Kosten Sheet\[Kosten Sheet.xlsx]2015'!$C:$D;2;0);"Ontbreekt")))


:thumb::thumb::thumb: