Kopieren van gegevens naar totaalblad

[felix474]

Hallo.

Ik zou graag gegevens geautomatiseerd willen kopieren vanuit een invoerblad naar een totaalblad. Ik heb een macro opgenomen waarmee ik dit kan. Deze macro blijft de gegevens op de eerste rij zetten. Dus hij overschrijft het al bestaande gegevens. Kan iemand mij helpen.

alvast bedankt

Felix474

 

[richard1970]

Hoi felix474,

Een heel simpele oplossing, mits er in kolom a geen lege cellen zijn:

Range("A1").End(xlDown).Offset(1, 0).Select

Zo ga je naar de eerste lege cel in kolom A.

Richard

 

[felix474]

dank je

Ik probeer het uit dank je wel voor de snelle reactie

Felix

 

[felix474]

Kom er niet uit

Dit is de code die ik ingeeft hij geeft foutmelding 1004. Enig idee

Selection.Copy
Sheets("Blad3").Select
Range("A1").End(xlDown).Offset(1, 0).Select
ActiveSheet.Paste
Sheets("Blad1").Select
Application.CutCopyMode = False
Selection.ClearContents
Range("C1").Select

 

[Wigi]

Ik vermoed dat je dit bedoelt:

Sub w()
    Selection.Cut Sheets("Blad3").Range("A1").End(xlDown).Offset(1)
    Application.Goto Sheets("Blad1").Range("C1")
End Sub

Wigi

 

[felix474]

Ik ben bang dat ik het niet goed uitleg

Ik wil graag bijv van werkblad 1 de cellen b1,b8,b10 en b14 kopieren naar werkblad 3 maar dan b1----naar a1
b8----naar b1
b10--- naar c1.
En de volgende keer als ik weer een nieuwe invoer doe moet hij deze nieuwe invoer kopieren naar

a2
b2
c2
Ik hoop dat ik het nu wel duidelijk heb uitgelegt. Ik hoop dat je mij kunt helpen.

alvast bedankt

Felix

 

[Wigi]

Is het altijd b1,b8,b10 en b14, of is dat ook veranderlijk?

 

[felix474]

Nee dit is altijd een vast gegeven. Het zijn altijd dezelfde cellen

 

[Wigi]

Zo dan:

Sub w()

    Dim i As Integer
    Dim lNextRow As Long
    
    If Sheets("Blad3").Range("A1").Value <> "" Then
        lNextRow = Sheets("Blad3").Range("A" & Rows.Count).End(xlUp).Row + 1
    Else
        lNextRow = 1
    End If
    
    For i = 1 To 4
        Sheets("Blad1").Range(Choose(i, "b1", "b8", "b10", "b14")).Copy Sheets("Blad3").Cells(lNextRow, i)
    Next

End Sub

Verander de bladnamen nog!

Wigi

 

[felix474]

Dank je wel

Dank je wel.

Dit is precies het antwoord voor mijn probleem

Dank daarvoor

Felix