Logo in Rapport van current path

[allard1977]

Hallo,

Ik zou graag een logo vanuit het current path (waar de database ook staat) op een rapport tonen.

Option Compare Database
Option Explicit

Public Function DisplayImage(ctlImageControl As Control, strImagePath As Variant) As String
On Error GoTo Err_DisplayImage

Dim strResult As String
Dim strDatabasePath As String
Dim intSlashLocation As Integer

With ctlImageControl
    If IsNull(strImagePath) Then
        .Visible = False
        strResult = "No image name specified."
    Else
        If InStr(1, strImagePath, "\") = 0 Then
            ' Path is relative
            strDatabasePath = CurrentProject.FullName
            intSlashLocation = InStrRev(strDatabasePath, "\", Len(strDatabasePath))
            strDatabasePath = Left(strDatabasePath, intSlashLocation)
            strImagePath = strDatabasePath & strImagePath
        End If
    .Visible = True
    .Picture = strImagePath
    strResult = "Image found and displayed."
    End If
End With

Exit_DisplayImage:
    DisplayImage = strResult
    Exit Function

Err_DisplayImage:
    Select Case Err.Number
        Case 2220       ' Can't find the picture.
            ctlImageControl.Visible = False
            strResult = "Can't find image in the specified name."
            Resume Exit_DisplayImage:
        Case Else       ' Some other error.
            MsgBox Err.Number & " " & Err.Description
            strResult = "An error occurred displaying image."
            Resume Exit_DisplayImage:
    End Select
End Function

Dit is wat ik al gevonden heb, maar krijg hem niet werkend.

iemand ideeën?

 

[OctaFish]

Mooie functie, maar waarom een functie als het met één regel kan?

Private Sub Rapportkoptekst_Format(Cancel As Integer, FormatCount As Integer)
    On Error Resume Next
    Me.imgLogo.Picture = CurrentProject.Path & "\Startpunt.jpg"
End Sub

 

[allard1977]

Ja Dat is een stuk makkelijker. Super bedankt het werkt heel goed.
Maar zie dat de foto wat in kwaliteit achteruitgaat? Heeft u hier ervaring mee.

 

[OctaFish]

Als de grootte van de afbeelding in het rapport níet overeenkomt met die van de afbeelding zelf, moet er een compressie plaatsvinden, hetzij in de pluskant (meer pixels om uit te vergroten) hetzij in de min (pixels verwijderen om plaatje te verkleinen). Beiden doen weinig goeds voor de kwaliteit van de foto. Probeer dus een plaatje te gebruiken dat je niet hoeft aan te passen qua grootte.

 

[allard1977]

oke heel erg bedankt voor de info.

nog een ander vraagje.
ik zou graag if en then willen gebruiken.

IF Me.imgLogo.Picture = CurrentProject.Path & "\LOGO.jpg" = empty then
Me.imgLogo.visible = false
Me.txtLogo.visible = true
Else
Me.imgLogo.visible = true
Me.txtLogo.visible = false
end if

kunt u me misschien verder helpen?

 

[OctaFish]

Je denkt op de juiste weg, maar je zit op de verkeerde rijstrook

    With Me.imgLogo
        If Dir(CurrentProject.Path & "\Afbeeldingen\Logo.jpg") = "" Then
            .Visible = False
        Else
            .Picture = CurrentProject.Path & "\Afbeeldingen\Logo.jpg"
            .Visible = True
        End If
    End With

 

[allard1977]

Heel erg bedankt werkt super.