magazijn lokatie zoeken

[ewh]

in de bijlage zie je een sheet waar materiaal is opgeslagen op welke lokatie
tab aanduiding 1 : 8 in B2 ( gele vak ) staat de lokatie
van B4 : B200 staan de nummers en C4: C200 de naam van de projeketleider

tab "Blad1" is het de bedoeling dat met in bv een userform , een nummer invult en vervolgens is het de bedoeling dat in het gele vak de lokatie, nummer, en naam worden geplaatst

op deze wijze kunnen we snel zien waar het materiaal ligt ( nummers kunnen op verschillende plaatsen liggen


wie kan hier mee helpen ? Bekijk bijlage voorbeeld magazijn.xls

 

[HSV]

Er is geen formulier, vandaar de inputbox.

Sub hsv()
Dim nummer, sh As Worksheet, c As Range
nummer = Application.InputBox("voer een nummer in", "zoek", , , , , , 1)
If nummer <> False and nummer <> "" Then
 For Each sh In Sheets
  If sh.Name <> "Blad1" Then
    Set c = sh.Columns(2).Find(nummer, , xlValues, xlWhole)
    If Not c Is Nothing Then
      Sheets("blad1").Range("n23").Resize(, 3) = Array(sh.Range("b2"),c, c.Offset(, 1))
      Exit For
    End If
   End If
Next sh
End If
End Sub

Voor meerdere alsook tekst.

Sub hsv()
Dim nummer, sh As Worksheet, c As Range
nummer = Application.InputBox("voer een nummer in", "zoek", , , , , , 1+2)
If nummer <> False and nummer <>"" Then
 For Each sh In Sheets
  If sh.Name <> "Blad1" Then
    Set c = sh.Columns(2).Find(nummer, , xlValues, xlWhole)
    If Not c Is Nothing Then
      Sheets("blad1").Cells(Rows.Count, 14).End(xlUp).Offset(1).Resize(, 3) = Array(sh.Range("b2"), c, c.Offset(, 1))
    End If
   End If
Next sh
End If
End Sub

Als het er veel meer kunnen zijn, is het pas een overweging om het in een keer weg te schrijven in een array.

 

[ewh]

HSV ,,bedankt voor je geweldige hulp

deze was ik nooit achter gekomen .
Ik heb de tweede code toegepast

bedankt