Marco gegevens Excel overzetten naar word bestand

[weusty]

Ik ben opzoek naar een marco die gegevens die ik op een excelsheet heb staan invult in een bestaand word sjabloon.

Ik heb al een aantal macro's hiervoor gevonden maar krijg deze niet werkende.

Heeft iemand toevallig een éénvoudig voorbeeld voor excel 2003?

mvg weust

 

[Warme bakkertje]

Hier kan je wel een ideetje uithalen.
http://www.vbaexpress.com/kb/getarticle.php?kb_id=381

 

[weusty]

Dankje,

hier kan ik wel wat mee denk ik!

 

[weusty]

Voor de geïnteresseerden, het werkt als volgt (erg simpel):

- Benoem een aantal bladwijzers in WORD
- Benoem daarna een aantal cellen in EXCEL precies hetzelfde als de bladwijzers in word (naam > definiëren)
- Sla het EXCEL bestand en het WORD bestand(.dot) op in dezelfde map.
- Vul de bewuste cellen in EXCEL in en start onderstaande macro.

Sub BCMerge()
Dim pappWord As Object
Dim docWord As Object
Dim wb As Excel.Workbook
Dim xlName As Excel.Name
Dim TodayDate As String
Dim Path As String

  Set wb = ActiveWorkbook
  TodayDate = Format(Date, "mmmm d, yyyy")
  Path = wb.Path & "\Omzetten.dot"
  
  On Error GoTo ErrorHandler

'Create a new Word Session
  Set pappWord = CreateObject("Word.Application")
  
  On Error GoTo ErrorHandler

'Open document in word
  Set docWord = pappWord.Documents.Add(Path)

'Loop through names in the activeworkbook
  For Each xlName In wb.Names
    'if xlName's name is existing in document then put the value in place of the bookmark
    If docWord.Bookmarks.Exists(xlName.Name) Then
      docWord.Bookmarks(xlName.Name).Range.Text = Range(xlName.Value)
    End If
  Next xlName

'Activate word and display document
  With pappWord
      .Visible = True
      .ActiveWindow.WindowState = 0
      .Activate
  End With

'Release the Word object to save memory and exit macro
ErrorExit:
   Set pappWord = Nothing
   Exit Sub

'Error Handling routine
ErrorHandler:
   If Err Then
      MsgBox "Error No: " & Err.Number & "; There is a problem"
      If Not pappWord Is Nothing Then
        pappWord.Quit False
      End If
      Resume ErrorExit
   End If
End Sub

BRON: de door Warme bakkertje genoemde site!

Succes