Mail verzenden ZONDER bijlage

[vrouw]

Hoi,

Ik wil een mail verzenden vanuit Excel ZONDER dat er een bijlage of iets dergelijks word mee gezonden.
Er moeten mail adressen uit cellen gehaald worden en verder moet er een onderwerp in de subject regel komen en het belangrijkste is dat er ook een bericht in de mail(Body) komt te staan.

Ik weet dat er bij Ron de Bruin op de site heel veel staat maar dat is allemaal met het meezenden van een bijlage.

Ik wil mailen omdat er dmv een document wat bestanden zijn gemaakt en klaarstaan voor gebruik voor de gebruikers.
Dmv die mail (gestart vanuit het document) wil ik dus de gebruikers inlichten dat er op een bepaalde lokatie (liefst met een snelkoppeling naar de map) de documenten klaarstaan.

 

[vanveelen]

Hoi,

Mailen vanuit Outlook dus en niet vanuit Word of Excel .....
De evt. mailadressen moet je dan eerst importeren in Outlook.

 

[vrouw]

Nee ik wil mailen vanuit Excel.

 

[HWV]

Is dit wat je bedoeld

Private Sub Sendmail_Click()

Dim olApp As Outlook.Application
Dim olMail As MailItem

    Set olApp = New Outlook.Application
    Set olMail = olApp.CreateItem(olMailItem)

    With olMail
        .To = "hwv@helpmij.nll"
        '.CC = "iemandanders@test.nl"
        .Subject = "Digitale bericht"
        .Body = "Tik hier de tekst wat er in je body moet komen te staan"
        .Display
        .Send
    End With

    Set olMail = Nothing
    Set olApp = Nothing
    
    
End Sub

Vergeet niet bij extra verwijzingen microsoft outlook 12.0 libary aan te vinken want anders werkt het niet

Groet

HWV

 

[Warme bakkertje]

Met de namen in kolom A en de mailadressen in kolom B

Sub SendMassEmail()
Dim OutlookApp As Outlook.Application, MItem As Outlook.MailItem
Dim cell As Range, Subj As String, EmailAddr As String, Recipient As String
Application.ScreenUpdating = False
Set OutlookApp = New Outlook.Application
For Each cell In Columns("B").Cells.SpecialCells(xlCellTypeConstants)
    If cell.Value Like "*@*" Then
        Subj = "Nieuwe bestanden"
        Recipient = cell.Offset(0, -1).Value
        EmailAddr = cell.Value
        Msg = "Geachte " & Recipient & vbCrLf & vbCrLf
        Msg = Msg & "Langs deze weg wil ik je op de hoogte brengen dat er nieuwe bestanden ter uwer beshikking staan" & vbCrLf & vbCrLf
        Msg = Msg & "Met vriendelijke groet." & vbCrLf & vbCrLf
        Msg = Msg & "Vrouw"
    Set MItem = OutlookApp.CreateItem(olMailItem)
    With MItem
        .To = EmailAddr
        .Subject = Subj
        .body = Msg
        .Send
    End With
End If
Next
Application.ScreenUpdating = True
End Sub

 

[vrouw]

Bedankt voor de hulp ga het morgen testen maar ik werk met Lotus Notes, zal het daar ook mee gaan?

 

[vrouw]

Het is inmiddels gelukt om te mailen vanuit excel met lotus notes met onderstaande Code.

Sub SendNotesMail()
Dim Maildb As Object, UserName As String, MailDbName As String
Dim MailDoc As Object, Session As Object
Dim cl As Range
Set Session = CreateObject("Notes.NotesSession")
UserName = Session.UserName
MailDbName = Left$(UserName, 1) & Right$(UserName, _
(Len(UserName) - InStr(1, UserName, " "))) & ".nsf"
Set Maildb = Session.GetDatabase("", MailDbName)
If Not Maildb.IsOpen Then Maildb.OpenMail
For Each cl In Range([O1], [P1].End(3))
Set MailDoc = Maildb.CreateDocument
MailDoc.Form = "Memo"
MailDoc.SendTo = Right$(cl, Len(cl) - 0) 'Nickname or full address
'MailDoc.CopyTo = Whomever
'MailDoc.BlindCopyTo = Whomever
MailDoc.Subject = " Onderwerpregel "
MailDoc.Body = _
Replace("Beste Collega`s" & _
"" & _
cl(, 2) & _
" " & _
"@@ het bestand staat klaar en dat kan je hier vinden." & _
"@@ " & _
"[COLOR="Red"]Hier zou ik een snelkoppeling willen hebben[/COLOR]: " & _
"@@ nieuwe regel", "@", vbCrLf)
MailDoc.SaveMessageOnSend = True
MailDoc.PostedDate = Now
On Error GoTo Audi
Call MailDoc.Send(False)
Audi: On Error GoTo 0
Next
'Session.Quit
Set Maildb = Nothing: Set MailDoc = Nothing: Set Session = Nothing
MsgBox "  De Mail is verzonden naar alle medewerkers  "
End Sub

Nu zou ik nog in het mail bericht dat er in de body een snelkoppeling komt naar de lokatie waar het bestand staat.
Ik weet echter niet hoe dit aan te maken zodat het "aanklikbaar" is.