=(INDEX(Vergoeding;VERGELIJKEN($C36;Afkortingen;0))+((INDEX(Vergoeding;VERGELIJKEN($F

[Albert4043]

Hallo excel experts,

Ik heb het volgende probleem. Waarschijnlijk zeer simpel op te lossen, maar ik kom er na een dag ploeteren niet uit.

=(INDEX(Vergoeding;VERGELIJKEN($C36;Afkortingen;0))+((INDEX(Vergoeding;VERGELIJKEN($F36;Afkortingen;0)))))

Vergoeding=getalswaarde
vergelijken en Cel $c36 en Cel $F36 zijn tekstwaarden


Dit gaat prima, zolang er daadwerkelijk in $c36 en $F36 beiden een tekst staat ingevuld, zelfs een foutieve tekst die niet aan de voorwaarde voldoet, geeft 0 als resultaat.


Maar zodra in cel $c36 en/of $F36 geen tekst bevat is de uitkomst #N/B

Wie weet de oplossing?

Albert

[TABLE="width: 823"]
[TR]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD][/TD]
[TD="align: right"][/TD]
[/TR]
[/TABLE]

 

[zapatr]

Kijk in de helpfile van Excel bij isfout.

 

[HSV]

Of: 'als.fout'.

 

[Albert4043]

Dag Harry,

Daar ben ik ook al heel de dag mee aan het ploeteren geweest, maar dan krijg je nog 0 als resultaat.
Het gaat erom dat twee de twee index vergelijkingen bij elkaar opgeteld worden, ook als 1 cel leeg is. En dat is juist het probleem, bij 1 legen cel toch weer #N/B

 

[zapatr]

Nee hoor Albert, als je het goed toepast krijg je wel de gewenste uitkomst.
Als je een voorbeeldbestand zou posten, zouden we onmiddellijk kunnen zien wat er mis gaat.

 

[Cobbe]

Intussen kan je eens met deze testen:

=ALS.FOUT(INDEX(vergoeding;VERGELIJKEN($C36;afkortingen;0));0)+ALS.FOUT(INDEX(vergoeding;VERGELIJKEN($F36;afkortingen; 0));0)

 

[Albert4043]

bij deze bestand

ij deze het voorbeeld bestand.

 

[Albert4043]

zie voorbeeld bestand, van Cobbe had ik ook al uitgetest, maar werkt ook niet, probeer maar eens.

Albert

 

[Cobbe]

Met een bestand dat beveiligd is schieten we ook niet op.

 

[Albert4043]

Nu zonder bestand zonder beveiliging

Met een bestand dat beveiligd is schieten we ook niet op.

Ha Cobbe,

Sorry, dat is dom van mij. Maar bij deze bestand zonder wachtwoord, had ik even over hoofd gezien.

Albert

 

[Cobbe]

En wie zegt dat mijn formule niet werkt?

 

[Albert4043]

Cobbe,

Zeer hartelijk bedankt. Geniaal. Ik weet niet wat ik dan fout heb gedaan.
Maar je hebt mijn dag zeer goed gemaakt!! en vele weken erna.

Albert

 

[zapatr]

@Albert,
1. betreft je formule in blad 'medewerker x' in R10; die luidt:

=(ALS(C10=Uren!$D$8;Uren!$E$8+Q10;ALS(C10=Uren!$D$12;Uren!$E$12+Q10;ALS(C10=Uren!$D$14;Uren!$E$14+Q10;ALS(C10=Uren!$D$16;Uren!$E$16+Q10;ALS(C10=Uren!$D$18;Uren!$E$18+Q10;ALS(D10=Uren!$D$26;Uren!$E$26+Q10;ALS(D10=Uren!$D$26;Uren!$E$26+Q10;ALS(D10=Uren!$D$28;Uren!$E$28+Q10;ALS(E10=Uren!$D$37;Uren!$E$37+Q10;ALS(F10=Uren!$D$41;Uren!$E$41+Q10;)))))))))))

Je kijkt daarmee in de cellen C10:G10 of daarin 1 of meer van de afkortingen voorkomen uit het blad 'Basis'. Maar ben je je ervan bewust dat met die formule slechts 1 afkorting wordt meegeteld, nl. de eerste cel van C10:G10 waarin een afkorting staat? Er kan toch (denk ik) zowel 's morgens, 's middags, als 's avonds een afkorting van toepassing zijn? Als dat het geval is, dan moet je de ALS'en optellen.
Die formule kan veel korter, bv. zo:

=Q10+ALS.FOUT(VERT.ZOEKEN(C10;Uren!D8:E18;2;0);0)+ALS.FOUT(VERT.ZOEKEN(D10;Uren!D26:E28;2;0);0)+ALS.FOUT(VERT.ZOEKEN(E10;Uren!D37:E41;2;0);0)

2. betreft je formule in hetzelfde blad in T10; die luidt:

=[COLOR="#0000CD"][B]ALS.FOUT(INDEX(Basis;VERGELIJKEN($B10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)[/B][/COLOR]+ALS.FOUT(INDEX(Basis;VERGELIJKEN($C10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)+ALS.FOUT(INDEX(Basis;VERGELIJKEN($D10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)+ALS.FOUT(INDEX(Basis;VERGELIJKEN($E10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)+ALS.FOUT(INDEX(Basis;VERGELIJKEN($F10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)+ALS.FOUT(INDEX(Basis;VERGELIJKEN($G10;Afkortingen;0);VERGELIJKEN($P10&"|"&T$7;codes;0));0)+S10+H10-K10

Het blauwe gedeelte heeft geen enkel nut, je kijkt daarin of een datum overeenkomt met een afkorting. Die zullen NOOIT aan elkaar gelijk zijn, dus dat gedeelte kun je best verwijderen.