Leeftijd

[kappel]

=DATUMVERSCHIL(D80;VANDAAG();"j")

In cel d80 staat 25-11-1939 hoe bereken ik dan de leeftijd?

De formule die hier staat werkt niet, wat doe ik fout?

 

[HSV]

Maak van "j" → "y".

 

[kappel]

25-nov-1939 6-11-2016 76,00

Dank, ziet er al een stuk beter uit, ik ben dus over goed 2 weken 77 jaar.
Kan die 76 ook nog nauwkeuriger zoiets van 76 jaar en 11 maanden?

 

[Mde]

zo misschien

=DATUMVERSCHIL(D80;VANDAAG();"y") & " jaar, " & DATUMVERSCHIL(D80;VANDAAG();"ym") & " maand, " & DATUMVERSCHIL(D80;VANDAAG();"md") & " dagen"

 

[Cobbe]

Heb iets in een bestandje gezet.

 

[kappel]

Cobbe, allemachtig prachtig, nu kan ik op de bridgeclub de blits maken.
Bedankt.

 

[Cobbe]

Kleine dingen maken het leven aangenaam.

 

[snb]

Iets kleiner ?

=INT(DATEDIF($A$1;TODAY();"M")/12)&" jaar, "&MOD(DATEDIF($A$1;TODAY();"M");12)&" maanden en "&(EDATE(A1;DATEDIF($A$1;TODAY();"M")+1)-TODAY())&" dagen"

 

[Cobbe]

Eigenlijk was mijn formule niet veel langer, maar had er in verwerkt voor leeftijden kleiner dan 1 jaar dat er niet 0 jaar kwam te staan.

=DATUMVERSCHIL($A$1;VANDAAG();"Y")&" jaar,"&DATUMVERSCHIL($A$1;VANDAAG();"YM")&" maand en "&DATUMVERSCHIL($A$1;VANDAAG();"MD")&" dagen"

 

[popipipo]

Iets kleiner ?

Wel kleiner maar niet correct
Als ik vandaag geboren wordt ben ik al meteen 30 dagen oud???
Ben ik op 31 oktober geboren ben ik nu 23 dagen oud??

 

[robdgr]

Ik probeer onterechte meervoudswoorden te voorkomen en daardoor is de formule langer:

=ALS(A1=0;"";DATUMVERSCHIL(A1;VANDAAG();"y")&" jaar"&ALS(DATUMVERSCHIL(A1;VANDAAG();"ym")=0;"";", "&DATUMVERSCHIL(A1;VANDAAG();"ym")&ALS(DATUMVERSCHIL(A1;VANDAAG();"ym")=1;" maand";" maanden"))&ALS(DATUMVERSCHIL(A1;VANDAAG();"md")=0;"";", "&DATUMVERSCHIL(A1;VANDAAG();"md")&ALS(DATUMVERSCHIL(A1;VANDAAG();"md")=1;" dag";" dagen")))

 

[snb]

Ik ook:

=SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(DATEDIF(A1;TODAY();"Y")&" jaar, " & DATEDIF(A1;TODAY();"YM")&" maanden en " &DATEDIF(A1;TODAY();"MD") & " dagen";" 1 maanden";" 1 maand"); ", 0 maanden";"");" 1 dagen";" 1 dag");" en 0 dagen";"")

 

[mr0007]

=ALS(DATUMVERSCHIL(D80;VANDAAG();"Y")=113;0;DATUMVERSCHIL(D80;VANDAAG();"Y"))

deze formule om leeftijd te berekenen heb ik een tijd terug gekregen werkt goed

MVG mr0007

 

[snb]

@mr0007

Ben benieuwd hoeveel maanden en dagen daaruit komen ?

 

[mr0007]

25-11-1939

923 maanden

28108 dagen

MVG mr0007