Mail versturen vanuit Excel naar meerdere personen

[WiBi]

Goedemorgen allen,

Ik ben op zoek naar een code of een andere manier om vanuit excel (waar ik meerdere mailadressen heb staan) een knop te genereren waarbij ik met een druk op de knop een mailtje kan sturen aan de personen welke in het excel bestand staan.

In de bijlage een bestand met 4 voorbeeld adressen.

Alvast bedankt voor de mogelijke oplossingen.

Met vriendelijke groet
WiBiBekijk bijlage test1.xlsx

 

[Timshel]

Sub tsh()
    Dim Br
    Dim i As Long
    
    Br = Sheets("Blad1").Range("A2").CurrentRegion
    For i = 1 To UBound(Br)
        With CreateObject("Outlook.Application").CreateItem(0)
            .To = Br(i, 1)
            .Subject = "Foreclosure"
            .Body = "Dear Mr. Tsipras"
            .Display
        End With
    Next
End Sub

 

[WiBi]

Goedemorgen,

Allereerst dank voor uw snelle reactie.
Als ik nu de knop gebruik dan krijg ik 4 losse mail vensters, graag zou ik gewoon alle mailadressen in de "AAN" lijst willen hebben zodat ik 1 keer een mail hoef te tikken.
Alvast bedankt voor de reactie.

 

[edmoor]

Probeer het eens zo:

Sub tsh()
    Dim Br
    Dim Ontvangers As String
    Dim i As Long
    
    Br = Sheets("Blad1").Range("A2").CurrentRegion
    For i = 1 To UBound(Br)
        Ontvangers = Ontvangers & Br(i) & ";"
    Next
    
    With CreateObject("Outlook.Application").CreateItem(0)
        .To = Ontvangers
        .Subject = "Foreclosure"
        .Body = "Dear Mr. Tsipras"
        .Display
    End With
End Sub

 

[WiBi]

Hoi Edmoor,

Ik heb het bestand met de code welke jij aangaf te proberen bijgevoegd maar dan krijg ik een foutmelding,
zou jij eens kunnen kijken naar dat bestand?
Alvast bedankt.

Met vriendelijke groet WilliamBekijk bijlage test1.xlsm

 

[edmoor]

Als je zegt een foutmelding te krijgen is het ook wel handig om deze erbij te vermelden.

 

[Timshel]

Ik denk zo:

Sub tsh()
    Dim Br
    Dim Ontvangers As String
    Dim i As Long
    
    Br = Sheets("Blad1").Range("A2").CurrentRegion
    For i = 1 To UBound(Br)
        Ontvangers = Ontvangers & Br(i[COLOR="#FF0000"], 1[/COLOR]) & ";"
    Next
    
    With CreateObject("Outlook.Application").CreateItem(0)
        .To = Ontvangers
        .Subject = "Foreclosure"
        .Body = "Dear Mr. Tsipras"
        .Display
    End With
End Sub

Je kunt overigens ook een bereik met e-mailadressen uit XL kopiëren en plakken in het AAN-veld van je mail.
Nog even Namen Controleren en klaar ben je.

 

[WiBi]

Edmoor,

Bedankt, excuses ik zal volgende keer mijn foutmelding erbij vermelden maar tot zover bedankt.

 

[WiBi]

sorry heren,

Ik was even te snel met zeggen dat het werkt, ik heb het bestand waar het om draait bijgevoegd.
Als ik nu op de knop in het bestand klik dan krijg ik alleen het woord gemeente in mijn "aan" lijst, ik hoop dat jullie mij nogmaals kunnen helpen.

Timshel als ik de namen wil kopiëren dan zegt excel dat deze bewerking niet uitgevoerd kan worden.

Alvast bedankt voor de reacties

Mvg

William
Bekijk bijlage gegevens team ZW.xlsm

 

[edmoor]

Maak er dit van:

Sub tsh()
    Dim Br
    Dim Ontvangers As String
    Dim i As Long
    
    Br = Sheets("Blad1").Range("F2").CurrentRegion
    For i = 2 To UBound(Br)
        Ontvangers = Ontvangers & Br(i, 6) & ";"
    Next
    
    With CreateObject("Outlook.Application").CreateItem(0)
        .To = Ontvangers
        .Subject = "Foreclosure"
        .Body = "Dear Mr. Tsipras"
        .Display
    End With
End Sub

 

[HSV]

Of:

Br = Sheets("Blad1").Range("F2", Range("F2").End(xlDown))
    Ontvangers = Join(Application.Transpose(Br), ";")

 

[snb]

of

.To = join(filter(application.transpose(Sheets("Blad1").columns(6).specialcells(2)),"@"),";")

 

[WiBi]

Heren goedemorgen,

Bedankt voor de reacties, het werkt en ik ben ermee geholpen.

Met vriendelijke groet,

William