lege rij na elke key

[moensk]

in bijlage klein voorbeeld gemaakt
via Power Query tot tabblad "definitief" gekomen
nu wil ik een lege rij na elke nieuwe key.
kan dit ook in power query

 

[peter59]

Hallo,

Kijk eens naar deze link of dit een beetje in de buurt komt.
https://www.google.nl/search?q=add+empty+row+power+query&source=hp&ei=N8rLZJjuMciN9u8P5J-sgAI&iflsig=AD69kcEAAAAAZMvYRyaSPfACclM-WhFkAshPXPRXp7zO&oq=empty+row+powwer+query&gs_lp=Egdnd3Mtd2l6IhZlbXB0eSByb3cgcG93d2VyIHF1ZXJ5KgIIADIGEAAYFhgeMgYQABgWGB4yBhAAGBYYHjIGEAAYFhgeMgYQABgWGB4yBhAAGBYYHjIIEAAYBRgeGA0yCBAAGAUYHhgNMggQABgIGB4YDUi0UFAAWJY5cAB4AJABAJgBYKABgQ2qAQIyMrgBAcgBAPgBAcICERAuGIAEGLEDGIMBGMcBGNEDwgIFEAAYgATCAgsQABiABBixAxiDAcICDhAuGIAEGLEDGMcBGK8BwgILEC4YigUYsQMYgwHCAg4QLhiABBixAxjHARjRA8ICCBAuGIAEGLEDwgIIEAAYgAQYsQPCAgsQLhiABBjHARivAcICCxAuGIAEGLEDGIMBwgIIEC4YsQMYgATCAgUQLhiABA&sclient=gws-wiz#kpvalbx=_Q8rLZMDVN8CB9u8P9oSeyAw_26
of
https://www.google.nl/search?q=add+blank+row+power+query&source=hp&ei=wMrLZO8c8LmL6A_7sI6ADQ&iflsig=AD69kcEAAAAAZMvY0J6HfglqZV8d9TL1nsOvtF8cmVA1&oq=empty+row+power+query&gs_lp=Egdnd3Mtd2l6IhVlbXB0eSByb3cgcG93ZXIgcXVlcnkqAggCMgYQABgWGB4yBhAAGBYYHjIGEAAYFhgeMgYQABgWGB4yBhAAGBYYHjIGEAAYFhgeSIClAVAAWMJ0cAF4AJABAJgBcqABlgyqAQQyMS4xuAEByAEA-AEBwgIREC4YgAQYsQMYgwEYxwEY0QPCAgUQABiABMICCxAAGIAEGLEDGIMBwgILEC4YigUYsQMYgwHCAg4QLhiABBixAxjHARivAcICDhAuGIAEGLEDGMcBGNEDwgIIEC4YgAQYsQPCAggQABiABBixA8ICCxAuGIAEGMcBGK8BwgIHEC4YigUYQ8ICBxAAGIoFGEPCAg0QLhiKBRixAxiDARhDwgIIEC4YsQMYgATCAgsQLhiABBixAxiDAcICEBAuGIoFGLEDGMcBGNEDGEPCAgUQLhiABMICBxAAGA0YgATCAggQABgFGB4YDcICCBAAGAgYHhgN&sclient=gws-wiz#fpstate=ive&vld=cid:6ca14eaa,vid:IL9hTiYIcyM
of
https://www.google.nl/search?q=add+blank+row+power+query&source=hp&ei=wMrLZO8c8LmL6A_7sI6ADQ&iflsig=AD69kcEAAAAAZMvY0J6HfglqZV8d9TL1nsOvtF8cmVA1&oq=empty+row+power+query&gs_lp=Egdnd3Mtd2l6IhVlbXB0eSByb3cgcG93ZXIgcXVlcnkqAggCMgYQABgWGB4yBhAAGBYYHjIGEAAYFhgeMgYQABgWGB4yBhAAGBYYHjIGEAAYFhgeSIClAVAAWMJ0cAF4AJABAJgBcqABlgyqAQQyMS4xuAEByAEA-AEBwgIREC4YgAQYsQMYgwEYxwEY0QPCAgUQABiABMICCxAAGIAEGLEDGIMBwgILEC4YigUYsQMYgwHCAg4QLhiABBixAxjHARivAcICDhAuGIAEGLEDGMcBGNEDwgIIEC4YgAQYsQPCAggQABiABBixA8ICCxAuGIAEGMcBGK8BwgIHEC4YigUYQ8ICBxAAGIoFGEPCAg0QLhiKBRixAxiDARhDwgIIEC4YsQMYgATCAgsQLhiABBixAxiDAcICEBAuGIoFGLEDGMcBGNEDGEPCAgUQLhiABMICBxAAGA0YgATCAggQABgFGB4YDcICCBAAGAgYHhgN&sclient=gws-wiz#fpstate=ive&vld=cid:04783acb,vid:alqP3A8XQPc

 

