mailto gebruiken met e-mail in een cell

[Schipper1994]

ik heb wat aan het zoeken geweest maar vind deze niet terug in andere vragen.

ik wil een sheet versturen via een mail, hoe ik dat doe weet ik.
maar.
ik wil die sheet versturen naar een mailadres die bijvoorbeeld in cell A1 staat, uiteraard via VBA.


voorbeeld

ik wil Sheet1 versturen naar een mailadres dat genoteerd staat in cell A1.

alvast bedankt

 

[edmoor]

Kijk eens hier:
https://www.rondebruin.nl/win/s1/outlook/amail2.htm

Zet dan bij .to =
.to = Range("A1")

Of kijk eens hier:
https://www.extendoffice.com/documents/excel/2688-excel-mailto-link.html

Of laat zien hoe je dat nu doet.

 

[JEC.]

Als je "Mail VBA" intikt in de zoekbalk van het forum ga je echt vinden wat je zoekt.

 

[snb]

Sub M_mail_met_hyperlink()
  With ActiveWorkbook
    .SaveAs "__hyperlinkmail.xlsb", 50
    .FollowHyperlink "mailto:" & [A3] & "?subject=Voorbeeld van " & .Name & "&body=Please check: %0A%0A   File    : <File://" & .FullName & ">%0A   Folder: <File://" & .Path & "\>"
  End With
End Sub

 

[Schipper1994]

ik heb dit ondertussen kunnen oplossen door verschillende dingen te zoeken en te proberen via allerlei websites. toch bedankt.

 

[snb]

Fijn dat je de gevonden oplossing voor ons verborgen houdt.

 

[Schipper1994]

snb,
u heeft gelijk, niet aardig van me.

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range
 
Set xSht = Worksheets("bladnaam")
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

'ophalen opslaglocatie
    With xFileDlg
       .InitialFileName = Sheets("bladnaam").Range("b10")
    End With
 
If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" & xSht.Cells(12, 5) & ".pdf"
 
'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If
 
Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
     
    'Create Outlook email
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = xSht.Cells(16, 9)
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
        '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

deze slaat een pdf op een gewenste locatie die je van te voren invoert.
open achteraf OUTLOOK
onderwerp en mailadres is al ingevoerd vanuit excel.