@Teun,
Even je korte formule uitgeprobeerd, maar als ik bij jouw formule, 'Het huis is van de Slager' intyp krijg ik 'ager' als uitkomst.
En met 'Achterham van de slager' komt er ' de slager' uit...
Code:
=RECHTS(A2;VIND.SPEC(" ";A2;1))
Is het dus toch niet helemaal.
Uitleg; Excel gaat eerst op zoek via Vind.speciaal naar de (eerste) spatie en gebruik deze locatie waarde vervolgens in de Rechts formule.
In m'n eerste voorbeeld stond de spatie op positie 4 en vervolgens laat je met recht de 4 laatste (meest rechtse) tekens zien, en dat is 'ager'.
----------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------------
Voor de volledigheid waarom en hoe deze (mijn) formule dan wel werkt;
=RECHTS(A1;
LENGTE(A1)-VIND.ALLES("*";SUBSTITUEREN(A1;" ";"*";
LENGTE(A1)-LENGTE(SUBSTITUEREN(A1;" ";"")))))
Ik ga even uit van de volgende zin in cel A1;
Achterham van de slager
In de formule staat 2x
LENGTE(A1), deze is
23.
1). =RECHTS(A1;
23-VIND.ALLES("*";SUBSTITUEREN(A1;" ";"*";
23-LENGTE(
SUBSTITUEREN(A1;" ";"")))))
Achteraan staat
SUBSTITUEREN(A1;" ";""), dit betekend maak van
elke " " (spatie) die je tegen komt "", of wel geen spatie.
A1; Achterham van de slager wordt dan dus:
Achterhamvandeslager
2). =RECHTS(A1;
23-VIND.ALLES("*";SUBSTITUEREN(A1;" ";"*";
23-LENGTE(
Achterhamvandeslager)))
Vervolgens wordt er dus gekeken naar de lengte van
Achterhamvandeslager, dat zijn er
20.
3). =RECHTS(A1;
23-VIND.ALLES("*";
SUBSTITUEREN(A1;" ";"*";23-20)))
Nu kun je met SUBSTITUEREN tekens vervangen, maar dat kan ook selectief, in dit geval op de 3e (
23-
20) positie waar een spatie staat, en wel met een
*
4). =RECHTS(A1;
23-VIND.ALLES(
"*";Achterham van de*slager))
Met Vind.alles gaan we op zoek naar het
*-etje, vind.alles geeft ons de locatie in de tekst, in dit geval is dat
17.
5). =RECHTS(A1;
23-
17)
23-17 is 6 en met de formule =RECHTS krijgen we de 6 meest rechtse karakters als uitkomst van de gehele formule;
slager
