Lege rij invoegen bij andere welwaarde

[Licorne]

Hallo,

Graag hulp bij deze.

Ik zou graag automatisch een lege rij laten invoegen bij elke veranderde waarde uit de eerste kolom.
Dit met als uitkomst verschillende blokken met een variabel aantal rijen die vet omrand zijn (of dikke lijn onder en bovenaan).

Alvast bedankt!

Bekijk bijlage Voorbeeld 2.xlsx

 

[Licorne]

Bij andere celwaarde dus

 

[Timshel]

Macrootje:

Sub tsh()
    Dim i As Long, j As Long
    
    For i = Cells(Rows.Count, 1).End(xlUp).Row To 2 Step -1
        If Cells(i, 1) <> Cells(i - 1, 1) Then
            Rows(i).Insert Shift:=xlDown
            For j = 7 To 10
                With Cells(i + 1, 1).CurrentRegion.Borders(j)
                    .LineStyle = xlContinuous
                    .Weight = xlThick
                End With
            Next
        End If
    Next
End Sub

 

[VenA]

of

Sub VenA()
Dim j As Long, ar
  For j = Cells(Rows.Count, 1).End(xlUp).Row To 3 Step -1
    If Cells(j, 1) <> Cells(j - 1, 1) Then Cells(j, 1).EntireRow.Insert
  Next j
  For Each ar In Range("A2:D" & Cells(Rows.Count, 1).End(xlUp).Row).SpecialCells(2).Areas
    ar.BorderAround xlContinuous, xlThick
  Next ar
End Sub

 

[Timshel]

Handig die BorderAround. Die kende ik nog niet :thumb:

 

[Licorne]

Werkt zeer mooi.
Thanks Guy's!