Lege rijen toevoegen

[Koenie]

Hallo forummers,

Het bijgevoegde rapportageformulier is voorzien van een tabel.(formulier is standaard een .dot)

Wanneer een dienstdoende nu bij de laatste regel komt, dient hij door middel van een druk op de tab toets een regel toe te voegen.

Mijn vraag is of dit ook automatisch kan?


Gr.
Koen

 

[Koenie]

de bijlage dus

te snel verzonden.
hier dus de bijlage

 

[joost verdaasdo]

Hai Koenie,

Theoretisch zou dit met een Application Event in een Macro wel kunnen lukken.

Dit betekent echter wel dat men de macro altijd moet activeren terwijl men het document opent.

Ook moeten er op de pc enkele macro-instellingen goed ingesteld worden. (Is dit op één pc dan valt het best mee)

Of er een Event is wat geschikt is voor deze actie zou ik even moeten bekijken maar het lijkt mij in theorie wel mogelijk. (Alleen nogal erg veel moeite terwijl je één tabje van de oplossing verwijdert bent)

Heb je zelf al eens met macro's gewerkt?

Als je geïnteresseerd bent dan wil ik best eens een poging wagen deze macro te schrijven.

See Yah! :thumb:

 

[Koenie]

Joost,

mijn kennis van macro's binnen word is beperkt, dus als je de moeite zou willen nemen, dan houd ik mij aanbevolen.
Zoals je zelf al zegt zijn we maar één tabje van de oplossing verwijderd, maar ........ helaas heeft niet iedere collega zoveel kennis van het werken met word, dat het voor een ieder gemakkelijk is!! (niet lachen is echt zo)
Bedrijfsbreed worden rapportageformulieren nogal vaak met de hand ingevuld, echter zijn er ook opdrachtgevers die dit via de pc willen hebben.

Mocht je een totaal andere oplossing hebben voor een rapportageformulier, omdat het maken van die macro veel tijd/moeite gaat kosten, dan sta ik open voor suggesties.

Alvast bedankt voor de input

Koen

 

[joost verdaasdo]

Hai Koen,

Verwacht dat het redelijk wat werk zal zijn (om het juiste event te vinden) maar ik ga er even achterzitten voor je.

Einde van het weekend heb je het wel...vermoed ik.

See Yah!

 

[joost verdaasdo]

Hai Koen,

Nou het is gelukt hoor!

Zorg dat de macrobeveiling op gemiddeld staat! (menu/extra/macro/beveiliging)

De code:

'In ThisDocument: Dit is de Initialisatie van de Eventhandler
Option Explicit

Dim DoAppEvents As New AppEvents

Private Sub Document_Open()
    Set DoAppEvents.App = Application
End Sub

'In de Klassemodule AppEvents:

Option Explicit

Public WithEvents App As Application

Private Sub App_WindowSelectionChange(ByVal Sel As Selection)
    If Sel.Information(wdWithInTable) Then
        Dim iRow    As Long
        Dim iCol    As Long
            iRow = Sel.Tables(1).Rows.Count
            iCol = Sel.Tables(1).Columns.Count
            
            If Sel.Information(wdEndOfRangeRowNumber) = iRow Then
                If Sel.Information(wdEndOfRangeColumnNumber) = iCol Then
                    Dim oCell As Word.Cell
                        Set oCell = Sel.Cells(1)
                        Sel.InsertRowsBelow
                        oCell.Select
                        Set oCell = Nothing
                End If
            End If
    End If
End Sub

Zie bijlage voor jou document in actie!

Veel plezier ermee...:thumb:

 

[Koenie]

Joost bedankt

Hoi Joost,

heb net je aanpassing in de praktijk getest en het werkt fantastisch.

Bedankt voor je werk in deze.

gr
Koen

 

[joost verdaasdo]

Hai Koen,

Graag gedaan! :thumb: