meerdere email vanuit concepten tegelijk versturen

[daanblaauwgeers]

Goedemiddag,

Ik heb ongeveer 50 e-mails (met verschillende geadresseerden en inhoud) in de map concepten van outlook staan. Is er een slimme manier om deze in 1 keer te versturen? Dus met 1 druk op de knop zonder alle e-mails te openen? Moet er een stukje code geschreven worden? Of is er een andere manier?

Kan iemand mij helpen?

Alvast bedankt!

Mvg,

Daan Blaauwgeers

 

[OctaFish]

Dat kun je met een macro wel voor elkaar krijgen. Daarbij is het wel noodzakelijk dat je in de macro kijkt of het emailadres wel is ingevuld, want anders krijg je natuurlijk een foutmelding.

Public Sub SendDrafts()
'Send all items in the "Drafts" folder that have a "To" address filled in.
Dim itm As Integer
Dim appOut As Outlook.Application
Dim myNameSpace As Outlook.NameSpace
Dim myFolders As Outlook.Folders
Dim myDraftsFolder As Outlook.MAPIFolder

    'Setup Outlook
    Set appOut = Outlook.Application
    Set myNameSpace = appOut.GetNamespace("MAPI")
    Set myFolders = myNameSpace.Folders
    
    'Set Draft Folder.
    Set myDraftsFolder = myFolders("Mailbox - jouw naam").Folders("Concepten")
    
    'Loop through all Draft Items
    For itm = myDraftsFolder.Items.Count To 1 Step -1
        'Check for "To" address and only send if "To" is filled in.
        If Len(Trim(myDraftsFolder.Items.Item(itm).To)) > 0 Then
        'Send Item
        myDraftsFolder.Items.Item(itm).Send
        End If
    Next itm
    
    'Clean-up
    Set myDraftsFolder = Nothing
    Set myNameSpace = Nothing
    Set appOut = Nothing

End Sub

 

[daanblaauwgeers]

Hartstikke mooi dankjewel