In een mail bericht een tekst in het onderwerp plaatsen

[Geertvdb]

Mijn kennis van VBA is zeer beperkt, daarom deze vraag.
Met het onderstaande via een knop roep je het mailprogramma op en wordt het mailadres uit het veld geplaatst.
Dat gaat goed maar hoe krijg ik nu een (vaste) tekst in het onderwerp van het mail bericht?
Wie zet mij op het goede spoor
Geert

Function fEmail_link(strEmail_adres As String)

 
    If Len(strEmail_adres) > 5 Then
        If InStr(2, strEmail_adres, "@") Then
            strEmail_adres = "mailto:" & strEmail_adres
            FollowHyperlink (strEmail_adres)
        Else
            MsgBox strEmail_adres & " is geen geldig e-mail adres"
        End If
    Else
        MsgBox "U hebt geen e-mail adres ingevoerd", vbExclamation, "Geen e-mail adres"
    End If
    
End Function

 

[edmoor]

Om dat te kunnen doen zul je met Mail Automation moeten werken. Kijk hier voor een voorbeeld:
http://www.rondebruin.nl/win/s1/outlook/bmail4.htm

 

[Geertvdb]

Hartelijk dank voor de reactie,maar helaas dit gaat mijn kennis te boven.Ik werk maar een paar dagen met access per jaar voor een camping als goed willende amateur. Is er geen simpeler op lossing?

 

[edmoor]

Het zijn goede voorbeelden op die pagina dat zijn vrijwel de simpelste die er zijn voor volledige mail manipulatie. Maar het volgende is toegespitst op Access, dus kijk daar eens:
http://pcmenu.info/pc_help/access/e_mail.htm

Met name methode 2.

 

[Geertvdb]

Nogmaals bedankt,ik denk dat ik hiermee verder kom.

 

[Geertvdb]

Helaas is het mij ondanks de hulp niet gelukt om een vaste tekst in het onderwerp te plaatsen. Weet iemand ergens een voorbeeld?

 

[OctaFish]

De code van Ron kun je zo knippen en plakken, en dan werkt-ie perfect. In jouw functie dus ook:

Function fEmail_link(strEmail_adres As String)
Dim OutApp As Object
Dim OutMail As Object
Dim strbody As String

    Set OutApp = CreateObject("Outlook.Application")
    Set OutMail = OutApp.CreateItem(0)

    strbody = "Hi there" & vbNewLine & vbNewLine & _
              "This is line 1" & vbNewLine & _
              "This is line 2" & vbNewLine & _
              "This is line 3" & vbNewLine & _
              "This is line 4"

    On Error Resume Next
    With OutMail
        .To = strEmail_adres
        .CC = ""
        .BCC = ""
        .Subject = "This is the Subject line"
        .Body = strbody
        'You can add a file like this
        '.Attachments.Add ("C:\test.txt")
        ''.Send   'or use .Display
        .Display
    End With
    On Error GoTo 0

    Set OutMail = Nothing
    Set OutApp = Nothing
    
End Function

Zelfs als je niet veel van programmeren af weet, (en iedereen begint nu eenmaal met een schone lei) kun je de code wél snappen, want erg ingewikkeld is het niet. De code start een Outlook sessie, zodat je Outlook niet open hoeft te hebben als je gaat mailen. Verder bevat de variabele strBody de vaste mailtekst. (En daar ging het jou om). Vervolgens wordt de mail verstuurd, en zet je dus in het veld .To het emailadres dat je in de functie mee hebt gegeven. Met .Display krijg je de mail vervolgens op je scherm te zien.

 

[Geertvdb]

Ondanks de hulp is het mij niet gelukt de gewenste wijziging met maken.
Ik laat het maar bij het oude. Bedankt allen Geert