Ingevoerde gegevens beveiligen tegen verwijderen VBA

[MisterF]

Hoi Medestrijders,

Ik heb de volgende vraag.

Ik heb een werkmap, bestaande uit 6 werkbladen. Werkblad 2 bevat een database, bestaande uit Kolom A tot en met kolom G die door verschillende personen gevuld kan worden.
Na invoer van de gegevens wordt de werkmap opgeslagen. En later weer geopend voor nieuwe invoer van gegevens, dan weer opgeslagen , enz. , enz.

Is het mogelijk dmv VBA(Private Sub) om de database (werkblad 2), kolom A tot en met kolom E , na invoer van gegevens / na opslaan werkmap te beveiligen tegen verwijderen van de ingevoerde gegevens?
Let wel: De gegevens ingevoerd bij de kolommen F,G en H mogen wel achteraf gewijzigd en of verwijderd worden.

Bij voorbaat bedankt voor jullie hulp

 

[VenA]

Is een beetje afhankelijk van wat je allemaal wil beveiligen. Hier een eerste opzet:

Private Sub Workbook_BeforeClose(Cancel As Boolean)
With Sheets(2) 'de sheet waar de database staat
    .Unprotect 'haal de beveiliging eraf
    .Cells.Locked = False 'geef alle cellen vrij
    With .Range(.Range("a1:E1"), .Cells(.Rows.Count, 1).End(xlUp)) 'Bepaal de gevulde cellen in de kolommen A t/m E
        .Locked = True 'blokkeer deze
        With .Interior 'en geef ze een grijze achtergrond
            .Pattern = xlSolid
            .PatternColorIndex = xlAutomatic
            .ThemeColor = xlThemeColorDark1
            .TintAndShade = -0.149998474074526
            .PatternTintAndShade = 0
        End With
    End With
    .Protect DrawingObjects:=True, Contents:=True, Scenarios:=True 'zet de beveiliging er weer op
End With
End Sub

Anders graag even een voorbeeldbestandje.

 

[MisterF]

Goede middag VenA,

Sneller dan het geluid.
Precies wat ik bedoelde.:thumb:

Dank je en nog een prettig weekend.
MisterF