Meest voorkomende waarde weergeven

[Chris15]

Ik zoek een formule om de meest voorkomende waarde/tekst weer te geven.

Voorbeeld:
In B1 staat de tekst L
In C1 staat de tekst L
In D1 staat de tekst S

Ik wil dus de meest voorkomende waarde, dus L zien in A1

Is hier een formule voor?

 

[AlexCEL]

Wel heel beknopt voorbeeldje, gaat het echt maar om drie kolommen?

Deze is uit te breiden tot zoveel kolommen je wilt (let op: matrixfunctie, mogelijk afsluiten met Control+Shift+Enter als je geen Excel 365 gebruikt):

=INDEX(1:1;;MIN(ALS(AANTAL.ALS(B1:D1;B1:D1)=MAX(AANTAL.ALS(B1:D1;B1:D1));KOLOM(B:D))))

Mocht het om maar 3 kolommen gaan kan deze:

=ALS(AANTAL.ALS(B1:D1;B1)>1;B1;ALS(AANTAL.ALS(B1:D1;C1)>1;C1;ALS(AANTAL.ALS(B1:D1;B1)>1;D1;"Alle waarden komen even vaak voor. Wat nu?")))

En mits je Excel 365 gebruikt kan deze ook:

=UNIEK(TRANSPONEREN(FILTER(B1:D1;AANTAL.ALS(B1:D1;B1:D1)=MAX(AANTAL.ALS(B1:D1;B1:D1));"")))

 

[Chris15]

Dank je AlexCel! Werkt perfect!

 

[snb]

Vertikaal: array formule

=INDEX($A$1:$A$13;MATCH(MAX(COUNTIF($A$1:$A$13;A1:A13));COUNTIF($A$1:$A$13;A1:A13);0))

Horizontaal

=INDEX($A$1:$Z$1;MATCH(MAX(COUNTIF($A$1:$Z$1;A1:Z1));COUNTIF($A$1:$Z$1;A1:Z1);0))

 

[JEC.]

Deze simpele formule doet de truc ook

=INDEX(A1:E1;MODUS(VERGELIJKEN(A1:E1;A1:E1;0)))

 

[AlexCEL]

Nice :thumb:

 

[HSV]

Als alles is ingevuld.

=TEKEN(MODUS(CODE(A1:E1)))

=CHAR(MODE(CODE(A1:E1)))

Anders de matrix.

=TEKEN(MODUS(ALS.FOUT(CODE(A1:E1);"")))

=CHAR(MODE(iferror(CODE(A1:E1),"")))

 

[AlexCEL]

Ook nice :thumb:

 

[JEC.]

Die werkt alleen als het 1 letter bevat @HSV

 

[HSV]

Niks mis mee gezien de vraagstelling.