Melding ONWAAR verbergen

[HarmenD]

Beste experts,

De kolommen L en M bestaan uit een keuzemenu, waarbij de mogelijkheden in kolom M afhankelijk zijn van de keuze welke is gemaakt in kolom L;
In cel O1 staat een formule met geneste ALS met VERT.ZKN functie.
Deze is misschien niet zo elegant, maar doet wat hij moet doen!
In tabblad 'Nieuwe opdrachten' staat een

Private Sub Worksheet_Change(ByVal Target As Range)

Wanneer een naam in kolom B wordt ingevuld wordt de formule in cel O1 naar de cellen daaronder gekopieerd.
Wanneer er in een regel de cellen van kolom L en M leeg blijven, krijg ik in de cel van kolom O de vermelding 'ONWAAR'.
Het lukt mij niet deze melding te verbergen (heb al geprobeerd met ISNB, ISFOUT e.d. maar krijg dit niet op de juiste positie).
Graag zie ik jullie mogelijke oplossingen voor dit probleem.

Met dank al vast voor de mogelijke tijd die je hier in steekt.

mvg
]-[armenD

 

[VenA]

Waarom gebruik je geen echte tabel? Dan gaan de formules automatisch mee.

Je moet even toetsen of er in kolom M wel wat ingevuld is.

=IF(M1="";"";IF(L1="dealer1";VLOOKUP(M1;o_ac_d1;2;0);IF(L1="dealer2";VLOOKUP(M1;o_ac_d2;2;0);IF(L1="dealer3";VLOOKUP(M1;o_ac_d3;2;0)))))

 

[HarmenD]

Dank je VenA,

Ik heb de formule even aangepast met jou oplossing en het werkt (maar dat wist je natuurlijk al)!
en ...... bedankt voor de tip voor het gebruik van een tabel (hoeft de gebruiker ook geen toestemming e.d. te geven voor een .xlsm bestand)

Laat het bericht nog ff 'open staan'.

mvg
]-[armenD

 

[HSV]

Kan ook:

=ALS(M2="";"";VERT.ZOEKEN(M2;INDIRECT("o_ac_d"&RECHTS(L2;1));2;0))

Als je niet meer dan 9 tabellen hebt.

 

[HarmenD]

HSV ook bedankt!

Echter de 1e formule

=ALS(M2="";"";M2)

geeft in kolom O hetzelfde resultaat als in kolom M (want dat staat natuurlijk ook in die formule).
In kolom M staat de omschrijving en in kolom O de art.code (zie tabblad gegevens de tabellen 2, 3 en 4 / staat daar niet zo duidelijk, klopt!).

De 2e formule van je

=ALS(M2="";"";VERT.ZOEKEN(M2;INDIRECT("o_ac_d"&RECHTS(L2;1));2;0))

is ook een mooie oplossing ware het niet, dat in het keuzemenu in kolom M niet gekozen kan worden uit de omschrijving van dealer3.
Ik zie niet zo gauw waar ik die verwijzing moet neerzetten (maar dat ligt natuurlijk aan mij )

Bedankt voor het meedenken!

mvg
]-[armenD

 

[HarmenD]

Misschien iets te snel gereageerd op het bericht van HSV .....
toen ik de sheet naar een tabel 'converteerde' werkte de 2e formule van HSV wel .... zal wel aan de temperatuur gelegen hebben!

Nogmaals bedankt!

mvg
]-[armenD

 

[HSV]

Of als INDIRECT te traag wordt.

=ALS(M2="";"";VERT.ZOEKEN(M2;KIEZEN(RECHTS(L2;1);Tabel2[[Omschrijving]:[ArtCode]];Tabel3[[Omschrijving]:[ArtCode]];Tabel4[[Omschrijving]:[ArtCode]]);2;0))

Of:

=ALS(M2="";"";VERT.ZOEKEN(M2;KIEZEN(RECHTS(L2;1);o_ac_d1;o_ac_d2;o_ac_d3);2;0))

 

[HarmenD]

Allen bedankt!

Ik heb voorlopig genoeg om mee aan de slag te gaan :d
Tussen 2 ()-jes: ik heb het origineel inmiddels werkend met de aangedragen oplossing(en).

mvg
]-[armenD