[JEC.]

Ik heb 2 stappen toegevoegd in je Query onderin

let
    Bron = Excel.CurrentWorkbook(){[Name="Tabel1"]}[Content],
    #"Type gewijzigd" = Table.TransformColumnTypes(Bron,{{"key", Int64.Type}, {"datum", type date}, {"wagen", Int64.Type}, {"losnaam", type text}, {"postcode", Int64.Type}}),
    aantal_KD = Table.NestedJoin(#"Type gewijzigd", {"key", "datum"}, #"key&datum", {"key", "datum"}, "key&datum", JoinKind.LeftOuter),
    #"key&datum uitgevouwd" = Table.ExpandTableColumn(aantal_KD, "key&datum", {"Aantal_KD"}, {"key&datum.Aantal_KD"}),
    #"Namen van kolommen gewijzigd1" = Table.RenameColumns(#"key&datum uitgevouwd",{{"key&datum.Aantal_KD", "Aantal_KD"}}),
    aantal_KDW = Table.NestedJoin(#"Namen van kolommen gewijzigd1", {"key", "datum", "wagen"}, #"key&datum&wagen", {"key", "datum", "wagen"}, "Tabel1 (2)", JoinKind.LeftOuter),
    #"key&datum&wagen uitgevouwd" = Table.ExpandTableColumn(aantal_KDW, "Tabel1 (2)", {"aantal_KDW"}, {"Tabel1 (2).aantal_KDW"}),
    #"Namen van kolommen gewijzigd" = Table.RenameColumns(#"key&datum&wagen uitgevouwd",{{"Tabel1 (2).aantal_KDW", "Aantal_KDW"}}),
    #"aantal_KD=1 verwijdert" = Table.SelectRows(#"Namen van kolommen gewijzigd", each ([Aantal_KD] <> 1)),
    #"Aangepaste kolom toegevoegd" = Table.AddColumn(#"aantal_KD=1 verwijdert", "Aangepast", each [Aantal_KD]-[Aantal_KDW]),
    flt = Table.SelectRows(#"Aangepaste kolom toegevoegd", each ([Aangepast] <> 0)),
    xlist = List.Alternate({1..Table.RowCount(flt)+4},1,1,1),
    out = List.Accumulate(xlist, flt, (s,c) =>
                  Table.InsertRows(s, c, {Record.FromList(List.Repeat({null},Table.ColumnCount(flt)),Table.ColumnNames(flt))}))
in
    out

 

[JEC.]

Die vorige voegt letterlijk na ieder key regel een lege regel toe. Deze doet het dan op basis van unieke key

let
    Bron = Excel.CurrentWorkbook(){[Name="Tabel1"]}[Content],
    #"Type gewijzigd" = Table.TransformColumnTypes(Bron,{{"key", Int64.Type}, {"datum", type date}, {"wagen", Int64.Type}, {"losnaam", type text}, {"postcode", Int64.Type}}),
    aantal_KD = Table.NestedJoin(#"Type gewijzigd", {"key", "datum"}, #"key&datum", {"key", "datum"}, "key&datum", JoinKind.LeftOuter),
    #"key&datum uitgevouwd" = Table.ExpandTableColumn(aantal_KD, "key&datum", {"Aantal_KD"}, {"key&datum.Aantal_KD"}),
    #"Namen van kolommen gewijzigd1" = Table.RenameColumns(#"key&datum uitgevouwd",{{"key&datum.Aantal_KD", "Aantal_KD"}}),
    aantal_KDW = Table.NestedJoin(#"Namen van kolommen gewijzigd1", {"key", "datum", "wagen"}, #"key&datum&wagen", {"key", "datum", "wagen"}, "Tabel1 (2)", JoinKind.LeftOuter),
    #"key&datum&wagen uitgevouwd" = Table.ExpandTableColumn(aantal_KDW, "Tabel1 (2)", {"aantal_KDW"}, {"Tabel1 (2).aantal_KDW"}),
    #"Namen van kolommen gewijzigd" = Table.RenameColumns(#"key&datum&wagen uitgevouwd",{{"Tabel1 (2).aantal_KDW", "Aantal_KDW"}}),
    #"aantal_KD=1 verwijdert" = Table.SelectRows(#"Namen van kolommen gewijzigd", each ([Aantal_KD] <> 1)),
    nCol = Table.AddColumn(#"aantal_KD=1 verwijdert", "Aangepast", each [Aantal_KD]-[Aantal_KDW]),
    cols = Table.ColumnNames(nCol),
    grp = Table.Group(nCol, {"key"}, {{"Count", each Table.InsertRows(_,Table.RowCount(_), {Record.FromList(List.Repeat({null},Table.ColumnCount(_)),cols)} )}}),
    delCol = Table.RemoveColumns(grp,{"key"}),
    out = Table.ExpandTableColumn(delCol, "Count", cols, cols)
in
    out

 

[moensk]

allen bedankt - wat filmpjes bekeken en stuk wijzer geworden....

 

[JEC.]

Kant en klare suggesties van mij ga je niet proberen?

 

[moensk]

JEC jawel - maar was al bezig met filmpjes kijken en mijne aan te passen alvorens ik u oplossing zag ...
de uwe moet ik nog eens besturen in stappen

 

[JEC.]

Heb jouw query alleen uitgebreid. Je kan deze code in je advanced editor plakken ipv je huidige code

 

[moensk]

JEC de stap "cols = Table.ColumnNames(nCol)" snap ik ni, kunt ge die kort even toelichten aub

 

[moensk]

JEC,kan het ook zonder de hulptabellen "key&datum" en "key&datum&wagen" ?

 

[JEC.]

Deze is zonder hulptabellen

"cols = Table.ColumnNames(nCol)" geeft een list terug van de kolomheaders

let
    Bron = Excel.CurrentWorkbook(){[Name="Tabel1"]}[Content],
    types = Table.TransformColumnTypes(Bron,{{"key", Int64.Type}, {"datum", type date}, {"wagen", Int64.Type}, {"losnaam", type text}, {"postcode", Int64.Type}}),
    hdr= {{"key", "datum"},{"key", "datum", "wagen"}},    
    KD = Table.Group(types, hdr{0}, {{"Aantal", each Table.RowCount(_)}}),
    KDW = Table.Group(types, hdr{1}, {{"Aantal", each Table.RowCount(_)}}),
    merge_KD = Table.NestedJoin(types, hdr{0}, KD, hdr{0}, "key&datum", JoinKind.LeftOuter),
    merge_KDW = Table.NestedJoin(merge_KD, hdr{1}, KDW, hdr{1}, "Key&datum&wagen", JoinKind.LeftOuter),
    exp_KD = Table.ExpandTableColumn(merge_KDW, "key&datum", {"Aantal"}, {"key_datum"}),
    exp_KDW = Table.ExpandTableColumn(exp_KD, "Key&datum&wagen", {"Aantal"}, {"Key_datum_wagen"}),
    fltr = Table.SelectRows(exp_KDW, each ([key_datum] <> 1)),
    nCol = Table.AddColumn(fltr, "Aangepast", each [key_datum]-[Key_datum_wagen]),
    cols = Table.ColumnNames(nCol),
    grp = Table.Group(nCol, {"key"}, {{"Count", each Table.InsertRows(_,Table.RowCount(_), {Record.FromList(List.Repeat({null},Table.ColumnCount(_)),cols)} )}}),
    delCol = Table.RemoveColumns(grp,{"key"}),
    out = Table.ExpandTableColumn(delCol, "Count", cols, cols)
in
    out

 

[peter59]

@JEC

Prachtig!! Ik ga deze eens bestuderen.
Zelf heb ik verder geborduurd met de gegevens van Moensk.
En, het resultaat is het zelfde.

 

[JEC.]

Thanks Peter

 

[snb]

Gebruik een draaitabel.
Net zo gemakkelijk.
Lege regels zijn daarin volstrekt overbodig.
Hoe moeilijk wil je het jezelf maken ?

 

[peter59]

SNB,

Topic Starter vraagt, wij draaien.

 

[snb]

Daar bestaat een term voor: code monkeys.

 

[peter59]

Daar bestaat een term voor: code monkeys.

Code monkey is een informele term die verwijst naar een persoon die code of programma's schrijft voor computers. Het wordt vaak op een speelse of informele manier gebruikt en kan soms een licht negatieve bijklank hebben, waarbij gesuggereerd wordt dat de persoon repetitieve of alledaagse codeertaken uitvoert zonder veel creativiteit of begrip van de bredere context.

De term heeft niet noodzakelijk een vaste of officiële definitie, en het gebruik ervan kan variëren afhankelijk van de context. Soms wordt het gebruikt om softwareontwikkelaars, programmeurs of ingenieurs te beschrijven die zich voornamelijk richten op het schrijven van code zonder noodzakelijkerwijs diep betrokken te zijn bij het ontwerp, de architectuur of de strategische aspecten van een project. Het is echter belangrijk om op te merken dat de term niet altijd met een negatieve intentie wordt gebruikt en eenvoudigweg kan verwijzen naar iemand die bekwaam is in coderen.

In de afgelopen jaren is er een streven geweest naar het gebruik van meer respectvol en inclusief taalgebruik in de technologiesector. Het is daarom een goed idee om bewust te zijn van hoe je termen als "code monkey" gebruikt om ervoor te zorgen dat je een positieve en respectvolle omgeving bevordert.

Zo, weten we dat ook weer.

 

[JEC.]

@snb, laat de output dan maar eens zien in een draaitabel. Je kunt er verder niets mee vanuit een draaitabel.

Lege regels toevoegen snap ik ook niet maar de overige stappen wel.

Volgens mij is het forum ervoor om niet betrokken te zijn bij een project. Daar heb ik mijn werk voor…

 

[moensk]

ik heb nu eerste script aangepast omdat volledig af te hebben (voorbeeld in bijlage) waarbij ik hoopte dat hij ook zou controleren op "eerst volgende werkdag"
wat in dit geval 7/8 zou moeten zijn doch hij geeft 1/8 weer
wat gaat er fout ?

let
    Bron = Excel.CurrentWorkbook(){[Name="Tabel1"]}[Content],
    #"Type gewijzigd" = Table.TransformColumnTypes(Bron,{{"key", Int64.Type}, {"datum", type date}, {"wagen", Int64.Type}, {"losnaam", type text}, {"postcode", Int64.Type}}),
    aantal_KD = Table.NestedJoin(#"Type gewijzigd", {"key", "datum"}, #"key&datum", {"key", "datum"}, "key&datum", JoinKind.LeftOuter),
    #"key&datum uitgevouwd" = Table.ExpandTableColumn(aantal_KD, "key&datum", {"Aantal_KD"}, {"key&datum.Aantal_KD"}),
    #"Namen van kolommen gewijzigd1" = Table.RenameColumns(#"key&datum uitgevouwd",{{"key&datum.Aantal_KD", "Aantal_KD"}}),
    aantal_KDW = Table.NestedJoin(#"Namen van kolommen gewijzigd1", {"key", "datum", "wagen"}, #"key&datum&wagen", {"key", "datum", "wagen"}, "Tabel1 (2)", JoinKind.LeftOuter),
    #"key&datum&wagen uitgevouwd" = Table.ExpandTableColumn(aantal_KDW, "Tabel1 (2)", {"aantal_KDW"}, {"Tabel1 (2).aantal_KDW"}),
    #"Namen van kolommen gewijzigd" = Table.RenameColumns(#"key&datum&wagen uitgevouwd",{{"Tabel1 (2).aantal_KDW", "Aantal_KDW"}}),
    #"aantal_KD=1 verwijdert" = Table.SelectRows(#"Namen van kolommen gewijzigd", each ([Aantal_KD] <> 1)),
    #"Aangepaste kolom toegevoegd" = Table.AddColumn(#"aantal_KD=1 verwijdert", "Aangepast", each [Aantal_KD]-[Aantal_KDW]),
    #"Rijen gefilterd" = Table.SelectRows(#"Aangepaste kolom toegevoegd", each ([Aangepast] <> 0)),
     #"vandaag" = Date.From(DateTime.LocalNow()),
    #"xDates" =  List.Select(List.Dates(vandaag - #duration(4,0,0,0),8,#duration(1,0,0,0)), (x)=> Date.DayOfWeek(x,1) < 5),
    #"posistie" = List.PositionOf(xDates,vandaag),
    #"out" = Table.SelectRows(#"Rijen gefilterd", each ([datum] = xDates{posistie+1} ))
in
    #"out"

 

[JEC.]

Met de vorige posts doe je niets?

    #"vandaag" = Date.From(DateTime.LocalNow()),
    #"xDates" =  List.Select(List.Dates(vandaag - #duration(4,0,0,0),8,#duration(1,0,0,0)), (x)=> Date.DayOfWeek(x,1) < 5 and x > vandaag),
    #"out" = Table.SelectRows(#"Rijen gefilterd", each ([datum] = xDates{0} ))
in
    #"out"