Macro werkend houden bij beveiliging werkblad

[rv82]

Ik heb de volgende VBA code om te zorgen dat ik meerdere resultaten kan selecteren in een dropdown. Probleem is dat deze niet meer werkt zodra ik het werkblad beveilig. Stel dat het wachtwoord test123 is, wat zou ik dan moeten aanpassen om dit voor elkaar te krijgen?

Alvast bedankt!

Private Sub Worksheet_Change(ByVal Target As Range)

Dim Oldvalue As String
Dim Newvalue As String
Application.EnableEvents = True
On Error GoTo Exitsub
If Target.Column = 3 Or Target.Column = 5 Then
  If Target.SpecialCells(xlCellTypeAllValidation) Is Nothing Then
    GoTo Exitsub
  Else: If Target.Value = "" Then GoTo Exitsub Else
    Application.EnableEvents = False
    Newvalue = Target.Value
    Application.Undo
    Oldvalue = Target.Value
      If Oldvalue = "" Then
        Target.Value = Newvalue
      Else
        If InStr(1, Oldvalue, Newvalue) = 0 Then
            Target.Value = Oldvalue & ", " & Newvalue
      Else:
        Target.Value = Oldvalue
      End If
    End If
  End If
End If
Application.EnableEvents = True
Exitsub:
Application.EnableEvents = True

End Sub

 

[VenA]

Moet de eerste Application.EnableEvents = True niet false zijn?

welke error ga je hier ondervangen?

On Error GoTo Exitsub

 

[edmoor]

In het begin:
Activesheet.UnProtect "test123"

Aan het eind:
Activesheet.Protect "test123"

En naast wat VenA zegt is die code totaal onleesbaar.

 

[SjonR]

zet de werkzame code tussen Unprotect en Protect:

Sub SjonR()
ActiveSheet.Unprotect "Test123"

'' werkende code

ActiveSheet.Protect "Test123"

End Sub

 

[edmoor]

Je code een beetje opgekalefatert zodat het leesbaar is en de zaken voor je vraag er in gezet.
Zonder te testen uiteraard omdat je geen documentje hebt geplaatst.

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.SpecialCells(xlCellTypeAllValidation) Is Nothing Then Exit Sub
    If Target.Value = "" Then Exit Sub
        
    If Target.Column = 3 Or Target.Column = 5 Then
        Application.EnableEvents = False
        ActiveSheet.Unprotect "test123"
        Newvalue = Target.Value
        Application.Undo
        Oldvalue = Target.Value
        
        If Oldvalue = "" Then
            Target.Value = Newvalue
        Else
            If InStr(1, Oldvalue, Newvalue) = 0 Then
                Target.Value = Oldvalue & ", " & Newvalue
            Else
                Target.Value = Oldvalue
            End If
        End If
    End If
    
    ActiveSheet.Protect "test123"
    Application.EnableEvents = True
End Sub