Meerdere zoekresultaten in 1 cel weergeven

[MrLampie]

Goedemiddag,

Is het mogelijk om via de zoekfunctie naar een bepaalde waarde, wanneer er meerdere resultaten zijn om deze resultaten dan in 1 cel weer te geven gescheiden door een scheidingsteken zoals bijvoorbeeld /

In mijn voorbeeld heb ik namelijk een factuur, maar voor die factuur zijn meerdere dossiers te vinden. Ik wil dus dat hij in die sheet naast de cel waar het factuurnummer staat, alle resultaten gaat vermelden

In mijn sheetvoorbeeld heb ik in cel G6 factuur abcd en hiervoor zijn 3 dossiers te vinden. Ik wil dus dat hij dan in cel H6 deze 3 dossiers op deze manier vermeld: 3544548/3544887/3155489

3 is niet het maximale resultaat wat terug zou kunnen komen. Er zouden ook best 15 dossiers voor 1 factuur kunnen zijn.

Is er een formule om zoiets voor elkaar te krijgen? Mij is het niet gelukt en met chatgtp kom ik er ook niet uit. Dus hopelijk kan iemand van jullie mij hiermee helpen

Alvast bedankt!

 

[AHulpje]

Zo misschien:

 

[peter59]

Of met power query?

 

[HSV]

Office 365.

=WEGLATEN(GROEPEREN.PER(R5:R15;S5:T15;KIEZEN({1\2};ARRAYTOTEXT;SOM);3;0);1)

 

[jverkerk]

Of met een functie.
Na het downloaden wel het blokkeren opheffen.

 

[popipipo]

=TEXTJOIN("/";;TRANSPOSE(FILTER($S$6:$S$15;$R$6:$R$15=G6)))

Of deze misschien wel als je specifiek de / als scheidingsteken wilt hebben.

 

[HSV]

Voor de gehele rits net als de vorige maar met "/" als scheidingsteken.

=SUBSTITUEREN(WEGLATEN(GROEPEREN.PER(R5:R15;S5:T15;KIEZEN({1\2};ARRAYTOTEXT;SOM);3;0);1);"; ";"/")

 

[popipipo]

Genoeg antwoorden om en keuze uit te maken

 

[MrLampie]

Wow, ik had niet zo snel al zo veel reacties verwacht, thanks!

Bij een aantal formules krijg ik als melding #OVERLOOP!, ik weet niet precies waar dat aan ligt. Dat kreeg ik zelf ook steeds als ik het probeerde, maar als ik het ging googlen las ik dat het misschien aan mijn excelversie kon liggen.

Maar met de oplossing van AHulpje krijg ik er zo goed als wat ik wil uit. Ik ga die formule in een macro verwerken en dan ga ik via de macro de puntkomma's die hij nu als scheidingsteken geeft vervangen voor de / als scheidingsteken. Dus het lijkt erop alsof jullie mij uitstekend en zo snel geholpen hebben met mijn probleem

 

[HSV]

Een formule voor alle gegevens Factuur, dossiers en bedragen.
De omringede cellen leeg maken voorkomt #OVERLOOP!.
De formule heeft niet voldoende ruimte.

 

[AHulpje]

Hoef je geen macro voor te maken:

=SUBSTITUEREN(ARRAYTOTEXT(TRANSPONEREN(FILTER($S$6:$S$15;$R$6:$R$15=G6)));";";"/")

Hele kleine aanpassing:

=SUBSTITUEREN(ARRAYTOTEXT(TRANSPONEREN(FILTER($S$6:$S$15;$R$6:$R$15=G6)));"; ";"/")

 

[HSV]

Helpt dat TRANSPONEREN?

 

[AHulpje]

Eh, nee, maar kwaad kan het ook niet.
Omdat FILTER(...) een kolom opleverde heb ik daar TRANSPONEREN omheen gezet, is dus niet nodig. Weer wat geleerd!

 

[MrLampie]

Hoef je geen macro voor te maken:

=SUBSTITUEREN(ARRAYTOTEXT(TRANSPONEREN(FILTER($S$6:$S$15;$R$6:$R$15=G6)));";";"/")

Hele kleine aanpassing:

=SUBSTITUEREN(ARRAYTOTEXT(TRANSPONEREN(FILTER($S$6:$S$15;$R$6:$R$15=G6)));"; ";"/")

Deze werken perfect voor mij

Ik verwerk het wel sowieso in een macro, want ik krijg elke maand een lijst met dit soort data waarin nog veel meer moet gebeuren, maar ik kreeg dit gedeelte dus niet voor elkaar, maar nu dus wel, nogmaals bedankt!

 

[peter59]

Ik krijg elke maand een lijst met dit soort data waarin nog veel meer moet gebeuren

Dan laat je licht maar eens schijnen op power query. Geen formules en geen macro's.