Maanden/MONTHS weergave

[Glenn2290]

Hello bestaat er een formule om maanden weer te geven in een cel die verwijst naar een cel waar de weeknummers genoteerd staan.
BV. In cel A1 staat 201901 kan ik dan adhv een formule in cel B1 "Januari" krijgen?

Thx!

 

[Conseclusie]

=TEKST(DATUM(LINKS(A1;4);RECHTS(A1;2);1);"mmmm")

 

[Glenn2290]

Hello,

Thx! Ik denk dat ik mijn vraag niet goed gesteld heb. De data in A1 zijn week nummers voorafgegaan door het jaar. Als ik uw formule probeer, dan werkt het prima voor de eerste week --> Januari, maar van het moment dat we week 2 zijn, geeft die met deze formule Februari aan, terwijl het eigenlijk nog steeds Januari is alleen zijn we week 2

Grtz
Glenn

 

[edmoor]

@Conseclusie:
Zo gebruik je RECHTS(A1;2) als maandnummer.
TS zegt dat het gaat om een weeknummer.

Het precies bepalen van de maand a.d.h.v. een weeknummer zal lastig zijn omdat weeknummers in 2 maanden kunnen vallen.

 

[Glenn2290]

Ik zie het verschil niet met hetgeen jij voorstelt en hetgeen in de eerste formule staat?
=TEKST(DATUM(LINKS(A1;4);RECHTS(A1;2);1);"mmmm")

 

[edmoor]

Ik deed geen voorstel voor een functie, ik constateerde alleen dat je zegt een weeknummer te gebruiken en Conseclusie dit als maandnummer gebruikt.

 

[AlexCEL]

Ik denk dat ik mijn vraag niet goed gesteld heb.

Inderdaad, want je hebt er geen voorbeeldbestand bij gedaan, waardoor er dus onduidelijkheid onstaat... (zie ook hier: https://www.helpmij.nl/forum/announcement.php?f=5).

Maar ok , probeer deze eens op gewenste resultaten:

=KIEZEN(MAAND(DATUM(LINKS(A1;4);1;RECHTS(A1;2)*7-2)-WEEKDAG(DATUM(RECHTS(A1;2);1;3)));"Jan";"Feb";"Mrt";"Apr";"Mei";"Jun";"Jul";"Aug";"Sep";"Okt";"Nov";"Dec")

=TEKST(MAX(DATUM(LINKS(A1;4);1;1);DATUM(LINKS(A1;4);1;1)-WEEKDAG(DATUM(LINKS(A1;4);1;1);2)+(RECHTS(A1;2)-1)*7+1);"mmmm")

 

[roeljongman]

Er is een standaardformule die de maandag kan bepalen.
met een kleine aanpassing kun je dan obv de woensdag (3e werkdag week) bepalen wat het maandnummer moet zijn (vergelijkbaar met de logica van het iso weeknummer die bepaald dat de week met eerste donderdagvan het jaar (donderdag dag 4 van 7) week 1 wordt)

dat levert de volgende formule

=MONTH(DATE(LEFT(A2;4);1;-2)-WEEKDAY(DATE(LEFT(A2;4);1;3))+2+RIGHT(A2;2)*7)

de month-weekday bepaald de laatste maandag van vorig jaar
de +2 schuift het naar woensdag
de Right(a2;2)*7 zorgt dat de woensdag voor betreffende week wordt gevonden waarop de maand wordt bepaald

zie ook bijlage voor de uitwerking

 

[snb]

Ik zou de maand bepalen van de eerste dag van zo'n week.
Gebruik 4 januari om de eerste ISO week van een jaar te bepalen.
Zie voor meer uitleg: https://www.snb-vba.eu/VBA_ISO_weeknummer.html

=MONTH(DATE(LEFT(A2;4);1;4)-WEEKDAY(DATE(LEFT(A2;4);1;4);2)+1+7*(RIGHT(A2;2)-1))

of

=TEXT(DATE(LEFT(A2;4);1;4)-WEEKDAY(DATE(LEFT(A2;4);1;4);2)+1+7*(RIGHT(A2;2)-1);"mmmm")

 

[AlexCEL]

Veel opties en hopelijk veel inspiratie voor TS.

 

[Glenn2290]

Super bedankt voor jullie hulp!! Hier ben ik inderdaad mee geholpen!!

Glenn

 

[Glenn2290]

Toch nog een vraagje hierover
Als ik de formule: =TEXT(DATE(LEFT(A2;1);1;1)-WEEKDAY(DATE(LEFT(A2;1);1;1);2)+1+7*(RIGHT(A2;2)-1);"mmmm") dan geeft dit als resultaat December? Wat moet ik aanpassen in de formule om het Januari te krijgen? Vanaf week krijg ik Januari en klopt de formule.

Grtz
Glenn

 

[edmoor]

Misschien handig om er ook even bij te vertellen wat er in A2 staat.

 

[Glenn2290]

201901 de weeknummer met het jaartal

 

[edmoor]

De maandag van week 201901 is 31-12-2018.
Logisch dus dat je daar december terug krijgt.

 

[Glenn2290]

Zo logisch is dat voor mij niet
Ik heb ondertussen dan deze formule gebruikt: =TEXT(DATE(LEFT(A2;4);1;4)-WEEKDAY(DATE(LEFT(A2;4);1;4);2)+1+7*(RIGHT(A2;2)-1);"mmmm")
want ik weet niet welk getal ik in de formule moet gebruiken om Januari in mijn cel te krijgen? Vandaar mijn vraag

 

[edmoor]

Je vraagt met die formule om de maandag van week 1 in 2019.
Dat is 31 december 2018.
Daarom krijg je december terug.
Daar lijkt me niks moeilijks aan te begrijpen.

Daarnaast heb ik al eerder genoemd dat het vragen naar een maand voor een weeknummer je er rekening mee moet houden dat die week in 2 maanden kan vallen.