Logische-test (zoeken op een deel van de tekst) "Bevat"

[Robert Smidt]

Beste Forumleden,

Ik ben op zoek naar een formule in de Als-functie dat bij logische-test vanuit een bepaalde cel wordt gekeken of hier in is opgenomen de tekst: "maand einde boekjaar" en dan gevolgd door een variabele.

Omdat deze variabele iedere keer anders is maar wel altijd begint met "maand einde boekjaar" moet de Als de variabele negeren. Zelf dacht ik aan: =ALS(Vragenformulier!H48="maand einde boekjaar *";1;2). Hier heb ik (*) als jokerteken opgenomen, echter werkt dat niet.

Heeft iemand voor mij de oplossing?

Alvast heel hartelijk dank.

Robert

 

[Conseclusie]

Gebruik SUBSTITUEREN i.c.m. LENGTE:

=ALS(LENGTE(A1)=LENGTE(SUBSTITUEREN(A1;"maand einde boekjaar";""));"NEE";"JA")

 

[VenA]

Probeer het zo eens. Wel even vertalen en aanpassen naar de eigen situatie.

=N(ISNUMBER(FIND("maand einde boekjaar";A1)))

 

[Robert Smidt]

Beiden dank voor het meedenken.

In geval van de eerste oplossing heb ik de formule aangepast in: =ALS(LENGTE(Vragenformulier!H48)=LENGTE(SUBSTITUEREN(Vragenformulier!H48;"maand einde boekjaar";""));"NEE";"JA").
Ik heb gekeken wat "Lengte" hier doet, in het eerste geval geeft deze de waarde 23 omdat de betreffende cel de tekst "maande einde boekjaar 12" bevat en het tweede geval geeft deze de waarde 12. Voor mij is het niet duidelijk wat nu precies de bedoeling is van deze formule.

 

[Conseclusie]

Lengte geeft het aantal karakters. Dus als de lengte van een waarde verschilt met diezelfde waarde waarbij de string "maand einde boekjaar" vervangen is door ""; dan weet je dat die string voorkomt in je waarde.

 

[Robert Smidt]

Volgens mij gaat er iets niet goed.

In mijn vragenformulier in de betreffende cel kan het voorkomen dat de volgende tekst in opgenomen wordt zoals: maand einde boekjaar 12, maand einde boekjaar 6, maand einde boekjaar 3 enz. Echter, kan het ook gebeuren dat er totaal iets anders staat. Het systeem moet wanneer maand einde boekjaar .. als uitkomst "Ja" hebben en wanneer er totaal iets anders staat, de tekst "Nee". Dus scenario 1 is Ja (waar) en scenario 2 is Nee (Onwaar). Nu is de uitkomst onwaar terwijl het waar moet zijn.

 

[Robert Smidt]

Ik heb een kleine aanpassing gedaan en volgens mij gaat het nu goed.

 

[Conseclusie]

?? Dan wissel je in de formule "NEE" en "JA" toch gewoon om?

 

[Robert Smidt]

Klopt, dat was dus mijn aanpassing. Super bedankt voor jouw hulp.

 

[VenA]

#3 blijkbaar gemist?

 

[Robert Smidt]

Beste VenA,

#3 heb ik niet gemist en zelfs op meerdere manieren uitgeprobeerd, helaas zonder resultaat, maar dat ligt aan mijn onkunde.

Omdat de andere oplossing, in mijn geval (en weer mijn onkunde), wel resultaat gaf, ben ik hier verder mee gegaan. Mijn verontschuldiging dat ik wellicht ongeïnteresseerd overkom, dat is zeker niet het geval en ik ben altijd enorm blij dat er mensen zoals jullie zijn die belangeloos de moeite nemen om de problemen op te lossen.

 

[VenA]

Lijkt mij niet zo moeilijk en daarom wordt er ook vaak om een voorbeeldbestand gevraagd.
In het Nederlands

=KIEZEN(ISGETAL(VIND.SPEC("maand einde boekjaar";Vragenformulier!A1))+1;"Nee";"Ja")

of

=ALS(ISGETAL(VIND.SPEC("maand einde boekjaar";Vragenformulier!A1));"Ja";"Nee")

of

=ISGETAL(VIND.SPEC("maand einde boekjaar";Vragenformulier!A1))

of

=N(ISGETAL(VIND.SPEC("maand einde boekjaar";Vragenformulier!A1)))

 

[HSV]

=KIEZEN(AANTAL.ALS(vragenformulier!H48;"maand einde boekjaar*")+1;"ja";"nee")

Of:

=ALS(AANTAL.ALS(vragenformulier!H48;"maand einde boekjaar*");"ja";"nee")

Of:

=N(AANTAL.ALS(vragenformulier!H48;"maand einde boekjaar*")=0)+1

Of:

=AANTAL.ALS(vragenformulier!H48;"maand einde boekjaar*")+1

Of:

=(AANTAL.ALS(vragenformulier!H48;"maand einde boekjaar*")=0)+1

 

[Robert Smidt]

Beiden nogmaals heel hartelijk bedankt voor jullie uitgebreide uitleg en voorbeelden. Ik ben hier hier echt heel blij mee en heb alle voorbeelden in een aparte map, waar ik alle antwoorden vanuit dit forum heb ontvangen, opgeslagen.