lotto

[don42]

Beste allemaal,

ik ben bezig om een lotto op te zetten
het is de bedoeling dat een variabel aantal deelnemers 10 nummers invult
kolom C t/m M
elke week worden 6 nummers getrokken die ik wil invullen van kolom P t/m U (getallen tussen 1 en 49)
nu zou ik graag zien dat in kolom M het aantal goede nummers komt te staan (per deelnemer)
en (mischien kan dat ook nog, dat de gevallen nummer een ander kleurtje krijgen)
We gaan door tot iemand alle 10 de nummers goed heeft dat kan dus een aantal weken duren
iemand een idee?

heb een voorbeeldje als bijlage
Bekijk bijlage lotto-g.xlsx

 

[Cobbe]

Ik denk dat je hier wel iets uit kunt halen/maken.

 

[don42]

Ik kom er hier niet uit waarom werkt dit niet

{=AANTAL(VERGELIJKEN(C5:L5;$C$24:$H$34;0))}

het probleem is dat men door wil gaan tot de 10 nummers van een deelnemer allemaal gevallen zijn
dat is niet in jouw voorbeeld, de aanpassing in de matrix formule werkt niet (ik sla de formule goed op met ctrl + shift + enter)

 

[Cobbe]

Die $H$34 dat kan niet, moet $H$24 zijn.

 

[MarcelBeug]

Een andere oplossing, matrixformule in M7 en kopiëren naar beneden:

=ALS(AANTAL($C7:$L7)<10;"";SOM(--ISGETAL(VERGELIJKEN($C7:$L7;KLEINSTE($P$7:$U$36;RIJ(INDEX(A:A;1):INDEX(A:A;MAX(1;AANTAL($P$7:$U$36)))));0))))

Edit: SOM(--ISGETAL kun je ook vervangen door AANTAL.

 

[don42]

Zo Marcel,
die komt heel dicht in de beurt zeg geweldig
Zoiets is niet mogelijk met VBA?

nu ga ik proberen met de op maak uit het voorbeeld van cobbe

 

[MarcelBeug]

Zoiets is niet mogelijk met VBA?

Eerlijk gezegd kan ik me niet voorstellen dat er met VBA iets niet mogelijk zou zijn, dat met een formule wél kan.

Als je graag VBA wilt, dan is het wel zo handig om dat in je vraag te vermelden of veel beter nog: in het onderwerp.

 

[rebmog]

Een iets kortere variant van de formule van Marcel:

=ALS(AANTAL(C7:L7)<10;"";AANTAL(VERGELIJKEN(C7:L7;KLEINSTE(P$7:U$36;RIJ(INDIRECT("1:"&AANTAL(P$7:U$36))));0)))

 

[MarcelBeug]

Een iets kortere variant van de formule van Marcel:

=ALS(AANTAL($C7:$L7)<10;"";AANTAL(VERGELIJKEN(C7:L7;KLEINSTE($P7:$U36;RIJ(INDIRECT("1:"&AANTAL($P7:$U36))));0)))

Afgezien dat-ie iets te kort is voor wat betreft het blokkeren van bereiken: mijn formule is wat langer indachtig het principe om vluchtige functies (zoals INDIRECT) zoveel mogelijk te vermijden.

 

[rebmog]

Afgezien dat-ie iets te kort is voor wat betreft het blokkeren van bereiken:

Klopt, zie ik nu ook. Heb ik aangepast.

mijn formule is wat langer indachtig het principe om vluchtige functies (zoals INDIRECT) zoveel mogelijk te vermijden.

Ik heb ook niet gezegd dat mij formule beter is . Het principe om volatile functies zoveel mogelijk te vermijden is op zich goed, want deze kunnen vertragend werken bij grote bestanden. Hetzelfde kan gezegd worden over matrixformules. Maar dat speelt hier natuurlijk geen enkele rol.

 

[HSV]

Of:

=SOMPRODUCT(AANTAL.ALS(C7:L7;P7:U7))

of als matrix
som ipv somproduct

 

[don42]

Allemaal heel erg bedankt voor de hulp

HSV, jouw optie is mooi kort
maar als er in 3 weken bv het getal 6 3 x getrokken wordt
dan telt hij het ook 3 x bij het totaal dat zou maar 1 keer moeten zijn
ik bereik dit eigenlijk alleen met oplossing #5



Nog 1 vraagje voor ik de vraag sluit (want het werkt echt zo als ik graag wil )
wat is het verschil voor of nadeel van een matrixformule

 

[HSV]

Matrix.

=SOM(ALS(AANTAL.ALS(P$7:U$36;C7:L7)>0;1;0))

Of:

=SOM(--(AANTAL.ALS(P$7:U$36;C7:L7)>0))

Of:

=SOM(N(AANTAL.ALS(P$7:U$36;C7:L7)>0))

Nadeel: Vele matrixformules in je werkblad zorgen ervoor dat het herberekenen lang duurt.
Voordeel: korter of robuuster.

 

[don42]

nogmaals bedankt

ik ben uiteindelijk hier mee geholpen

=ALS(AANTAL($C7:$L7)<10;"";SOMPRODUCT(N(AANTAL.ALS(P$7:U$36;C7:L7)>0)))

Bekijk bijlage lotto-db.xlsx
:thumb: