mail verplaatsen in VBA

[tepke]

hoi

hieronder heb ik een vba code die ik gebruik om bijlage op te slaan op de C: schijf hierna laat ik het mailtje als gelezen betitelen en ik stop het in een categorie jacob om te laten "zien" aan de gebruiker dat de bijlage "mailtje" opgeslagen is.
echter zou ik de ontvangen bijlage nog in een andere map willen plaatsen zodat hij niet bij regulieren mailtje komt. ik wil hem graag opslaan bij inbox in de map jacob.

ik kom er niet uit onder heb ik iets geprobeerd in rood

is er iemand die mij kan helpen


--------------------------------------------------------
Private WithEvents Items As Outlook.Items

Private Sub Application_Startup()
Dim olApp As Outlook.Application
Dim objNS As Outlook.NameSpace
Set olApp = Outlook.Application
Set objNS = olApp.GetNamespace("MAPI")
Set Items = objNS.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub Items_ItemAdd(ByVal item As Object)

On Error GoTo ErrorHandler

'Only act if it's a MailItem
Dim Msg As Outlook.MailItem
If TypeName(item) = "MailItem" Then
Set Msg = item

'Change variables to match need. Comment or delete any part unnecessary.
'Msg.SenderName in die naam van iemand
If (Msg.SenderEmailAddress = "marc-de-wit@live.nl") And _
(Msg.Subject = "order") And _
(Msg.Attachments.Count >= 1) Then

'Set folder to save in.
Dim olDestFldr As Outlook.MAPIFolder
Dim myAttachments As Outlook.Attachments
Dim Att As String

'location to save in. Can be root drive or mapped network drive.
Const attPath As String = "C:\test\"


' save attachment
Set myAttachments = item.Attachments
Att = myAttachments.item(1).DisplayName
myAttachments.item(1).SaveAsFile attPath & Att

' mark as read
Msg.UnRead = False

'Set the green jacob flag_catagorie icon
item.Categories = "jacob_gelezen"
item.save

'verplaats mijn ontvangen mail in een andere map

'item.Move myInbox.Folders("Jacob")
'item.save


End If
End If

ProgramExit:
Exit Sub

ErrorHandler:
MsgBox Err.Number & " - " & Err.Description
Resume ProgramExit
End Sub

 

[edmoor]

Het stukje: item.Move myInbox.Folders("Jacob")
Moet je vervangen door: item.Move FolderJacob

FolderJacob moet dan een object zijn in de juiste namespace en voor de juiste Inbox:

Dim myNameSpace As Outlook.NameSpace
Dim myInbox As Outlook.Folder
Dim FolderJacob As Outlook.Folder

Set myNameSpace = Application.GetNamespace("MAPI")
Set myInbox = myNameSpace.GetDefaultFolder(olFolderInbox)
Set FolderJacob = myInbox.Folders("Jacob")

 

[tepke]

bedankt

beste bedankt voor je hulp het werkt

 

[edmoor]

Ok dan. En graag gedaan